dev-python/black: add 23.9.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/black/Manifest

@@ -1 +1,2 @@
 DIST black-23.7.0.tar.gz 586177 BLAKE2B 4bb50b6c7409a97aa277f1048c17101a1c91368b9269cf4c08d3052c036887d2ed6e5f1f2e044c14f41bf2d969d65183413c2a9810f12d96cbf09778c9b1310e SHA512 78d5e87bfef4dcaff007455e8c72dcd45f9374c09da6f4ba45ae7caa980005d1bc984c68fa44d4abf7969a376a4039546e7e8f537c3aa1331d213e13dcbe3941
+DIST black-23.9.0.tar.gz 588540 BLAKE2B f3c94acb1af6c4bf1ada948d4ea7b7cd243184b920fab7e741d9e5ee4a82e163e5570ca1451424ea379362ae1755907e4b5e63b517a4e420d6cbe9d69655a10f SHA512 4d1ae51353c7a0a4113796fcc10824228d5bd9a0f19474efc8c5e3a9b929433a586f058521fd1dae35301e9e33e6d231b0584f81514104ac5c787f8e55cb9fa8

dev-python/black/black-23.9.0.ebuild

@@ -0,0 +1,53 @@
+# Copyright 2020-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1 multiprocessing optfeature pypi
+
+DESCRIPTION="The uncompromising Python code formatter"
+HOMEPAGE="
+	https://black.readthedocs.io/en/stable/
+	https://github.com/psf/black/
+	https://pypi.org/project/black/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
+
+RDEPEND="
+	>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
+	>=dev-python/mypy_extensions-0.4.3[${PYTHON_USEDEP}]
+	>=dev-python/packaging-22.0[${PYTHON_USEDEP}]
+	>=dev-python/pathspec-0.9.0[${PYTHON_USEDEP}]
+	>=dev-python/platformdirs-2[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-1.1.0[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	dev-python/hatch-vcs[${PYTHON_USEDEP}]
+	test? (
+		>=dev-python/aiohttp-3.7.4[${PYTHON_USEDEP}]
+		dev-python/aiohttp-cors[${PYTHON_USEDEP}]
+		dev-python/colorama[${PYTHON_USEDEP}]
+		dev-python/parameterized[${PYTHON_USEDEP}]
+		dev-python/pytest-xdist[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	epytest -n "$(makeopts_jobs)" --dist=worksteal
+}
+
+pkg_postinst() {
+	optfeature "blackd - HTTP API for black" \
+		"dev-python/aiohttp dev-python/aiohttp-cors"
+}