media-libs/libopenmpt: Version bump to 0.8.1

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

media-libs/libopenmpt/Manifest

@@ -1 +1,2 @@
 DIST libopenmpt-0.7.13+release.autotools.tar.gz 1681351 BLAKE2B d75df89e85531e85974bd532773e8ed16440211448790779191a61a629dde33ef7280bcc1c82e6ac6aeb313f7f568bc7a2abe707772801f52c271977b88eff8e SHA512 04e63c635dd6c63c2ce79db4eff971f10e4d14a12c7f143fc317a4b5f5188cd8cbf84fc5121057c2beff3a3e6b9b48767c02b9eb5c569accab3e6ff7322a9690
+DIST libopenmpt-0.8.1+release.autotools.tar.gz 1760147 BLAKE2B 7e0f300d4d93fb179080c7b7b83ba0df6b9fe00eee46c9e798a44f1a9f98f3a4de9d1ba3b4a1ac2585eef2e1ac857b76ce8cb1389c866b581be2a907ab99fb72 SHA512 f306fe15cbb7f2d0fd830d6237c52fb60196d5d011ef63f652091bde4780bee47d0e424cbb82431cdb2578f59dd426a3c8f8c914be7fecaa75fe4992a0ccba70

media-libs/libopenmpt/libopenmpt-0.8.1.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit multilib-minimal
+
+MY_P="libopenmpt-${PV}+release.autotools"
+DESCRIPTION="Library to decode tracked music files (modules)"
+HOMEPAGE="https://lib.openmpt.org/libopenmpt/"
+SRC_URI="https://lib.openmpt.org/files/libopenmpt/src/${MY_P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="examples mp3 ogg static-libs test vorbis zlib"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	mp3? ( media-sound/mpg123[${MULTILIB_USEDEP}] )
+	ogg? ( media-libs/libogg[${MULTILIB_USEDEP}] )
+	vorbis? ( media-libs/libvorbis[${MULTILIB_USEDEP}] )
+	zlib? ( sys-libs/zlib[${MULTILIB_USEDEP}] )
+"
+
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+ECONF_SOURCE="${S}"
+
+multilib_src_configure() {
+	# A lot of these optional dependencies relate to openmpt123, which
+	# we package separately, so we disable them here.
+	econf \
+		$(use_enable static-libs static) \
+		--disable-openmpt123 \
+		--disable-examples \
+		$(use_enable test tests) \
+		--disable-doxygen-doc \
+		$(use_with zlib) \
+		$(use_with mp3 mpg123) \
+		$(use_with ogg) \
+		$(use_with vorbis) \
+		$(use_with vorbis vorbisfile) \
+		--without-pulseaudio \
+		--without-portaudio \
+		--without-portaudiocpp \
+		--without-sdl2 \
+		--without-sndfile \
+		--without-flac
+}
+
+multilib_src_install_all() {
+	rm -f \
+		"${ED}"/usr/*/*.la \
+		"${ED}"/usr/share/doc/${P}/LICENSE || die
+
+	if ! use examples; then
+		rm -r "${ED}"/usr/share/doc/${P}/examples || die
+	fi
+}