media-video/motion: add 4.5.1

Closes: https://bugs.gentoo.org/727056
Closes: https://bugs.gentoo.org/820383
Closes: https://bugs.gentoo.org/834407
Signed-off-by: Johannes Willem Fernhout <hfern@fernhout.info>
Closes: https://github.com/gentoo/gentoo/pull/29330
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

media-video/motion/Manifest

@@ -1 +1,2 @@
 DIST motion-release-4.3.2.tar.gz 849378 BLAKE2B 2ff49f44bb1d57123760860ae17cc241ecabf3d045ac0c45e1ca08ce3ac8be2fec308492472c37c0d869bc21a7c04658c923c763f9b8f6b547403fc094b03196 SHA512 df54297eebc44b3bc50fd40890c69a9cbbfc5936224bf7027065364e794d7201ceadd99ac99bf43113ec3368f2b5ca435d2956258b9c774e03a6750b41346a7c
+DIST motion-release-4.5.1.tar.gz 856665 BLAKE2B 59ae638113c7f08ced4b18d7c4f19e3b3f1850ba0cd4c224b300be5ac65ae3b45aa391f26f506a91bb4c38a47b552c71db846d2b3217ccf0b2f5799873ab7ddb SHA512 3b8b60ad4f41c37cc215aa575b0295ee99b15f2d32cbf3393c0f7cdd8d87616cca1c00e11cb7bf74e4afa285caa094f08df3ba62ab21dcb28a48336e3ff5803e

media-video/motion/motion-4.5.1.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools readme.gentoo-r1 systemd
+
+DESCRIPTION="A software motion detector"
+HOMEPAGE="https://motion-project.github.io"
+SRC_URI="https://github.com/Motion-Project/${PN}/archive/release-${PV}.tar.gz -> ${PN}-release-${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="ffmpeg mariadb mmal mysql postgres sqlite v4l webp"
+
+RDEPEND="
+	acct-group/motion
+	acct-user/motion
+	net-libs/libmicrohttpd:=
+	media-libs/libjpeg-turbo:=
+	>=sys-devel/gettext-0.19
+	ffmpeg? ( media-video/ffmpeg:0= )
+	mariadb? ( dev-db/mariadb-connector-c )
+	mmal? ( media-libs/raspberrypi-userland )
+	mysql? ( dev-db/mysql-connector-c )
+	postgres? ( dev-db/postgresql:= )
+	sqlite? ( dev-db/sqlite:3 )
+	webp? ( media-libs/libwebp:= )
+"
+DEPEND="${RDEPEND}
+	v4l? (
+		media-libs/libv4l
+		virtual/os-headers
+	)
+"
+DISABLE_AUTOFORMATTING="yes"
+DOC_CONTENTS="
+You need to setup a configuraton file (/etc/motion/motion.conf) before
+running motion for the first time.
+
+If motion is built with the mysql or mariadb use flags then please make
+sure to configure a matching database_type in the config file.
+
+Motion runs by default under user motion and group motion:
+- change this if needed in /etc/conf.d/motion
+- or add users who need access to the output files to the motion group
+
+To install motion as a service, use:
+- rc-update add motion default # with OpenRC
+- systemctl enable motion.service # with systemd
+"
+
+S="${WORKDIR}"/${PN}-release-${PV}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_with ffmpeg) \
+		$(use_with mariadb) \
+		$(use_with mmal) \
+		$(use_with mysql) \
+		$(use_with postgres pgsql) \
+		$(use_with sqlite sqlite3) \
+		$(use_with v4l v4l2) \
+		$(use_with webp) \
+		--without-optimizecpu
+}
+
+src_install() {
+	emake \
+		DESTDIR="${D}" \
+		docdir=/usr/share/doc/${PF} \
+		examplesdir=/usr/share/doc/${PF}/examples \
+		install
+
+	newinitd "${FILESDIR}/motion.initd-r5" ${PN}
+	newconfd "${FILESDIR}/motion.confd-r5" ${PN}
+	systemd_newunit "${FILESDIR}/${PN}.service-r4" "${PN}.service"
+	readme.gentoo_create_doc
+	readme.gentoo_print_elog
+}