kde-apps/gwenview: 22.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/gwenview/Manifest

@@ -1 +1,2 @@
 DIST gwenview-22.08.3.tar.xz 6825392 BLAKE2B 60f7ea9623a88fc153e6ba60bd7f3ae8e76e5e3da95940578e89d41a90f401b48c927d15f3270cbf18ff93998e50b7fdefde6ad9944ee9a11733f12262df0f7f SHA512 1a450a6df3b5976cca2f4077695e7360e434fbe500d07b1d8f4adb72d3cad6caee8c886a89c2067082c721959f78fce6385fd561c8ec8916b3c6b0ceef2b6462
+DIST gwenview-22.12.0.tar.xz 6875456 BLAKE2B 1b9a70cd920b5dab6d1ac4fa2f70ac1c3208fdd8b5679ee1e164a7eaae2355614c91eaad7176244718ea8df37ee453484a65bc5ff75bc10a797e9eeaf0fb2514 SHA512 053587eaf80b819511dee9872cf0b529fc281c7acf420196a7baed770c74551f0a3b8d184da957c7dc30ca94029182d7839ea804c33a3020162ce999bc21d8cc

kde-apps/gwenview/gwenview-22.12.0.ebuild

@@ -0,0 +1,102 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.99.0
+QTMIN=5.15.5
+inherit ecm gear.kde.org optfeature
+
+DESCRIPTION="Image viewer by KDE"
+HOMEPAGE="https://apps.kde.org/gwenview/ https://userbase.kde.org/Gwenview"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="activities fits +mpris raw semantic-desktop share X"
+
+# requires running environment
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	media-gfx/exiv2:=
+	media-libs/kcolorpicker
+	>=media-libs/kimageannotator-0.5.0
+	media-libs/lcms:2
+	media-libs/libjpeg-turbo:=
+	media-libs/libpng:0=
+	>=media-libs/phonon-4.11.0
+	media-libs/tiff
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+	fits? ( sci-libs/cfitsio )
+	mpris? ( >=dev-qt/qtdbus-${QTMIN}:5 )
+	raw? ( >=kde-apps/libkdcraw-${PVCUT}:5 )
+	semantic-desktop? (
+		>=kde-frameworks/baloo-${KFMIN}:5
+		>=kde-frameworks/kfilemetadata-${KFMIN}:5
+	)
+	share? ( >=kde-frameworks/purpose-${KFMIN}:5 )
+	X? (
+		>=dev-qt/qtx11extras-${QTMIN}:5
+		x11-libs/libX11
+	)
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtimageformats-${QTMIN}:5
+	>=kde-frameworks/kimageformats-${KFMIN}:5
+"
+
+src_prepare() {
+	ecm_src_prepare
+	if ! use mpris; then
+		# FIXME: upstream a better solution
+		sed -e "/set(HAVE_QTDBUS/s/\${Qt5DBus_FOUND}/0/" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package fits CFitsio)
+		$(cmake_use_find_package raw KF5KDcraw)
+		-DGWENVIEW_SEMANTICINFO_BACKEND=$(usex semantic-desktop Baloo None)
+		$(cmake_use_find_package share KF5Purpose)
+		-DWITHOUT_X11=$(usex !X)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "SVG support" "kde-apps/svgpart:${SLOT}"
+	fi
+	ecm_pkg_postinst
+}