gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-04 13:47:35 -08:00
Code Issues Projects Releases Wiki Activity

dev-python/pytest-regressions: Bump to 2.8.0

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2025-05-31 06:21:57 +02:00
parent 4c81caded0
commit b7194dc19b
No known key found for this signature in database
GPG Key ID: 639ADAE2329E240E
2 changed files with 69 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/pytest-regressions/Manifest
View File

@ -1 +1,2 @@
DIST pytest_regressions-2.7.0.tar.gz 116270 BLAKE2B 90d589081db352e2acbb58b8b56445ba86c92e4eec1ac588b573b27e979a9d5cbd942b8ba8cf978c9c372364176517e76376c3b33775297df5300fe2ce225bc9 SHA512 b4702850470d03e3f1759b7abda003ff930cfffa9e70c95097778fd4efa634ee62e955f2abbec5e0eaac840c0918b7257b747509c8bf3819af0234a15f80fecd
DIST pytest_regressions-2.8.0.tar.gz 116454 BLAKE2B 3ebe0590ae794a83ea2be5372c318fe9ff16c59b2093ad221961a39f472c35daa0974e192e82cdb100fb20d4a7a24574d6b057854c2246c7f6f97f1fcf016a9e SHA512 dcb7b2aa7e80d59e86f1c6e12cb736fe9ecbf043d61dd462575b5a24b71c88325b13631cdd0052444087b8e61490fd21153867299c19b03dc465d7f9d07cdff9

68
dev-python/pytest-regressions/pytest-regressions-2.8.0.ebuild Normal file
View File

@ -0,0 +1,68 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
inherit distutils-r1 pypi
DESCRIPTION="Easy to use fixtures to write regression tests"
HOMEPAGE="
https://github.com/ESSS/pytest-regressions/
https://pypi.org/project/pytest-regressions/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
dev-python/pytest[${PYTHON_USEDEP}]
>=dev-python/pytest-datadir-1.7.0[${PYTHON_USEDEP}]
dev-python/pyyaml[${PYTHON_USEDEP}]
"
distutils_enable_tests pytest
distutils_enable_sphinx doc dev-python/sphinx-rtd-theme
python_test() {
local EPYTEST_DESELECT=()
local EPYTEST_IGNORE=()
if ! has_version "dev-python/matplotlib[${PYTHON_USEDEP}]"; then
EPYTEST_DESELECT+=(
tests/test_image_regression.py::test_image_regression
)
fi
if ! has_version "dev-python/numpy[${PYTHON_USEDEP}]"; then
EPYTEST_IGNORE+=(
tests/test_ndarrays_regression.py
)
fi
if ! has_version "dev-python/pandas[${PYTHON_USEDEP}]"; then
EPYTEST_DESELECT+=(
tests/test_filenames.py::test_foo
tests/test_filenames.py::TestClass::test_foo
tests/test_filenames.py::TestClassWithIgnoredName::test_foo
)
EPYTEST_IGNORE+=(
tests/test_dataframe_regression.py
tests/test_num_regression.py
)
fi
if ! has_version "dev-python/pillow[${PYTHON_USEDEP}]"; then
EPYTEST_DESELECT+=(
tests/test_image_regression.py
)
fi
if [[ ${EPYTHON} == python3.14* ]] ; then
EPYTEST_DESELECT+=(
# Sensitive to warnings
tests/test_data_regression.py::test_regen_all
)
fi
epytest
}