dev-python/stripe: Remove old

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/stripe/Manifest

@@ -1,3 +1,2 @@
-DIST stripe-13.2.0.tar.gz 1357785 BLAKE2B 5462cd451f111878c4a12019a1e8efd515c25a93d0c10dd0a59ae9fb1d5a94ebfb66dbc3e76f1bf822ff8713fa05027f08974545c08a559486a9cbaec7e4ec97 SHA512 3cb687d6a1f45c0cbdc5ed301f5751d3c2499f8524e03e429aca54d11c4ab8735a9fd81e18b56829c479a3c68dce43dd5c4bd86c82c9d4ed4144dbc4ac2b5bd1
 DIST stripe-14.0.1.tar.gz 1362960 BLAKE2B aaa99435384a99f54cd8d33c73989040e8d20f17e2df9dd11a4d8ba8d0b429d04f8a29887583853c6c7e9b51fea59585ca3fd4ecee9ce5c32d3120d6871fff3f SHA512 0459973952e28fa1706dcca2a14e9b7f844bbd6b37cc4445b603ead34b8b711b3311ec3c0f404beb39041430a5c121f371525d3496998b27cf0328e8b335e355
 DIST stripe-14.1.0.tar.gz 1449934 BLAKE2B abfcc3853bbdb645851e41da825c203ba5303b738c657e179525a673e2cb9d39ce8e6b9c2ebdd4eae6c02946c1ff7d0c9fe9207e357200ec457eb788134213f4 SHA512 6178266699a484a5a7a3571826f6c2fd4ccb4c4e5b8cf2b86b2da2857b00df8b575a64c9ae97d9fdd891532f7dc6b90855c58c6bbb6feaf8204231348c9519d5

dev-python/stripe/stripe-13.2.0.ebuild

@@ -1,91 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_USE_PEP517=flit
-PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
-
-inherit distutils-r1 pypi
-
-DESCRIPTION="Stripe Python bindings"
-HOMEPAGE="
-	https://github.com/stripe/stripe-python/
-	https://pypi.org/project/stripe/
-"
-
-LICENSE="MIT"
-SLOT="0"
-KEYWORDS="amd64 arm64 x86"
-IUSE="telemetry"
-
-RDEPEND="
-	>=dev-python/requests-2.20[${PYTHON_USEDEP}]
-	>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
-"
-# please bump dev-util/stripe-mock dep to the latest version on every bump
-BDEPEND="
-	test? (
-		>=dev-util/stripe-mock-0.197.0
-		dev-python/aiohttp[${PYTHON_USEDEP}]
-		dev-python/httpx[${PYTHON_USEDEP}]
-		dev-python/trio[${PYTHON_USEDEP}]
-		net-misc/curl
-	)
-"
-
-EPYTEST_PLUGINS=( anyio pytest-mock )
-EPYTEST_XDIST=1
-distutils_enable_tests pytest
-
-src_prepare() {
-	distutils-r1_src_prepare
-
-	if ! use telemetry; then
-		sed -i -e '/enable_telemetry/s:True:False:' stripe/__init__.py || die
-	fi
-}
-
-python_test() {
-	local EPYTEST_DESELECT=(
-		# Internet
-		tests/test_http_client.py::TestLiveHTTPClients::test_httpx_request_async_https
-		'tests/test_integration.py::TestIntegration::test_async_raw_request_timeout[asyncio-aiohttp]'
-		# timing
-		tests/test_integration.py::TestIntegration::test_passes_client_telemetry_when_enabled
-	)
-
-	epytest tests
-}
-
-src_test() {
-	local stripe_mock_port=12111
-	local stripe_mock_max_port=12121
-	local stripe_mock_logfile="${T}/stripe_mock_${EPYTHON}.log"
-	# Try to start stripe-mock until we find a free port
-	while [[ ${stripe_mock_port} -le ${stripe_mock_max_port} ]]; do
-		ebegin "Trying to start stripe-mock on port ${stripe_mock_port}"
-		stripe-mock --http-port "${stripe_mock_port}" &> "${stripe_mock_logfile}" &
-		local stripe_mock_pid=${!}
-		sleep 2
-		# Did stripe-mock start?
-		curl --fail -u "sk_test_123:" \
-			"http://127.0.0.1:${stripe_mock_port}/v1/customers" &> /dev/null
-		eend ${?} "Port ${stripe_mock_port} unavailable"
-		if [[ ${?} -eq 0 ]]; then
-			einfo "stripe-mock running on port ${stripe_mock_port}"
-			break
-		fi
-		(( stripe_mock_port++ ))
-	done
-	if [[ ${stripe_mock_port} -gt ${stripe_mock_max_port} ]]; then
-		eerror "Unable to start stripe-mock for tests"
-		die "Please see the logfile located at: ${stripe_mock_logfile}"
-	fi
-
-	local -x STRIPE_MOCK_PORT=${stripe_mock_port}
-	distutils-r1_src_test
-
-	# Tear down stripe-mock
-	kill "${stripe_mock_pid}" || die "Unable to stop stripe-mock"
-}