mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 18:58:08 -07:00
app-emulation/lxc: 2.0.8 version bump bug 621368
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>
This commit is contained in:
Nils Freydank
committed by
Matthew Thode
Matthew Thode
parent
ca013d6f36
commit
b81541bddb
@@ -4,3 +4,4 @@ DIST lxc-2.0.4.tar.gz 775634 SHA256 57d40234aeecf5b60fb29d563e5a09d6a04c89e1267e
|
||||
DIST lxc-2.0.5.tar.gz 778842 SHA256 1f1c491b2ad5e74a85b8eb791ccac8128e6eaf5ddcc1323e9360997c030f7072 SHA512 8e14036597fa3407c87fb92d13b40bbca9a646d27d817e0a9d20fe626625d6cf04a1df65b1a723391d41a311b9f4f3432b3213004892d64355fe0edc7858cb9f WHIRLPOOL fa6ac86d67fe563f92411cbd09a0d66d729a0a15fe48076b42f4b3996e6b786826990bd51382c14606fd1b5240d413bc8d217fac37becd9baccd89de15d30b22
|
||||
DIST lxc-2.0.6.tar.gz 788483 SHA256 8723ef5973a47e7b2c439002c28590d74689e871d36f03089965503c0c0d50b2 SHA512 f44c0498876462d78e57d19816eab666e90470badc2bbd38fed9f504e8b21c3e68e4d0f63a8676fa8716be60481befb3db44098228fd71b480972af2b5dcf1e3 WHIRLPOOL 5bb2648637a46e3547edeba2ad46eb131b2ae194f5efe52a688157cfa3f361f51a832554a94bcd47074e65cbf8d1e1119d23548bdf83ca62c131400c40aff34a
|
||||
DIST lxc-2.0.7.tar.gz 792557 SHA256 e74ee4a61a8ff426051ce86664f85b028052dd5664cc8e4cf710205c75ded356 SHA512 eb48dc800ce43d2f4d46e0cecc4d0a714b3e22c6a4975776b54d17d1d20d5a1411e6b605215282f1f77286ddf22b61c80b86b83752191fc18023894ef7a1c44d WHIRLPOOL 81da3116450a7c41c7aa4de95e0094a56e6dee29ef2a111bfe87a61d9b7b97846f77984ec4b9b45aaf776a2c8103b5957c129f6d05b9ebf46455450129653502
|
||||
DIST lxc-2.0.8.tar.gz 1308705 SHA256 0d8e34b302cfe4c40c6c9ae5097096aa5cc2c1dfceea3f0f22e3e16c4a4e8494 SHA512 ed9fd47e92007f433695cffea659180866a5ac2778712f4eb13b6629bb18292589f5b674b734853ca196ba1f6d38bdbf3cc8a2bb28e25d3540b06b945fcf9096 WHIRLPOOL 10485c76f43c6358fc09a7843f13d16b178b1fbc1c3741d04293e170716bd253d1f7b4c3d6529829d135b381debf857263aea6070f2157d3c095d49209b7113e
|
||||
|
||||
199
app-emulation/lxc/lxc-2.0.8.ebuild
Normal file
199
app-emulation/lxc/lxc-2.0.8.ebuild
Normal file
@@ -0,0 +1,199 @@
|
||||
# Copyright 1999-2017 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI="6"
|
||||
|
||||
PYTHON_COMPAT=( python{3_4,3_5} )
|
||||
DISTUTILS_OPTIONAL=1
|
||||
|
||||
inherit autotools bash-completion-r1 distutils-r1 linux-info versionator flag-o-matic systemd
|
||||
|
||||
DESCRIPTION="LinuX Containers userspace utilities"
|
||||
HOMEPAGE="https://linuxcontainers.org/"
|
||||
SRC_URI="https://linuxcontainers.org/downloads/lxc/${P}.tar.gz"
|
||||
|
||||
KEYWORDS="~amd64 ~arm ~arm64"
|
||||
|
||||
LICENSE="LGPL-3"
|
||||
SLOT="0"
|
||||
IUSE="cgmanager doc examples lua python seccomp"
|
||||
|
||||
RDEPEND="net-libs/gnutls
|
||||
sys-libs/libcap
|
||||
cgmanager? ( app-admin/cgmanager )
|
||||
lua? ( >=dev-lang/lua-5.1:= )
|
||||
python? ( ${PYTHON_DEPS} )
|
||||
seccomp? ( sys-libs/libseccomp )"
|
||||
|
||||
DEPEND="${RDEPEND}
|
||||
doc? ( app-text/docbook-sgml-utils )
|
||||
>=sys-kernel/linux-headers-3.2"
|
||||
|
||||
RDEPEND="${RDEPEND}
|
||||
sys-process/criu
|
||||
sys-apps/util-linux
|
||||
app-misc/pax-utils
|
||||
virtual/awk"
|
||||
|
||||
CONFIG_CHECK="~CGROUPS ~CGROUP_DEVICE
|
||||
~CPUSETS ~CGROUP_CPUACCT
|
||||
~CGROUP_SCHED
|
||||
|
||||
~NAMESPACES
|
||||
~IPC_NS ~USER_NS ~PID_NS
|
||||
|
||||
~NETLINK_DIAG ~PACKET_DIAG
|
||||
~INET_UDP_DIAG ~INET_TCP_DIAG
|
||||
~UNIX_DIAG ~CHECKPOINT_RESTORE
|
||||
|
||||
~CGROUP_FREEZER
|
||||
~UTS_NS ~NET_NS
|
||||
~VETH ~MACVLAN
|
||||
|
||||
~POSIX_MQUEUE
|
||||
~!NETPRIO_CGROUP
|
||||
|
||||
~!GRKERNSEC_CHROOT_MOUNT
|
||||
~!GRKERNSEC_CHROOT_DOUBLE
|
||||
~!GRKERNSEC_CHROOT_PIVOT
|
||||
~!GRKERNSEC_CHROOT_CHMOD
|
||||
~!GRKERNSEC_CHROOT_CAPS
|
||||
~!GRKERNSEC_PROC
|
||||
~!GRKERNSEC_SYSFS_RESTRICT
|
||||
"
|
||||
|
||||
ERROR_DEVPTS_MULTIPLE_INSTANCES="CONFIG_DEVPTS_MULTIPLE_INSTANCES: needed for pts inside container"
|
||||
|
||||
ERROR_CGROUP_FREEZER="CONFIG_CGROUP_FREEZER: needed to freeze containers"
|
||||
|
||||
ERROR_UTS_NS="CONFIG_UTS_NS: needed to unshare hostnames and uname info"
|
||||
ERROR_NET_NS="CONFIG_NET_NS: needed for unshared network"
|
||||
|
||||
ERROR_VETH="CONFIG_VETH: needed for internal (host-to-container) networking"
|
||||
ERROR_MACVLAN="CONFIG_MACVLAN: needed for internal (inter-container) networking"
|
||||
|
||||
ERROR_NETLINK_DIAG="CONFIG_NETLINK_DIAG: needed for lxc-checkpoint"
|
||||
ERROR_PACKET_DIAG="CONFIG_PACKET_DIAG: needed for lxc-checkpoint"
|
||||
ERROR_INET_UDP_DIAG="CONFIG_INET_UDP_DIAG: needed for lxc-checkpoint"
|
||||
ERROR_INET_TCP_DIAG="CONFIG_INET_TCP_DIAG: needed for lxc-checkpoint"
|
||||
ERROR_UNIX_DIAG="CONFIG_UNIX_DIAG: needed for lxc-checkpoint"
|
||||
ERROR_CHECKPOINT_RESTORE="CONFIG_CHECKPOINT_RESTORE: needed for lxc-checkpoint"
|
||||
|
||||
ERROR_POSIX_MQUEUE="CONFIG_POSIX_MQUEUE: needed for lxc-execute command"
|
||||
|
||||
ERROR_NETPRIO_CGROUP="CONFIG_NETPRIO_CGROUP: as of kernel 3.3 and lxc 0.8.0_rc1 this causes LXCs to fail booting."
|
||||
|
||||
ERROR_GRKERNSEC_CHROOT_MOUNT="CONFIG_GRKERNSEC_CHROOT_MOUNT: some GRSEC features make LXC unusable see postinst notes"
|
||||
ERROR_GRKERNSEC_CHROOT_DOUBLE="CONFIG_GRKERNSEC_CHROOT_DOUBLE: some GRSEC features make LXC unusable see postinst notes"
|
||||
ERROR_GRKERNSEC_CHROOT_PIVOT="CONFIG_GRKERNSEC_CHROOT_PIVOT: some GRSEC features make LXC unusable see postinst notes"
|
||||
ERROR_GRKERNSEC_CHROOT_CHMOD="CONFIG_GRKERNSEC_CHROOT_CHMOD: some GRSEC features make LXC unusable see postinst notes"
|
||||
ERROR_GRKERNSEC_CHROOT_CAPS="CONFIG_GRKERNSEC_CHROOT_CAPS: some GRSEC features make LXC unusable see postinst notes"
|
||||
ERROR_GRKERNSEC_PROC="CONFIG_GRKERNSEC_PROC: this GRSEC feature is incompatible with unprivileged containers"
|
||||
ERROR_GRKERNSEC_SYSFS_RESTRICT="CONFIG_GRKERNSEC_SYSFS_RESTRICT: this GRSEC feature is incompatible with unprivileged containers"
|
||||
|
||||
DOCS=(AUTHORS CONTRIBUTING MAINTAINERS NEWS README doc/FAQ.txt)
|
||||
|
||||
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
|
||||
|
||||
pkg_setup() {
|
||||
kernel_is -lt 4 7 && CONFIG_CHECK="${CONFIG_CHECK} ~DEVPTS_MULTIPLE_INSTANCES"
|
||||
linux-info_pkg_setup
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
eapply "${FILESDIR}"/${PN}-2.0.6-bash-completion.patch
|
||||
#558854
|
||||
eapply "${FILESDIR}"/${PN}-2.0.5-omit-sysconfig.patch
|
||||
eapply_user
|
||||
eautoreconf
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
append-flags -fno-strict-aliasing
|
||||
|
||||
if use python; then
|
||||
#541932
|
||||
python_setup "python3*"
|
||||
export PKG_CONFIG_PATH="${T}/${EPYTHON}/pkgconfig:${PKG_CONFIG_PATH}"
|
||||
fi
|
||||
|
||||
# I am not sure about the --with-rootfs-path
|
||||
# /var/lib/lxc is probably more appropriate than
|
||||
# /usr/lib/lxc.
|
||||
# Note by holgersson: Why is apparmor disabled?
|
||||
econf \
|
||||
--localstatedir=/var \
|
||||
--bindir=/usr/bin \
|
||||
--sbindir=/usr/bin \
|
||||
--with-config-path=/var/lib/lxc \
|
||||
--with-rootfs-path=/var/lib/lxc/rootfs \
|
||||
--with-distro=gentoo \
|
||||
--with-runtime-path=/run \
|
||||
--disable-apparmor \
|
||||
--disable-werror \
|
||||
$(use_enable cgmanager) \
|
||||
$(use_enable doc) \
|
||||
$(use_enable examples) \
|
||||
$(use_enable lua) \
|
||||
$(use_enable python) \
|
||||
$(use_enable seccomp)
|
||||
}
|
||||
|
||||
python_compile() {
|
||||
distutils-r1_python_compile build_ext -I ../ -L ../${PN}
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
default
|
||||
|
||||
if use python; then
|
||||
pushd "${S}/src/python-${PN}" > /dev/null
|
||||
distutils-r1_src_compile
|
||||
popd > /dev/null
|
||||
fi
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
|
||||
mv "${ED}"/usr/share/bash-completion/completions/${PN} "${ED}"/$(get_bashcompdir)/${PN}-start || die
|
||||
# start-ephemeral is no longer a command but removing it here
|
||||
# generates QA warnings (still in upstream completion script)
|
||||
bashcomp_alias ${PN}-start \
|
||||
${PN}-{attach,cgroup,copy,console,create,destroy,device,execute,freeze,info,monitor,snapshot,start-ephemeral,stop,unfreeze,wait}
|
||||
|
||||
if use python; then
|
||||
pushd "${S}/src/python-lxc" > /dev/null
|
||||
# Unset DOCS. This has been handled by the default target
|
||||
unset DOCS
|
||||
distutils-r1_src_install
|
||||
popd > /dev/null
|
||||
fi
|
||||
|
||||
keepdir /etc/lxc /var/lib/lxc/rootfs /var/log/lxc
|
||||
|
||||
find "${D}" -name '*.la' -delete
|
||||
|
||||
# Gentoo-specific additions!
|
||||
newinitd "${FILESDIR}/${PN}.initd.5" ${PN}
|
||||
|
||||
# Remember to compare our systemd unit file with the upstream one
|
||||
# config/init/systemd/lxc.service.in
|
||||
systemd_newunit "${FILESDIR}"/${PN}_at.service.4 "lxc@.service"
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
elog ""
|
||||
elog "Starting from version ${PN}-1.1.0-r3, the default lxc path has been"
|
||||
elog "moved from /etc/lxc to /var/lib/lxc. If you still want to use /etc/lxc"
|
||||
elog "please add the following to your /etc/lxc/default.conf"
|
||||
elog "lxc.lxcpath = /etc/lxc"
|
||||
elog ""
|
||||
elog "There is an init script provided with the package now; no documentation"
|
||||
elog "is currently available though, so please check out /etc/init.d/lxc ."
|
||||
elog "You _should_ only need to symlink it to /etc/init.d/lxc.configname"
|
||||
elog "to start the container defined into /etc/lxc/configname.conf ."
|
||||
elog "For further information about LXC development see"
|
||||
elog "http://blog.flameeyes.eu/tag/lxc" # remove once proper doc is available
|
||||
elog ""
|
||||
}
|
||||
Reference in New Issue
Block a user