x11-misc/qtfm: Version 5.9 (bug #592194 by Vincent Hardy).

Package-Manager: Portage-2.3.19, Repoman-2.3.6

x11-misc/qtfm/Manifest

@@ -1 +1,2 @@
 DIST qtfm-5.5.tar.gz 149667 BLAKE2B f369495fd5fba183e7bb5b38db61a8a667d5835b42cf78f424d0db4bb4f0c7fcb0856578df30cb50547c7799fa16147d17951b72d99398937774bd097487ccbf SHA512 0d592b482f35c76b424cc581394d34299bb93367f287f57718d640df256f352fef7e389a8370889d0d78ca8afb9868cdfb56ae15671614e279365b72f9e629e0
+DIST qtfm-5.9.zip 172616 BLAKE2B 50219cb9afbca78b4fe7767631e91008254f6a4e745c3f1b87b821dc49655117d6d61a0aeb37cb1771641aac6b5ccfa8eefaa6e2f6d453c68061594e47bf5c5e SHA512 7686a84f1678e1f04f439d65290f5c93da25fbe80487a37f4ce32eae0d29d7a03a169d3dd9cbc81c2b678f54d9fdc01967b6c1b1cb8a19cf37a910a19918a2ba

x11-misc/qtfm/qtfm-5.9.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit qmake-utils xdg-utils
+
+DESCRIPTION="A small, lightweight file manager for desktops based on pure Qt"
+HOMEPAGE="http://www.qtfm.org/"
+SRC_URI="https://dev.gentoo.org/~jer/${P}.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+RDEPEND="
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5
+	dev-qt/qtwidgets:5
+	sys-apps/file
+"
+DEPEND="
+	${RDEPEND}
+	dev-qt/qtchooser
+"
+PATCHES=( "${FILESDIR}"/${PN}-5.5-gcc6.patch )
+S=${WORKDIR}/${PN}-master
+
+QTFM_LINGUAS="
+	da de es fr it pl ru sr sv zh zh_TW
+"
+for lingua in ${QTFM_LINGUAS}; do
+	IUSE+=" l10n_${lingua/_/-}"
+done
+
+src_prepare() {
+	rm translations/${PN}_XX.ts || die
+
+	default
+
+	sed -i \
+		-e '/MimeType=/s|$|;|' \
+		-e '/Categories=/s|$|;System;FileTools;|' \
+		${PN}.desktop || die
+}
+
+src_configure() {
+	if [[ -n "${L10N}" ]]; then
+		local lingua
+		for lingua in ${QTFM_LINGUAS}; do
+			if ! use l10n_${lingua/_/-}; then
+				sed -i -e "s:translations/${PN}_${lingua}.qm::g" ${PN}.pro || die
+				rm translations/${PN}_${lingua}.ts || die
+			fi
+		done
+	fi
+
+	lrelease translations/*.ts || die
+	eqmake5
+}
+
+src_install() {
+	emake INSTALL_ROOT="${D}" install
+
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}