kde-frameworks/extra-cmake-modules: 6.24.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-frameworks/extra-cmake-modules/Manifest

@@ -1 +1,2 @@
 DIST extra-cmake-modules-6.23.0.tar.xz 337824 BLAKE2B 21fe83d5c7ef94593ced840bffe870f783f051c91c5c082dfb9cbadf243db6f9087cfb9630e8e57d0a9ef3d9558580cead33a73ed4945177f8121317c6a96572 SHA512 ba76dc31d31fb4317236f3a0d828d3589ed1af77d7318dc84df849e425ecca845a4d4ca6898df0020cae49d9444870bcee2c001e650bf5c8fbe1b31b982c620a
+DIST extra-cmake-modules-6.24.0.tar.xz 337884 BLAKE2B 8dc787e007a4928dfd1856ae09e02bed038fd06bbd85850d0a1fe0db5852c61af5fbb3977302843af0011be6b422b4685b907fdd5cf55ad81d76f80af91263e9 SHA512 76fad7614dcdeb252a5f877e4d9e7957c2438f2bbd7d0fbe8ba420405c2748e55c64d984978f4a9cd2846cc0fdabe6b6c5dacf61cc2224ba5ca10db45a4657cf

kde-frameworks/extra-cmake-modules/extra-cmake-modules-6.24.0.ebuild

@@ -0,0 +1,81 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+CMAKE_QA_COMPAT_SKIP=1 # bug #964519 tests/ subdir is irrelevant
+PYTHON_COMPAT=( python3_{11..14} )
+QTMIN=6.10.1
+inherit cmake frameworks.kde.org python-any-r1
+
+DESCRIPTION="Extra modules and scripts for CMake"
+HOMEPAGE="https://invent.kde.org/frameworks/extra-cmake-modules"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-arch/libarchive[bzip2]"
+DEPEND="
+	test? (
+		>=dev-qt/qtbase-${QTMIN}:6[dbus,gui]
+		>=dev-qt/qtdeclarative-${QTMIN}:6
+	)
+"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+		>=dev-qt/qttools-${QTMIN}:6[assistant]
+	)
+	test? (
+		>=dev-qt/qtbase-${QTMIN}:6
+		>=dev-qt/qttools-${QTMIN}:6[linguist]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch"
+	"${FILESDIR}/${PN}-6.22.0-skip-ecm_add_test-early.patch"
+	"${FILESDIR}/${PN}-5.245.0-disable-qmlplugindump.patch"
+	"${FILESDIR}/${PN}-6.5.0-disable-appstreamtest.patch"
+	"${FILESDIR}/${PN}-6.5.0-disable-git-commit-hooks.patch"
+)
+
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
+		-DBUILD_QTHELP_DOCS=$(usex doc)
+		-DBUILD_HTML_DOCS=$(usex doc)
+		-DBUILD_MAN_DOCS=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+	)
+	if use test; then
+		mycmakeargs+=( -DQT_MAJOR_VERSION=6 ) # bug 938316
+	fi
+
+	cmake_src_configure
+}
+
+src_test() {
+	local CMAKE_SKIP_TESTS=(
+		# passes, but then breaks src_install
+		ECMToolchainAndroidTest
+		# broken, bug #627806
+		ECMPoQmToolsTest
+		# can not possibly succeed in releases, bug #764953
+		KDEFetchTranslations
+	)
+	# possible race condition with multiple jobs, bug #701854
+	cmake_src_test -j1
+}