gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-06 00:48:18 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: add 6.59.0

Browse Source 
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
Arthur Zamarin
2022-12-02 15:58:08 +02:00
parent a9d570fcc7
commit b78f7ddc03
2 changed files with 78 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -3,3 +3,4 @@ DIST hypothesis-6.57.1.gh.tar.gz 9334332 BLAKE2B 5516e9ff84f11909eadc7888f2727f1
DIST hypothesis-6.58.0.gh.tar.gz 9335693 BLAKE2B 8e72b1ddd2a0c3bd07e5e865147e0befc7bbb42eb16e02704dbb79372e94161b6cc8f1f989b8541331e8488244c3d07e87d118ee43ba07a123de31cdb7b58bbb SHA512 91f128f333144859331e9a841d47d8414964955e14071a49e3d4504a9c9970e5f737c9036be8f20bdda1e620bb428809301d1008bfbd4b0aaa05757abeb8687d
DIST hypothesis-6.58.1.gh.tar.gz 9335673 BLAKE2B 2f4c34f89547c3e05bc9238b9daee864335b89e1c2aab81765aeb0f806c730c33a52fe4820a718df078bb502e507cb954abe4f8528ec8566a366994cadb45d2d SHA512 efcddb49239b10ae851d3c3331629fd41f19d78e30f52f7d672735b397d4cc21fc5e3cabac824046cb391d999605e80abd014d837437593215a3d71aa60b407e
DIST hypothesis-6.58.2.gh.tar.gz 9336284 BLAKE2B 404265e82d5b2e7e131cde9a97ef08a8bbfc482ba58f44fcfca4650b59529b51968c8eba1156b0b397bafa429cfa4b4e3c9d8988a6dbecad40d96c3736a5c2da SHA512 3bfd11c2f10e2075ad756247af6ef8f7e47a79746c6103db2158a3e569319226064f108170018f3455c542308a36bcb9e46d63ec9a66d8d081fdafdb82dfe65f
DIST hypothesis-6.59.0.gh.tar.gz 9337749 BLAKE2B 29673a769702cf80efa05c3f5a60a3dac6d1226db2afbf25e3ff71be801c396db843222dac5facff8bbb1105dbd7533e2e908188a611a6e051b757ef87498dae SHA512 8d189576a45dc527c2adc0b36781a9323292aa3ed61ab1e0747c379d170c8a1907b787889ceb767d4814422d158c3cdd542360e75295605805b22d832a999777

77
dev-python/hypothesis/hypothesis-6.59.0.ebuild Normal file
View File

@@ -0,0 +1,77 @@
# Copyright 1999-2022 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
CLI_COMPAT=( python3_{8..10} )
PYTHON_COMPAT=( "${CLI_COMPAT[@]}" python3_11 pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 multiprocessing optfeature
TAG=hypothesis-python-${PV}
MY_P=hypothesis-${TAG}
DESCRIPTION="A library for property based testing"
HOMEPAGE="
https://github.com/HypothesisWorks/hypothesis/
https://pypi.org/project/hypothesis/
"
SRC_URI="
https://github.com/HypothesisWorks/hypothesis/archive/${TAG}.tar.gz
-> ${P}.gh.tar.gz
"
S="${WORKDIR}/${MY_P}/hypothesis-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
IUSE="cli"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/exceptiongroup-1.0.0_rc8[${PYTHON_USEDEP}]
' 3.8 3.9 3.10)
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' "${CLI_COMPAT[@]}")
)
"
BDEPEND="
test? (
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/requests-toolbelt-0.10.1
)
"
distutils_enable_tests pytest
python_test() {
# subtests are broken by warnings from random plugins
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
local -x PYTEST_PLUGINS=xdist.plugin,pytest_forked,_hypothesis_pytestplugin
epytest tests/cover tests/pytest tests/quality -n "$(makeopts_jobs)"
}
python_install() {
distutils-r1_python_install
if ! use cli || ! has "${EPYTHON}" "${CLI_COMPAT[@]/_/.}"; then
rm -r "${ED}/usr/bin" "${D}$(python_get_scriptdir)" || die
fi
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}