media-gfx/eog-plugins: bump to 3.16.6 for translation updates, don't default enable flickr

flickr pulls in postr, which in its current latest version drags in pygtk:2 and co,
so lets not IUSE default to it for now; modern flickr upload support is in gnome-photos.

media-gfx/eog-plugins/Manifest

@@ -1 +1,2 @@
 DIST eog-plugins-3.16.5.tar.xz 397044 SHA256 9de42235cc7dabc4e4b228c1a27ead4ee386cf5a3cc75fdb7ea12355d408108a SHA512 08a92cec37155fe4875de542865d583d2a1eca497af4caf94d21b38c7672685c27fcff23f18c50261b5f8012824931a531e62a8eb77167d6b3a5e375c83dfc40 WHIRLPOOL eccccce1b00495da09747866842cddbea044ef5320e05693c076d122bfd22457c8ea8099b31b5087c5e8836e9133a2c00df07ab243298a6035934269ef78dbdc
+DIST eog-plugins-3.16.6.tar.xz 398836 SHA256 51ca356a29bbedfc48ce3fd1de1efe9339af38020c301df79dae6b67cd34ed96 SHA512 e3bff786785ae36a41bc7c5fcb3cf75233595777409f373c4a6597fa6e432f72c7a75608e09ab66e1033ca0d12e3855346d7f7e0c571014b5aaef40184a3383b WHIRLPOOL 277016a9939e213f40c5612b1afbdf7119951eecd346bb5d70b4665d07a1aa7082add1b2fe51a6e3c3b71ea5dd7c2e55484ac2af3792fc7b1facdaadc78cea2a

media-gfx/eog-plugins/eog-plugins-3.16.6.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python{3_4,3_5} )
+
+inherit gnome2 python-r1
+
+DESCRIPTION="Eye of GNOME plugins"
+HOMEPAGE="https://wiki.gnome.org/Apps/EyeOfGnome/Plugins"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="+exif flickr map picasa +python"
+REQUIRED_USE="
+	map? ( exif )
+	python? ( ^^ ( $(python_gen_useflags '*') ) )
+"
+
+RDEPEND="
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libpeas-0.7.4:=
+	>=media-gfx/eog-3.15.90
+	>=x11-libs/gtk+-3.14:3
+	exif? ( >=media-libs/libexif-0.6.16 )
+	flickr? ( media-gfx/postr )
+	map? (
+		media-libs/libchamplain:0.12[gtk]
+		>=media-libs/clutter-1.9.4:1.0
+		>=media-libs/clutter-gtk-1.1.2:1.0 )
+	picasa? ( >=dev-libs/libgdata-0.9.1:= )
+	python? (
+		${PYTHON_DEPS}
+		>=dev-libs/glib-2.32:2[dbus]
+		dev-libs/libpeas:=[gtk,python,${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		gnome-base/gsettings-desktop-schemas
+		media-gfx/eog[introspection]
+		x11-libs/gtk+:3[introspection]
+		x11-libs/pango[introspection] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/intltool-0.50.1
+	sys-devel/gettext
+	virtual/pkgconfig
+"
+
+pkg_setup() {
+	use python && [[ ${MERGE_TYPE} != binary ]] && python_setup
+}
+
+src_configure() {
+	local plugins="fit-to-width,send-by-mail,hide-titlebar,light-theme"
+	use exif && plugins="${plugins},exif-display"
+	use flickr && plugins="${plugins},postr"
+	use map && plugins="${plugins},map"
+	use picasa && plugins="${plugins},postasa"
+	use python && plugins="${plugins},slideshowshuffle,pythonconsole,fullscreenbg,export-to-folder,maximize-windows"
+	gnome2_src_configure \
+		$(use_enable python) \
+		--with-plugins=${plugins}
+}