gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-php/libvirt-php: bump to v0.5.8

Browse Source 
Signed-off-by: Michal Privoznik <michal.privoznik@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/35535
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Michal Privoznik
2024-02-15 08:24:59 +01:00
committed by Sam James
parent cc0a7d0944
commit b414fef956
2 changed files with 72 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-php/libvirt-php/Manifest
View File

@@ -1,2 +1,3 @@
DIST libvirt-php-0.5.6.tar.xz 386372 BLAKE2B 30d6a1c8dd18a4bd9d46e9c20551978fa0c20f2d671a359fdbf86def5166df7f882e65c509087efe0acef7d0dc468b3eb520689f9e7ba552e966809c8f647390 SHA512 5d1b3a2afc697051a5a0d4750ce4d02b31f482b1c17ef2cf4a593b705de438d8ccb4b1543ce6b2520b450734b3634e64ccf9200227f5681cbd2daad5a9f5ee9c
DIST libvirt-php-0.5.7.tar.xz 389380 BLAKE2B c8189ffdeb29a056ef959624cd46a18ce7e4e00df6a42bfb3d6349ee8aa3865a4d66b82aed9ee4f68aa7f9761adb8eb8b62bd15d7c6e8e17c187ae44eba71a86 SHA512 ecc640ce2c936f59824212eca36bbe3ae13c560854e0d86da9f1d4d02373751f974b374915ded57d74636c0443c09c895857e8701204fbf49c402c1f315ae0b7
DIST libvirt-php-0.5.8.tar.xz 392316 BLAKE2B 5c1746512a405aaa32840b47f867804d854006a3ed38db168b8a60b8a6d5c4c454b5070c71a7dce8669377842c8063b78bb1894c7a69a8ff439b770f3867a3d2 SHA512 efff730f101a2b4210d720bf1e9a7bb86b41caaf45de31241be05a64ea71b8bca52c73b23a39137d5849ac9f4d2d309acb72111e3e64f0b47211991e4a6a2d9a

71
dev-php/libvirt-php/libvirt-php-0.5.8.ebuild Normal file
View File

@@ -0,0 +1,71 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI="8"
PHP_EXT_NAME="libvirt-php"
PHP_EXT_SKIP_PHPIZE="yes"
USE_PHP="php8-1 php8-2 php8-3"
PHP_EXT_ECONF_ARGS=()
inherit php-ext-source-r3 autotools
DESCRIPTION="PHP bindings for libvirt"
HOMEPAGE="http://libvirt.org/php/"
SRC_URI="http://libvirt.org/sources/php/${P}.tar.xz"
LICENSE="LGPL-2.1"
SLOT="0"
KEYWORDS="~amd64"
IUSE="doc"
RDEPEND="app-emulation/libvirt
dev-libs/libxml2"
DEPEND="${RDEPEND}
dev-libs/libxslt
virtual/pkgconfig
doc? ( app-text/xhtml1 )"
DOCS=( ChangeLog NEWS README )
src_unpack() {
default
# create the default modules directory to be able
# to use the php-ext-source-r3 eclass to configure/build
ln -s src "${S}/modules" || die
}
src_prepare() {
php-ext-source-r3_src_prepare
local slot
for slot in $(php_get_slots); do
php_init_slot_env "${slot}"
eautoreconf
done
}
src_install() {
local slot
for slot in $(php_get_slots); do
php_init_slot_env ${slot}
insinto "${EXT_DIR}"
doins "src/.libs/${PHP_EXT_NAME}.so"
done
php-ext-source-r3_createinifiles
einstalldocs
if use doc ; then
docinto html
dodoc -r docs/*
fi
}
src_test() {
for slot in $(php_get_slots); do
php_init_slot_env ${slot}
default
done
}