dev-python/python-glanceclient: Bump to 4.8.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/python-glanceclient/Manifest

@@ -1 +1,2 @@
 DIST python-glanceclient-4.7.0.tar.gz 208314 BLAKE2B 97a157781efc0fc67d67f25119edea2a3f85344447e4614f41c73a3f9abda1c9ba646ca7f8d7b2b315b4572997ec730e6eef1782852590e7021f69c61b02920b SHA512 5fff50d499b7fe439cb43c7d396a7dd28439f45cfc157e4fdefb029e7db4cc9955911aae9c4d748fc19bd10ad66d299e26a1178a63a866fef7fb60164467c79d
+DIST python_glanceclient-4.8.0.tar.gz 208444 BLAKE2B e880bb7eded96b933c40981d408d772e7486971ab243cec0ea8b09ff82f69f20dfe96bb0765eb5102996a16f052ab21bad220539b2903bbcc5f80a4f82659abe SHA512 2948ca3b215c3f3b32cfd7f60c8fd40aecceb96fcc005519b3c21e98f3045ad24a77aa1700962eae5ef707eb35b8afb58f6bf96911ce4146ced05219b1e4b58f

dev-python/python-glanceclient/python-glanceclient-4.8.0.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A client for the OpenStack Glance API"
+HOMEPAGE="
+	https://opendev.org/openstack/python-glanceclient/
+	https://github.com/openstack/python-glanceclient/
+	https://pypi.org/project/python-glanceclient/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/keystoneauth1-3.6.2[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/prettytable-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/pyopenssl-17.1.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+	>=dev-python/warlock-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/wrapt-1.7.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/ddt[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/tempest[${PYTHON_USEDEP}]
+		dev-python/testscenarios[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+PATCHES=(
+	# combined patch for urllib3-2 and py3.12 test failures
+	# https://bugs.launchpad.net/python-glanceclient/+bug/2069684
+	# https://bugs.launchpad.net/python-glanceclient/+bug/2069682
+	"${FILESDIR}/${PN}-4.6.0-test.patch"
+
+	# py3.13 added close() to mock_open calls
+	# https://review.opendev.org/c/openstack/python-glanceclient/+/923628
+	"${FILESDIR}/${PN}-4.6.0-test-py3.13.patch"
+)
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b glanceclient/tests/unit
+}