dev-libs/libical: add 3.0.16

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

dev-libs/libical/Manifest

@@ -1,2 +1,3 @@
 DIST libical-3.0.14.tar.gz 887795 BLAKE2B 8c073b77b5e4e6b24e3dfae7ac7a5f88da874bdfa53489cd04afd4d458d2fc963d39c2816691e777003ca9af510ceaf7bab9d7e1021942aa9c3adaad32ca8341 SHA512 36da5516672976c71b049a12af36164d91f9b655f81f1884766558149f25e80c30e64d15da848842f8a629295d708f39ce6fa63a3b0da39b5cbeb91911a4e6d8
 DIST libical-3.0.15.tar.gz 920483 BLAKE2B 9d4c1a84440b2363537f678363f9b7d8061e429c5bf7bf9ae2c9ea33e328f238dc4ce0e79c66d33441a89b6c2e18527fdb7d40e80338dda0086b636b165d5ae2 SHA512 14f0eaabdd8fc56d91d2fff8647b3871439cceae3cb7af31eaae30b3cc29f818b6f9d582dd4770b8b3b0c6fe53684258d30c743a5fd5dd337fda64e3adae35ba
+DIST libical-3.0.16.tar.gz 921245 BLAKE2B d6afe96abf32ece87393d85b4e5b0c1c10330ac64bca52bbaef96af45fbc06242cbbb4274fa350cc9a56655de238a85dea6111f381674b7cff44ab67a470e89e SHA512 72659c98f6c98b3e0fa15849df7f80993403100fb5c237e452df714a7be2d1d27f4547c81b399fe7bc6b1fb10c8c7cf9a23f5b969d588d7b05d7fe2e29c86bd4

dev-libs/libical/libical-3.0.16.ebuild

@@ -0,0 +1,117 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+VALA_USE_DEPEND="vapigen"
+inherit cmake python-any-r1 vala
+
+DESCRIPTION="Implementation of basic iCAL protocols"
+HOMEPAGE="https://github.com/libical/libical"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-solaris"
+IUSE="doc examples +glib +introspection static-libs test vala"
+
+REQUIRED_USE="introspection? ( glib ) vala? ( introspection )"
+
+RESTRICT="!test? ( test )"
+
+COMMON_DEPEND="
+	dev-libs/icu:=
+	glib? ( dev-libs/glib:2 )
+"
+DEPEND="${COMMON_DEPEND}
+	glib? ( dev-libs/libxml2:2 )
+"
+RDEPEND="${COMMON_DEPEND}
+	sys-libs/timezone-data
+"
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	doc? (
+		app-doc/doxygen[dot]
+		glib? ( dev-util/gtk-doc )
+	)
+	introspection? ( dev-libs/gobject-introspection )
+	test? (
+		${PYTHON_DEPS}
+		glib? ( $(python_gen_any_dep 'dev-python/pygobject:3[${PYTHON_USEDEP}]') )
+	)
+	vala? ( $(vala_depend) )
+"
+
+DOCS=(
+	AUTHORS README.md ReleaseNotes.txt TEST THANKS TODO
+	doc/{AddingOrModifyingComponents.txt,UsingLibical.md}
+)
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.4-tests.patch"
+	"${FILESDIR}/${PN}-3.0.11-pkgconfig-libdir.patch"
+)
+
+python_check_deps() {
+	python_has_version "dev-python/pygobject:3[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake_src_prepare
+
+	use examples || cmake_comment_add_subdirectory examples
+	use vala && vala_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_BerkeleyDB=ON
+		-DICAL_BUILD_DOCS=$(usex doc)
+		-DICAL_GLIB=$(usex glib)
+		-DGOBJECT_INTROSPECTION=$(usex introspection)
+		-DSHARED_ONLY=$(usex !static-libs)
+		-DLIBICAL_BUILD_TESTING=$(usex test)
+		-DICAL_GLIB_VAPI=$(usex vala)
+	)
+	if use vala; then
+		mycmakeargs+=(
+			-DVALAC="${VALAC}"
+			-DVAPIGEN="${VAPIGEN}"
+		)
+	fi
+	cmake_src_configure
+}
+
+src_compile() {
+	cmake_src_compile
+
+	if use doc; then
+		cmake_src_compile docs
+
+		HTML_DOCS=( "${BUILD_DIR}"/apidocs/html/. )
+	fi
+}
+
+src_test() {
+	local myctestargs=(
+		-E "(icalrecurtest|icalrecurtest-r)" # bug 660282
+	)
+
+	cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	if use examples; then
+		rm examples/CMakeLists.txt || die
+		dodoc -r examples
+	fi
+}