dev-python/meson-python: add 0.12.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/meson-python/Manifest

@@ -1 +1,2 @@
 DIST meson-python-0.11.0.gh.tar.gz 43192 BLAKE2B c12a18698f270b36685bbd4ad7ff5f2a718bab28f834cad89be724457704cd56966247e13ed6ba7dd201c5397ccfc78ab9202e7435f0672d63d544f67323b7b3 SHA512 fb894d0db6d18febd6388b7e686d0c7c1e3308f6ebf926c7300e2f376b1d2a803adcf5925c80d05982805e3ce4a59676c9ef829eacdab4696dabec3cb93e4192
+DIST meson-python-0.12.0.gh.tar.gz 43801 BLAKE2B fa4f5b73d490fce64da5c9f79c590e32af5b39790c0ffddc694a6b11a9274760a4e92a3d45abdefdbec1e6c5235ae799ee6c3e1b99685028b3bc007d5322683d SHA512 f2e416027bb6fb6cf6ad0fd84c6b65ddc83b497ff96b5a144dfcdd1addee44972eaa7422c8d9a8092431b6df1b052f970e9e7bd7dc57b28fbf42d2ea3a8d9231

dev-python/meson-python/meson-python-0.12.0.ebuild

@@ -0,0 +1,74 @@
+# Copyright 2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{8..11} )
+
+inherit distutils-r1
+
+DESCRIPTION="Meson PEP 517 Python build backend"
+HOMEPAGE="
+	https://pypi.org/project/meson-python/
+	https://github.com/mesonbuild/meson-python/
+"
+SRC_URI="
+	https://github.com/mesonbuild/meson-python/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/pyproject-metadata-0.6.1[${PYTHON_USEDEP}]
+	>=dev-util/meson-0.63.0[${PYTHON_USEDEP}]
+	dev-util/patchelf
+	$(python_gen_cond_dep '
+		dev-python/typing-extensions[${PYTHON_USEDEP}]
+	' 3.8 3.9)
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.0.0[${PYTHON_USEDEP}]
+	' 3.8 3.9 3.10)
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/GitPython[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.11.0-defaults.patch
+)
+
+distutils_enable_sphinx docs \
+	dev-python/furo \
+	dev-python/sphinx-autodoc-typehints
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# requires network access
+	tests/test_pep518.py::test_pep518
+)
+
+src_prepare() {
+	# strip dependency on ninja -- we provide ninja via Gentoo package
+	# rather than the Python wheel, so we don't have .dist-info there
+	sed -i -e '/ninja/d' pyproject.toml || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# requires network access
+		tests/test_pep518.py::test_pep518
+	)
+
+	epytest
+
+	rm -rf docs/examples/spam/build/ || die # remove artifacts
+}