www-client/vivaldi-snapshot: Add version 6.1.3035.50

Signed-off-by: James Le Cuirot <chewi@gentoo.org>
This commit is contained in:
James Le Cuirot
2023-06-09 20:32:44 +01:00
parent 0faf645c97
commit b3e2eea5c1
2 changed files with 221 additions and 0 deletions
+3
View File
@@ -4,3 +4,6 @@ DIST vivaldi-snapshot_6.1.3023.3-1_armhf.deb 93642376 BLAKE2B 636800843df0d5ce40
DIST vivaldi-snapshot_6.1.3035.3-1_amd64.deb 98024212 BLAKE2B 492ac02599918af86cb282b33c1118b0b32202455d0bc8299bc990bd5d257111a350fda458de1744b2ebcccedeb4ff4884e4da11e5473ec9defd65eed847d2e0 SHA512 decf441c019b91b49fc17fa5e49d503e9a2e8a0fc25bf96acc8570f0af74f44a460b4c498a225d99501074399dba8c785829dc2edc4a31f0f001df0e73c15007
DIST vivaldi-snapshot_6.1.3035.3-1_arm64.deb 93483324 BLAKE2B 838d9eb9d6d4f8765e73d18d581898584121b99ae3747372d6a12b818c11e6de3ff95b69e6804d311d9d063006352eab9b59257c8d5a0b9ad50282cd70dd53f5 SHA512 5a01e5b022bace6b32cc70e3613ebd374bbc7d0a6d74871895d67ff3b28ede148966d866094d9621866f949f7b0cde8a139582dcffd01671422f6d92403cf60f
DIST vivaldi-snapshot_6.1.3035.3-1_armhf.deb 93678588 BLAKE2B 3254e89a873ac1a48acbd3c5f89c7384120093197163af2a01cba23e3b0eb3322f0cc2b653f377b9bda5908f49b273aca22102f450f4e5db54a26c27e6956545 SHA512 0c6fb32bb14ab62cc8714f7612cc0b54036b75755829cc3ddf1c5f004bc5c207fc8f2d5857d79e8d596131ce8339a36e316e251e9d4ece6bf95e1f45fa25bbf4
DIST vivaldi-snapshot_6.1.3035.50-1_amd64.deb 97845924 BLAKE2B 30c03e84b707d86a689a51a54258302ce4f4b9550596c12c9f9cebcb320e1399f89f842c05fc09a1687ac0a62c5aec59ce4e123009cbf3917f2338a4e17f7a1b SHA512 97b0872da2b97371848992f20ac32d830b72f26d26499591f31f7fae85ff8610f42e383868758db61c17dc76ecffb6bf1425db586807512ba023cb5b73f7578a
DIST vivaldi-snapshot_6.1.3035.50-1_arm64.deb 93465764 BLAKE2B cc37d4fd4371354825bb147a3147f75c51df9adce52eca2e3e120942d13f9cbb983671464964d5a206ad2f55b432e59b71abac43dde69b430153f67f7a7721ec SHA512 0613b0a089fd6b70e62acac7da1a79c46b00c1a41b62e6da4d6a2c5ff7f9caaff6c6766a4bca422fb93a68840fad3e7ef0aaa180783c92c8dd0d1670eef0fa73
DIST vivaldi-snapshot_6.1.3035.50-1_armhf.deb 93617388 BLAKE2B 4b856b3f8f4ac7bd60cc84691f6bf57e0d755a3f7bf9840ac9d5af373a4052057c555a29826b20c867879bf9a166a4b6d38c6654cbafb7d323e4b1f9a5573a8c SHA512 b7194639f50aa89b5ace81a62330a905cb5721f1406ea2e20cc3f01f46d8468aa2046bd775f8e9d30de3b818528e82046e89e075c943327d16fe8f7cb5a8b717
@@ -0,0 +1,218 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
CHROMIUM_VERSION="114"
CHROMIUM_LANGS="
af
am
ar
az
be
bg
bn
ca
ca-valencia
cs
da
de
de-CH
el
en-GB
en-US
eo
es
es-419
es-PE
et
eu
fa
fi
fil
fr
fy
gd
gl
gu
he
hi
hr
hu
hy
id
io
is
it
ja
jbo
ka
kab
kn
ko
ku
lt
lv
mk
ml
mr
ms
nb
nl
nn
pa
pl
pt-BR
pt-PT
ro
ru
sc
sk
sl
sq
sr
sr-Latn
sv
sw
ta
te
th
tr
uk
ur
vi
zh-CN
zh-TW
"
inherit chromium-2 desktop linux-info unpacker xdg
VIVALDI_PN="${PN/%vivaldi/vivaldi-stable}"
VIVALDI_HOME="opt/${PN}"
DESCRIPTION="A browser for our friends"
HOMEPAGE="https://vivaldi.com/"
if [[ ${PV} = *_p* ]]; then
DEB_REV="${PV#*_p}"
else
DEB_REV=1
fi
KEYWORDS="-* ~amd64 ~arm ~arm64"
VIVALDI_BASE_URI="https://downloads.vivaldi.com/${VIVALDI_PN#vivaldi-}/${VIVALDI_PN}_${PV%_p*}-${DEB_REV}_"
RE="\bamd64\b"; [[ ${KEYWORDS} =~ ${RE} ]] && SRC_URI+=" amd64? ( ${VIVALDI_BASE_URI}amd64.deb )"
RE="\barm\b"; [[ ${KEYWORDS} =~ ${RE} ]] && SRC_URI+=" arm? ( ${VIVALDI_BASE_URI}armhf.deb )"
RE="\barm64\b"; [[ ${KEYWORDS} =~ ${RE} ]] && SRC_URI+=" arm64? ( ${VIVALDI_BASE_URI}arm64.deb )"
RE="\bx86\b"; [[ ${KEYWORDS} =~ ${RE} ]] && SRC_URI+=" x86? ( ${VIVALDI_BASE_URI}i386.deb )"
LICENSE="Vivaldi"
SLOT="0"
IUSE="gtk proprietary-codecs qt5 widevine"
RESTRICT="bindist mirror"
RDEPEND="
|| (
>=app-accessibility/at-spi2-core-2.46.0:2
( app-accessibility/at-spi2-atk dev-libs/atk )
)
dev-libs/expat
dev-libs/glib:2
dev-libs/nspr
dev-libs/nss
media-libs/alsa-lib
media-libs/mesa[gbm(+)]
net-print/cups
sys-apps/dbus
x11-libs/cairo
x11-libs/libdrm
x11-libs/libX11
x11-libs/libxcb
x11-libs/libXcomposite
x11-libs/libXdamage
x11-libs/libXext
x11-libs/libXfixes
x11-libs/libxkbcommon
x11-libs/libXrandr
x11-libs/pango[X]
gtk? ( gui-libs/gtk:4 x11-libs/gtk+:3 )
proprietary-codecs? ( media-video/ffmpeg-chromium:${CHROMIUM_VERSION} )
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtwidgets:5
)
widevine? ( www-plugins/chrome-binary-plugins )
"
QA_PREBUILT="*"
CONFIG_CHECK="~CPU_FREQ"
S="${WORKDIR}"
src_unpack() {
unpack_deb ${A}
}
src_prepare() {
# Rename docs directory to our needs.
mv usr/share/doc/{${VIVALDI_PN},${PF}}/ || die
# Decompress the docs.
gunzip usr/share/doc/${PF}/changelog.gz || die
# The appdata directory is deprecated.
mv usr/share/{appdata,metainfo}/ || die
# Remove cron job for updating from Debian repos.
rm etc/cron.daily/${PN} ${VIVALDI_HOME}/cron/${PN} || die
rmdir etc/{cron.daily/,} ${VIVALDI_HOME}/cron/ || die
# Remove scripts that will most likely break things.
rm -vf ${VIVALDI_HOME}/update-{ffmpeg,widevine} || die
pushd ${VIVALDI_HOME}/locales > /dev/null || die
rm ja-KS.pak || die # No flag for Kansai as not in IETF list.
chromium_remove_language_paks
popd > /dev/null || die
if use proprietary-codecs; then
rm ${VIVALDI_HOME}/lib/libffmpeg.so || die
rmdir ${VIVALDI_HOME}/lib || die
fi
if ! use qt5; then
rm ${VIVALDI_HOME}/libqt5_shim.so || die
fi
eapply_user
}
src_install() {
mv */ "${D}" || die
dosym ../../${VIVALDI_HOME}/${PN} /usr/bin/${VIVALDI_PN}
fperms 4711 /${VIVALDI_HOME}/vivaldi-sandbox
local logo size
for logo in "${ED}"/${VIVALDI_HOME}/product_logo_*.png; do
size=${logo##*_}
size=${size%.*}
newicon -s "${size}" "${logo}" ${PN}.png
done
if use proprietary-codecs; then
dosym ../../usr/$(get_libdir)/chromium/libffmpeg.so.${CHROMIUM_VERSION} \
/${VIVALDI_HOME}/libffmpeg.so.$(ver_cut 1-2)
fi
if use widevine; then
dosym ../../usr/$(get_libdir)/chromium-browser/WidevineCdm \
/${VIVALDI_HOME}/WidevineCdm
else
rm "${ED}"/${VIVALDI_HOME}/WidevineCdm || die
fi
case ${PN} in
vivaldi) dosym ${VIVALDI_PN} /usr/bin/${PN} ;;
vivaldi-snapshot) dosym ${PN} /${VIVALDI_HOME}/vivaldi ;;
esac
}