Revert "net-print/gutenprint: drop 5.3.3-r1, 5.3.4-r2"

This reverts commit 0695d8b0bd.

Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James
2022-03-11 00:41:15 +00:00
parent 70c8abad51
commit b6d3cdb548
3 changed files with 175 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST gutenprint-5.3.3.tar.xz 5050624 BLAKE2B dbcf74169d0756d991bbdad7338a6e6f995f8eeedc2610677b327abee6aecc787d1cc35949f73c1d93ad274de7d467542b72a5fe0abf58fbc4ec6f21667cbad7 SHA512 d2c47eb4ccc3c46ccb2f1042682edf7443f5c57439ead72f49ecd10537cf967251bacf7ca7da29fb8dceecc7eebd55ed021f2594ff9fb6509bab543fab1dc8d6
DIST gutenprint-5.3.4.tar.xz 5341824 BLAKE2B 134e59c7dbf9c0ba95b91c717f1e6841f35520b55105feb1ba40b82785c825b8e2a2429990e78186a1455e5c6de9880f911438d514c53c56d05575dd4e2d68a4 SHA512 63de0b62edbe255a7efaaeab1dcd22577b7b46d7e0e48441b79977f19e76bf3862e4e8e18c55dd1f2e7392d555f9e8ee875ea53b90c689852d2343491a8fbcc8
@@ -0,0 +1,84 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="Ghostscript and cups printer drivers"
HOMEPAGE="http://gutenprint.sourceforge.net"
MY_P="${P/_/-}"
S="${WORKDIR}/${MY_P}"
SRC_URI="mirror://sourceforge/gimp-print/${MY_P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ppc ppc64 sparc x86"
IUSE="cups gimp gtk nls readline ppds static-libs"
REQUIRED_USE="gimp? ( gtk )"
BDEPEND="
virtual/pkgconfig
nls? ( sys-devel/gettext )
"
# gimp restriction: https://sourceforge.net/p/gimp-print/bugs/725/
CDEPEND="
dev-lang/perl
readline? ( sys-libs/readline:0= )
cups? ( >=net-print/cups-1.1.14 )
gimp? ( media-gfx/gimp:0/2 x11-libs/gtk+:2 )
gtk? ( x11-libs/gtk+:2 )
nls? ( virtual/libintl )
"
RDEPEND="${CDEPEND}"
DEPEND="${CDEPEND}"
RESTRICT="test"
DOCS=( AUTHORS ChangeLog NEWS README doc/gutenprint-users-manual.{pdf,odt} )
PATCHES=(
"${FILESDIR}"/${PN}-5.3.1-cflags.patch
)
src_configure() {
local myeconfargs=(
--enable-test
--disable-translated-cups-ppds
$(use_enable gtk libgutenprintui2)
$(use_with gimp gimp2)
$(use_with gimp gimp2-as-gutenprint)
$(use_with cups)
$(use_enable nls)
$(use_with readline)
$(use_enable static-libs static)
)
if use cups && use ppds; then
myeconfargs+=( --enable-cups-ppds --enable-cups-level3-ppds )
else
myeconfargs+=( --disable-cups-ppds )
fi
econf "${myeconfargs[@]}"
}
src_install() {
default
dodoc doc/FAQ.html
dodoc -r doc/gutenprintui2/html
rm -r "${ED}"/usr/share/gutenprint/doc || die
find "${ED}" -name '*.la' -exec rm -f '{}' + || die
}
pkg_postinst() {
if [[ ${ROOT} == / ]] && [[ -x /usr/sbin/cups-genppdupdate ]]; then
elog "Updating installed printer ppd files"
elog $(/usr/sbin/cups-genppdupdate)
else
elog "You need to update installed ppds manually using cups-genppdupdate"
fi
}
@@ -0,0 +1,90 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit autotools
DESCRIPTION="Ghostscript and cups printer drivers"
HOMEPAGE="http://gutenprint.sourceforge.net"
MY_P="${P/_/-}"
S="${WORKDIR}/${MY_P}"
SRC_URI="mirror://sourceforge/gimp-print/${MY_P}.tar.xz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ppc ppc64 sparc x86"
IUSE="cups gimp gtk nls readline ppds static-libs"
RESTRICT="test"
REQUIRED_USE="gimp? ( gtk )"
BDEPEND="
virtual/pkgconfig
nls? ( sys-devel/gettext )
"
# gimp restriction: https://sourceforge.net/p/gimp-print/bugs/725/
RDEPEND="
dev-lang/perl
cups? ( >=net-print/cups-1.1.14 )
gimp? (
media-gfx/gimp:0/2
x11-libs/gtk+:2
)
gtk? ( x11-libs/gtk+:2 )
readline? ( sys-libs/readline:0= )
"
DEPEND="${RDEPEND}"
DOCS=( AUTHORS ChangeLog NEWS README doc/gutenprint-users-manual.{pdf,odt} )
PATCHES=( "${FILESDIR}"/${PN}-5.3.1-cflags.patch )
src_prepare() {
default
# Needed for cflags patch
eautoreconf
}
src_configure() {
local myeconfargs=(
--enable-test
--disable-translated-cups-ppds
$(use_enable gtk libgutenprintui2)
$(use_with gimp gimp2)
$(use_with gimp gimp2-as-gutenprint)
$(use_with cups)
$(use_enable nls)
$(use_with readline)
$(use_enable static-libs static)
)
if use cups && use ppds; then
myeconfargs+=( --enable-cups-ppds --enable-cups-level3-ppds )
else
myeconfargs+=( --disable-cups-ppds )
fi
econf "${myeconfargs[@]}"
}
src_install() {
default
dodoc doc/FAQ.html
dodoc -r doc/gutenprintui2/html
rm -r "${ED}"/usr/share/gutenprint/doc || die
find "${ED}" -name '*.la' -delete || die
}
pkg_postinst() {
if [[ -x /usr/sbin/cups-genppdupdate ]]; then
elog "Updating installed printer ppd files"
elog $(/usr/sbin/cups-genppdupdate)
else
elog "You need to update installed ppds manually using cups-genppdupdate"
fi
}