media-radio/tucnak: Version bump

Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Thomas Beierlein <tomjbe@gentoo.org>

media-radio/tucnak/Manifest

@@ -1 +1,2 @@
 DIST tucnak-4.30.tar.gz 3594691 BLAKE2B 41ea3469ebd7ab4a50805c2806289c78ec4fe2ab28b3fea0301e486c9b9232a86b3c93ed26dc1ffc3dc531b69acb847f5cfe66b48ea2579d702d0a5427387d79 SHA512 dd840295c69c2a42ab2ac803444684e06bbf4f47623f9200832f2600bf4540817e2e375ffd1e1dcb6bb57743991396eea7f99a79182397d22dcb78adcf98f500
+DIST tucnak-4.32.tar.gz 3595195 BLAKE2B 6fd837efd0f649eec8c78f232b00e51d7f08a52e7651f6bbea3a16d3e1fcc21a7ad8a7a69e1507ce9a95b4c2da3a3605708849e0fc856511da9d297689d2163f SHA512 a414007e5090fcfb2f538dce2b8a33b5f9d8491cdbdb21a2067f976b9db8778de1b6cefff1e42fe161e8c0965e069102653ac9bb64ac8a1fbd0539d6a14f5b8f

media-radio/tucnak/tucnak-4.32.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit autotools flag-o-matic multilib
+
+DESCRIPTION="Amateur Radio VHF Contest Logbook"
+HOMEPAGE="http://tucnak.nagano.cz"
+SRC_URI="http://tucnak.nagano.cz/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="alsa fftw gpm hamlib suid"
+
+RDEPEND="dev-libs/glib:2
+	dev-libs/libzia
+	media-libs/libsndfile
+	>=media-libs/libsdl-1.2
+	alsa? ( media-libs/alsa-lib )
+	fftw? ( sci-libs/fftw:3.0 )
+	gpm? ( sys-libs/gpm )
+	hamlib? ( media-libs/hamlib:= )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_prepare() {
+	eapply_user
+	# fix destop file
+	sed -i -e "s/HamRadio/HamRadio;/" share/applications/tucnak.desktop || die
+	# fix doc install path
+	sed -i -e "s/docsdir/# docsdir/" \
+		-e "s/docs_DATA =/# docs_DATA/" \
+		-e "s/EXTRA_DIST =/# EXTRA_DIST =/" Makefile.am doc/Makefile.am || die
+	eautoreconf
+}
+
+src_configure() {
+	append-ldflags -L/usr/$(get_libdir)/hamlib
+	econf $(use_with alsa) \
+		$(use_with gpm) $(use_with hamlib) \
+		$(use_with fftw fftw3)
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	dodoc AUTHORS ChangeLog doc/NAVOD.pdf
+	if use suid ; then
+		fperms 4711 /usr/bin/soundwrapper
+	fi
+}
+
+pkg_postinst() {
+	elog "In order to use sound with tucnak add yourself to the 'audio' group"
+	elog "and to key your rig via the parport add yourself to the 'lp' group"
+	elog ""
+	elog "tucnak can be used with the following additional packages:"
+	elog "	   media-radio/cwdaemon  : Morse output via code cwdaemon"
+	elog "                             (No need to recompile)"
+	if use suid ; then
+		ewarn "You have choosen to install the little helper program 'soundwrapper'"
+		ewarn "setuid by setting USE=suid. That helper is only needed if you"
+		ewarn "want to use morse sidetone output via the PC speaker."
+		ewarn ""
+		ewarn "While the helper should be safe by design be aware that setting"
+		ewarn "any program setuid is a security risk."
+	fi
+}