dev-python/pyzmq: bump to 16.0.2

Package-Manager: Portage-2.3.6_p1, Repoman-2.3.2_p69

dev-python/pyzmq/Manifest

@@ -1,2 +1,3 @@
 DIST pyzmq-14.4.1.tar.gz 995366 SHA256 cb4a59875fdc26315045d800bac008b8e10a4cf2d72ac9af2fc45ef6ac8f330a SHA512 4b71677e4bfa771177a34dbff59cf6dfd54310a8996689a3d62902aaba35c7cf2ad6b7da806f9e189ad4b89fcefe9cbb3e192788eecd5d2c269e8a980b4d50fa WHIRLPOOL f6c093023b4494e1f9293a81ac86dcc55ff05f7ae10bb9677ff4fffd2e38fefe2462eb241c74b1ee283958a8546b128585c78c644dae544aa38f4b9c1f3e3ad8
 DIST pyzmq-15.2.0.tar.gz 1078561 SHA256 2dafa322670a94e20283aba2a44b92134d425bd326419b68ad4db8d0831a26ec SHA512 28541b095b5486b662fe33a24994af5a465989a2391091ec8b693579124fdd600c3b0721853377c7551430d55b13c9116a1eebdced74678598d78c01fa7431c7 WHIRLPOOL 2ef08e72f1d35336118191a914068aa1b2b77cea92c197f902ffdf679c80b7bd6bf025ab1dc267f9adc65c38213499631441b5f69a5c2296d7cb4d723867499c
+DIST pyzmq-16.0.2.tar.gz 1026531 SHA256 0322543fff5ab6f87d11a8a099c4c07dd8a1719040084b6ce9162bcdf5c45c9d SHA512 40eaf8ce39db86ab3866890d74b92bd6f20d4ae827828a8772003656d899d10ffcfc222d21f344d9daba390824e6c43b9f34e31beb604ec5ee1ec199165f4b96 WHIRLPOOL 69db3fc02c16bf16631a56b8cd0a0cd6befa0a8a7251eb72cc53c7cb252dd65304e03b25f27215dc6ed1792ac001b07d2539e40724be0fe0292620f78327161a

dev-python/pyzmq/pyzmq-16.0.2.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit flag-o-matic distutils-r1 toolchain-funcs
+
+DESCRIPTION="Lightweight and super-fast messaging library built on top of the ZeroMQ library"
+HOMEPAGE="http://www.zeromq.org/bindings:python https://pypi.python.org/pypi/pyzmq"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
+IUSE="doc test"
+
+RDEPEND="
+	>=net-libs/zeromq-4.1.2:=
+	dev-python/py[${PYTHON_USEDEP}]
+	dev-python/cffi:=[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/gevent[${PYTHON_USEDEP}]' python2_7)
+"
+DEPEND="${RDEPEND}
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/unittest2[${PYTHON_USEDEP}]' -2)
+		www-servers/tornado[${PYTHON_USEDEP}]
+	)
+	doc? (
+		>=dev-python/sphinx-1.3[${PYTHON_USEDEP}]
+		dev-python/numpydoc[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# Prevent un-needed download during build
+	sed -e "/'sphinx.ext.intersphinx',/d" -i docs/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_configure_all() {
+	tc-export CC
+	append-cppflags -DZMQ_BUILD_DRAFT_API=1
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_compile() {
+	esetup.py cython --force
+	python_is_python3 || local -x CFLAGS="${CFLAGS} -fno-strict-aliasing"
+	distutils-r1_python_compile
+}
+
+python_test() {
+	${EPYTHON} -m pytest -v "${BUILD_DIR}/lib" || die
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}