mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-21 10:37:22 -08:00
@@ -2,3 +2,4 @@ DIST mpd-0.22.11.tar.xz 737184 BLAKE2B b47dcbd1e01812b66c81f33a53fc0838ddb8b7a14
|
||||
DIST mpd-0.22.3.tar.xz 726356 BLAKE2B a821e9fed56c3ad625d155057867747d2c883dd90d110b097dfd4acc56ff583949889b849686d5644687226f205c5ae3f95eec182841f706f56135c7e8f3746b SHA512 deeafbe1a95f777fa4f9f355293a648a3f7121fae8e299c92dbd43d821319ffa4182c558cb0691f65e90f243428cec2cf14f64e9572bc72fc6a2af0fd9c0cd60
|
||||
DIST mpd-0.23.5.tar.xz 770700 BLAKE2B 91f0d37bca0632a414083f6ecf8838ba5dc4ef4965692b14e56587d3d145140f61bcc120fe4b2bf83eb41f2a7e085da4d999efc19ca9717d2552d92fc6359c65 SHA512 3a870e79bb82c9e8877958d271e933daa3dd970a4510aff4aeea91feab521d7927cd59c7f1ea16a36e84ff879e4f24e4347602ac449c5da31853acb5a3b46f34
|
||||
DIST mpd-0.23.6.tar.xz 770812 BLAKE2B 5ccb4a7c06c4317e3285846a261438bdcc10db5eaf71fcba969bcae8321ca50bb26fe9317e23e38eca1c4a8785015596064d5bfc692bf66f8007d0d2a1b71cbb SHA512 1595fcc53a67f1a68b0c0516697d242da53b91626e37bc2f49095add78eb497a52c67c961a421f20b40f3c57a571557a76559a212838de2a3ec4aec6c7a3288d
|
||||
DIST mpd-0.23.7.tar.xz 771992 BLAKE2B 2c75196c37eb8d075cca2881bb7ed10e434a071d3c64bb7cdb3bb96dfea74c30de2dce5bfdbc51da945df325d9f278cdf8dd03b7ba07c0ad51cea50971f4a143 SHA512 2a6b3eb2c8b61a22861ae75fe2f62c8ec6cd391f029438577127e309b910e99d7b735e40afae96d52ed4f161195a0ce7cb89cc51ad45df5a18e04736c16ce3a6
|
||||
|
||||
@@ -0,0 +1,293 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
inherit flag-o-matic linux-info meson systemd xdg
|
||||
|
||||
DESCRIPTION="The Music Player Daemon (mpd)"
|
||||
HOMEPAGE="https://www.musicpd.org https://github.com/MusicPlayerDaemon/MPD"
|
||||
SRC_URI="https://www.musicpd.org/download/${PN}/${PV%.*}/${P}.tar.xz"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~ppc ~riscv ~x86"
|
||||
IUSE="+alsa ao +audiofile bzip2 cdio chromaprint +cue +curl doc +dbus
|
||||
+eventfd expat faad +ffmpeg +fifo flac fluidsynth gme +icu +id3tag +inotify
|
||||
+ipv6 jack lame libmpdclient libsamplerate libsoxr +mad mikmod mms
|
||||
modplug mpg123 musepack +network nfs openal openmpt opus oss pipe pipewire pulseaudio qobuz
|
||||
recorder samba selinux sid signalfd snapcast sndfile sndio soundcloud sqlite systemd
|
||||
test twolame udisks unicode vorbis wavpack webdav wildmidi upnp
|
||||
zeroconf zip zlib"
|
||||
|
||||
OUTPUT_PLUGINS="alsa ao fifo jack network openal oss pipe pipewire pulseaudio snapcast sndio recorder"
|
||||
DECODER_PLUGINS="audiofile faad ffmpeg flac fluidsynth mad mikmod
|
||||
modplug mpg123 musepack opus openmpt flac sid vorbis wavpack wildmidi"
|
||||
ENCODER_PLUGINS="audiofile flac lame twolame vorbis"
|
||||
|
||||
REQUIRED_USE="
|
||||
|| ( ${OUTPUT_PLUGINS} )
|
||||
|| ( ${DECODER_PLUGINS} )
|
||||
network? ( || ( ${ENCODER_PLUGINS} ) )
|
||||
recorder? ( || ( ${ENCODER_PLUGINS} ) )
|
||||
qobuz? ( curl soundcloud )
|
||||
soundcloud? ( curl qobuz )
|
||||
udisks? ( dbus )
|
||||
upnp? ( curl expat )
|
||||
webdav? ( curl expat )
|
||||
"
|
||||
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
RDEPEND="
|
||||
acct-user/mpd
|
||||
dev-libs/libfmt:=
|
||||
dev-libs/libpcre2
|
||||
media-libs/libogg
|
||||
sys-libs/liburing:=
|
||||
alsa? (
|
||||
media-libs/alsa-lib
|
||||
media-sound/alsa-utils
|
||||
)
|
||||
ao? ( media-libs/libao:=[alsa?,pulseaudio?] )
|
||||
audiofile? ( media-libs/audiofile:= )
|
||||
bzip2? ( app-arch/bzip2 )
|
||||
cdio? (
|
||||
dev-libs/libcdio:=
|
||||
dev-libs/libcdio-paranoia
|
||||
)
|
||||
chromaprint? ( media-libs/chromaprint )
|
||||
curl? ( net-misc/curl )
|
||||
dbus? ( sys-apps/dbus )
|
||||
doc? ( dev-python/sphinx )
|
||||
expat? ( dev-libs/expat )
|
||||
faad? ( media-libs/faad2 )
|
||||
ffmpeg? ( media-video/ffmpeg:0= )
|
||||
flac? ( media-libs/flac )
|
||||
fluidsynth? ( media-sound/fluidsynth )
|
||||
gme? ( >=media-libs/game-music-emu-0.6.0_pre20120802 )
|
||||
icu? (
|
||||
dev-libs/icu:=
|
||||
virtual/libiconv
|
||||
)
|
||||
id3tag? ( media-libs/libid3tag:= )
|
||||
jack? ( virtual/jack )
|
||||
lame? ( network? ( media-sound/lame ) )
|
||||
libmpdclient? ( media-libs/libmpdclient )
|
||||
libsamplerate? ( media-libs/libsamplerate )
|
||||
libsoxr? ( media-libs/soxr )
|
||||
mad? ( media-libs/libmad )
|
||||
mikmod? ( media-libs/libmikmod )
|
||||
mms? ( media-libs/libmms )
|
||||
modplug? ( media-libs/libmodplug )
|
||||
mpg123? ( media-sound/mpg123 )
|
||||
musepack? ( media-sound/musepack-tools )
|
||||
network? ( >=media-libs/libshout-2.4.0 )
|
||||
nfs? ( net-fs/libnfs )
|
||||
openal? ( media-libs/openal )
|
||||
openmpt? ( media-libs/libopenmpt )
|
||||
opus? ( media-libs/opus )
|
||||
pulseaudio? ( media-sound/pulseaudio )
|
||||
pipewire? ( media-video/pipewire:= )
|
||||
qobuz? ( dev-libs/libgcrypt:0 )
|
||||
samba? ( net-fs/samba )
|
||||
selinux? ( sec-policy/selinux-mpd )
|
||||
sid? ( || (
|
||||
media-libs/libsidplay:2
|
||||
media-libs/libsidplayfp
|
||||
) )
|
||||
snapcast? ( media-sound/snapcast )
|
||||
sndfile? ( media-libs/libsndfile )
|
||||
sndio? ( media-sound/sndio )
|
||||
soundcloud? ( >=dev-libs/yajl-2:= )
|
||||
sqlite? ( dev-db/sqlite:3 )
|
||||
systemd? ( sys-apps/systemd:= )
|
||||
twolame? ( media-sound/twolame )
|
||||
udisks? ( sys-fs/udisks:2 )
|
||||
upnp? ( net-libs/libupnp:0 )
|
||||
vorbis? ( media-libs/libvorbis )
|
||||
wavpack? ( media-sound/wavpack )
|
||||
wildmidi? ( media-sound/wildmidi )
|
||||
zeroconf? ( net-dns/avahi[dbus] )
|
||||
zip? ( dev-libs/zziplib:= )
|
||||
zlib? ( sys-libs/zlib:= )"
|
||||
|
||||
DEPEND="${RDEPEND}
|
||||
>=dev-libs/boost-1.68:=
|
||||
test? ( dev-cpp/gtest )"
|
||||
|
||||
BDEPEND="virtual/pkgconfig"
|
||||
|
||||
pkg_setup() {
|
||||
if use eventfd; then
|
||||
CONFIG_CHECK+=" ~EVENTFD"
|
||||
ERROR_EVENTFD="${P} requires eventfd in-kernel support."
|
||||
fi
|
||||
|
||||
if use signalfd; then
|
||||
CONFIG_CHECK+=" ~SIGNALFD"
|
||||
ERROR_SIGNALFD="${P} requires signalfd in-kernel support."
|
||||
fi
|
||||
|
||||
if use inotify; then
|
||||
CONFIG_CHECK+=" ~INOTIFY_USER"
|
||||
ERROR_INOTIFY_USER="${P} requires inotify in-kernel support."
|
||||
fi
|
||||
|
||||
if use eventfd || use signalfd || use inotify; then
|
||||
linux-info_pkg_setup
|
||||
fi
|
||||
|
||||
elog "If you will be starting mpd via /etc/init.d/mpd, please make sure that MPD's pid_file is _set_."
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
sed -i \
|
||||
-e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
|
||||
-e 's:^#user.*$:user "mpd":' \
|
||||
-e 's:^#bind_to_address.*any.*$:bind_to_address "localhost":' \
|
||||
-e 's:^#bind_to_address.*$:bind_to_address "/var/lib/mpd/socket":' \
|
||||
-e 's:^#music_directory.*$:music_directory "/var/lib/mpd/music":' \
|
||||
-e 's:^#playlist_directory.*$:playlist_directory "/var/lib/mpd/playlists":' \
|
||||
-e 's:^#db_file.*$:db_file "/var/lib/mpd/database":' \
|
||||
-e 's:^#log_file.*$:log_file "/var/lib/mpd/log":' \
|
||||
-e 's:^#pid_file.*$:pid_file "/var/lib/mpd/pid":' \
|
||||
-e 's:^#state_file.*$:state_file "/var/lib/mpd/state":' \
|
||||
doc/mpdconf.example || die
|
||||
default
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local emesonargs=(
|
||||
$(meson_feature bzip2)
|
||||
$(meson_feature cdio cdio_paranoia)
|
||||
$(meson_feature chromaprint)
|
||||
$(meson_use cue)
|
||||
$(meson_feature curl)
|
||||
$(meson_feature dbus)
|
||||
$(meson_use eventfd)
|
||||
$(meson_feature expat)
|
||||
$(meson_feature icu)
|
||||
$(meson_feature id3tag)
|
||||
$(meson_use inotify)
|
||||
$(meson_feature ipv6)
|
||||
$(meson_feature cdio iso9660)
|
||||
$(meson_feature libmpdclient)
|
||||
$(meson_feature libsamplerate)
|
||||
$(meson_feature mms)
|
||||
$(meson_feature nfs)
|
||||
$(meson_use signalfd)
|
||||
$(meson_feature samba smbclient)
|
||||
$(meson_feature libsoxr soxr)
|
||||
$(meson_feature sqlite)
|
||||
$(meson_feature systemd)
|
||||
$(meson_use test)
|
||||
$(meson_feature udisks)
|
||||
-Dupnp=$(usex upnp pupnp disabled)
|
||||
$(meson_feature webdav)
|
||||
-Dzeroconf=$(usex zeroconf avahi disabled)
|
||||
$(meson_feature zlib)
|
||||
$(meson_feature zip zzip)
|
||||
)
|
||||
|
||||
emesonargs+=(
|
||||
$(meson_feature alsa)
|
||||
$(meson_feature ao)
|
||||
$(meson_use fifo)
|
||||
$(meson_feature jack)
|
||||
$(meson_feature openal)
|
||||
$(meson_feature oss)
|
||||
$(meson_use pipe)
|
||||
$(meson_feature pipewire)
|
||||
$(meson_feature pulseaudio pulse)
|
||||
$(meson_use recorder)
|
||||
$(meson_use snapcast)
|
||||
$(meson_feature sndio)
|
||||
)
|
||||
|
||||
if use samba || use upnp; then
|
||||
emesonargs+=( -Dneighbor=true )
|
||||
fi
|
||||
|
||||
append-lfs-flags
|
||||
append-ldflags "-L${ESYSROOT}/usr/$(get_libdir)/sidplay/builders"
|
||||
|
||||
if use network; then
|
||||
emesonargs+=(
|
||||
-Dshine=disabled
|
||||
-Dshout=enabled
|
||||
$(meson_feature vorbis vorbisenc)
|
||||
-Dhttpd=true
|
||||
$(meson_feature lame)
|
||||
$(meson_feature twolame)
|
||||
$(meson_use audiofile wave_encoder)
|
||||
)
|
||||
fi
|
||||
|
||||
emesonargs+=(
|
||||
# media-libs/adplug is not packaged anymore
|
||||
-Dadplug=disabled
|
||||
$(meson_feature audiofile)
|
||||
$(meson_feature faad)
|
||||
$(meson_feature ffmpeg)
|
||||
$(meson_feature flac)
|
||||
$(meson_feature fluidsynth)
|
||||
$(meson_feature gme)
|
||||
$(meson_feature mad)
|
||||
$(meson_feature mikmod)
|
||||
$(meson_feature modplug)
|
||||
$(meson_feature musepack mpcdec)
|
||||
$(meson_feature mpg123)
|
||||
$(meson_feature openmpt)
|
||||
$(meson_feature opus)
|
||||
$(meson_feature sid sidplay)
|
||||
$(meson_feature sndfile)
|
||||
$(meson_feature vorbis)
|
||||
$(meson_feature wavpack)
|
||||
$(meson_feature wildmidi)
|
||||
$(meson_feature qobuz)
|
||||
$(meson_feature soundcloud)
|
||||
|
||||
--libdir="/usr/$(get_libdir)"
|
||||
$(meson_feature doc documentation)
|
||||
-Dsolaris_output=disabled
|
||||
|
||||
-Ddatabase=true
|
||||
-Ddsd=true
|
||||
-Dio_uring=enabled
|
||||
-Dtcp=true
|
||||
|
||||
-Dsystemd_system_unit_dir="$(systemd_get_systemunitdir)"
|
||||
-Dsystemd_user_unit_dir="$(systemd_get_userunitdir)"
|
||||
|
||||
$(meson_feature icu iconv)
|
||||
)
|
||||
|
||||
meson_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
meson_src_install
|
||||
|
||||
insinto /etc
|
||||
newins doc/mpdconf.example mpd.conf
|
||||
|
||||
insinto /etc/logrotate.d
|
||||
newins "${FILESDIR}"/${PN}-0.21.1.logrotate ${PN}
|
||||
|
||||
newinitd "${FILESDIR}"/${PN}-0.21.4.init ${PN}
|
||||
|
||||
if use unicode; then
|
||||
sed -i -e 's:^#filesystem_charset.*$:filesystem_charset "UTF-8":' \
|
||||
"${ED}"/etc/mpd.conf || die "sed failed"
|
||||
fi
|
||||
|
||||
keepdir /var/lib/mpd
|
||||
keepdir /var/lib/mpd/music
|
||||
keepdir /var/lib/mpd/playlists
|
||||
|
||||
rm -r "${ED}"/usr/share/doc/mpd || die
|
||||
|
||||
fowners mpd:audio -R /var/lib/mpd
|
||||
|
||||
}
|
||||
Reference in New Issue
Block a user