www-client/microsoft-edge: automated bump (126.0.2592.87)

Signed-off-by: Matt Jolly <kangie@gentoo.org>

www-client/microsoft-edge/Manifest

@@ -1 +1,2 @@
 DIST microsoft-edge-stable_126.0.2592.81-1_amd64.deb 168150094 BLAKE2B 7e3ffae48269651076428e86b92e3ae888abd09b9abc86c7f0923d0d7895733d993a3b9de5bf3c97a2030b06903459468d91a03d53cf6ee6f802d2f459f5187b SHA512 f694c2adff03a3b0465687716fc27bcff31c6d76db2f0a60e692d20eae45beeb18ebc5317098c46b8898050b2697909335597684e39992c79bd30c900fc1cec8
+DIST microsoft-edge-stable_126.0.2592.87-1_amd64.deb 168170546 BLAKE2B e1f4464f7bf50c2efbb36510578d5b26c4538c29aaf4f783335e8d0333db5978aac9a429cef1ba76d7662ac4bd93244e2a13238ded468c191858a8e46a4a6d89 SHA512 cbf72b15eb179e861f769908cc6cc84d2913e56b9f35405784063d12efc957cf5c6c4ff8f587e12500d0bbc1b27a5b6d71b455f31315a1a5b798480044d4fb2b

www-client/microsoft-edge/microsoft-edge-126.0.2592.87.ebuild

@@ -0,0 +1,126 @@
+# Copyright 2011-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="8"
+
+inherit chromium-2 desktop pax-utils unpacker xdg
+
+DESCRIPTION="The web browser from Microsoft"
+HOMEPAGE="https://www.microsoft.com/edge"
+
+if [[ ${PN} == microsoft-edge ]]; then
+	MY_PN=${PN}-stable
+else
+	MY_PN=${PN}
+fi
+
+MY_P="${MY_PN}_${PV}-1"
+SRC_URI="https://packages.microsoft.com/repos/edge/pool/main/m/${MY_PN}/${MY_P}_amd64.deb"
+S=${WORKDIR}
+
+LICENSE="microsoft-edge"
+SLOT="0"
+KEYWORDS="-* ~amd64"
+
+IUSE="+mip qt5 qt6"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-misc/ca-certificates
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	media-fonts/liberation-fonts
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl[ssl]
+	net-print/cups
+	sys-apps/dbus
+	sys-apps/util-linux
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3[X]
+	x11-libs/libdrm
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/pango
+	x11-misc/xdg-utils
+	mip? ( app-crypt/libsecret )
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[X]
+		dev-qt/qtwidgets:5
+	)
+	qt6? ( dev-qt/qtbase:6[gui,widgets] )
+"
+
+QA_PREBUILT="*"
+QA_DESKTOP_FILE="usr/share/applications/microsoft-edge.*\\.desktop"
+EDGE_HOME="opt/microsoft/msedge${PN#microsoft-edge}"
+
+pkg_nofetch() {
+	eerror "Please wait 24 hours and sync your tree before reporting a bug for microsoft-edge fetch failures."
+}
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "microsoft-edge only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	unpacker
+
+	rm -f _gpgorigin || die
+
+	rm -r etc usr/share/menu || die
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+
+	gzip -d usr/share/doc/${PF}/changelog.gz || die
+	gzip -d usr/share/man/man1/${MY_PN}.1.gz || die
+	if [[ -L usr/share/man/man1/${PN}.1.gz ]]; then
+		rm usr/share/man/man1/${PN}.1.gz || die
+		dosym ${MY_PN}.1 usr/share/man/man1/${PN}.1
+	fi
+
+	local suffix=
+	[[ ${PN} == microsoft-edge-beta ]] && suffix=_beta
+	[[ ${PN} == microsoft-edge-dev ]] && suffix=_dev
+
+	local size
+	for size in 16 24 32 48 64 128 256 ; do
+		newicon -s ${size} "${EDGE_HOME}/product_logo_${size}${suffix}.png" ${PN}.png
+	done
+
+	if ! use mip; then
+		rm "${EDGE_HOME}"/libmip_{core,protection_sdk}.so || die
+	fi
+
+	if ! use qt5; then
+		rm "${EDGE_HOME}/libqt5_shim.so" || die
+	fi
+	if ! use qt6; then
+		rm "${EDGE_HOME}/libqt6_shim.so" || die
+	fi
+
+	pax-mark m "${EDGE_HOME}/msedge"
+}