dev-python/sentry-sdk: Bump to 1.2.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/sentry-sdk/Manifest

@@ -1 +1,2 @@
 DIST sentry-sdk-1.1.0.tar.gz 215946 BLAKE2B 486f32430a03d42c73814195ef16ec4efc71512faca197d8020fad7b3d1e7350ec619ef453075bc4fc4e0e454f3aa6eda41ec29b88af19d75b5f6a10273db325 SHA512 500d0d3add4bf8e74f2e34d6c00491f4bbd45a2226cc0ee93ca0f63f5ae5aea61be6730f845d50e10909c9ede6918ec6cfb90e5ebe80b753dd634ac9a9238061
+DIST sentry-sdk-1.2.0.tar.gz 218371 BLAKE2B dcba23b246d4620f93b82a07a9fa9c73ae8b67d54e9a690fc53c1b08580433b2d37a50f29a47e01c7cdcc29eef45cc0b67e96f1e9b333496002ceea5ce7388a9 SHA512 86705fab17331bf5cbe4dbb25562d80b5b080d2bee0a9bb2c153bb379e63ada10465bd5fdfa24d71fc50cc1d80d5afd3e569a779f2a11bde671cc6782ddca347

dev-python/sentry-sdk/sentry-sdk-1.2.0.ebuild

@@ -0,0 +1,71 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..9} )
+inherit distutils-r1
+
+DESCRIPTION="Python client for Sentry"
+HOMEPAGE="https://sentry.io/ https://pypi.org/project/sentry-sdk/"
+SRC_URI="https://github.com/getsentry/sentry-python/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/sentry-python-${PV}"
+
+LICENSE="PSF-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/urllib3[${PYTHON_USEDEP}]
+	dev-python/certifi[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/asttokens[${PYTHON_USEDEP}]
+		dev-python/django[${PYTHON_USEDEP}]
+		dev-python/executing[${PYTHON_USEDEP}]
+		dev-python/eventlet[${PYTHON_USEDEP}]
+		dev-python/fakeredis[${PYTHON_USEDEP}]
+		dev-python/flask-login[${PYTHON_USEDEP}]
+		dev-python/gevent[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/pyrsistent[${PYTHON_USEDEP}]
+		dev-python/pytest-aiohttp[${PYTHON_USEDEP}]
+		dev-python/pytest-django[${PYTHON_USEDEP}]
+		dev-python/pytest-forked[${PYTHON_USEDEP}]
+		dev-python/pytest-localserver[${PYTHON_USEDEP}]
+		dev-python/werkzeug[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local deselect=(
+		# tests require Internet access
+		tests/integrations/httpx/test_httpx.py
+		tests/integrations/requests/test_requests.py
+		tests/integrations/stdlib/test_httplib.py
+		# wtf is it supposed to do?!
+		tests/integrations/gcp/test_gcp.py
+		# hangs
+		'tests/test_transport.py::test_transport_works[eventlet'
+		# TODO
+		'tests/test_basics.py::test_auto_enabling_integrations_catches_import_error'
+		tests/test_client.py::test_databag_depth_stripping
+		tests/test_client.py::test_databag_string_stripping
+		tests/test_client.py::test_databag_breadth_stripping
+		# incompatible version?
+		tests/integrations/falcon/test_falcon.py
+		# test_circular_references: apparently fragile
+		'tests/integrations/threading/test_threading.py::test_circular_references'
+		# test for new feature, fails with IndexError
+		tests/integrations/wsgi/test_wsgi.py::test_session_mode_defaults_to_request_mode_in_wsgi_handler
+	)
+
+	# Prevent tests/integrations/modules/test_modules.py:test_basic failure
+	# Needs to detect sentry-sdk in the installed modules
+	distutils_install_for_testing
+
+	epytest ${deselect[@]/#/--deselect }
+}