kde-apps/kget: 25.04.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/kget/Manifest

@@ -1,2 +1,3 @@
 DIST kget-24.12.3.tar.xz 4913524 BLAKE2B 65acbe964af7db92d64b4a49f0597f377ae6f786d8be9d180c64a4c0e663d280d7bc23d74d8762fed765c9d93f0b24ec43e4cdf1f912dd9ea9026835e695630e SHA512 f333e348bfbe05b4df5d826b9d67eaee989da94a80b8617d84642db78ec9820dbab93f072b6801750c91250e87c0a71b020fc2765da7d198953db9b67ffd5af2
 DIST kget-25.04.2.tar.xz 4853484 BLAKE2B a42ec50c67b330c6ba71d28b9eeeede2cbdd00bf1f9fd02982a995d2333e31d2a0d5035ec77ffe46a72609ab6e1c9a164ae82d81eb52cb429927df31ff86070d SHA512 3ab4ff308f0c956301d2264935d91909300e8c8c0b9f5a80f831e6783757a2fd484ee16e433c3de0d762e8c304988a2476814a852bc35035f05768f73304fcc3
+DIST kget-25.04.3.tar.xz 4853416 BLAKE2B be62c2e85ab6dead8e3b8b288486d8adfab093ec0436f92bb88699df18add360b767365fc2739057d19a1fb6735002a6830e2feb46f8aaa567e72066edeb5df3 SHA512 077dbe9671089e23a29e9eb94ec65c3af308ed7961060c10954d25cc9c9c80aa44d4bf4125b17192d34309e622c2deb8675c0bb7f337f797ecb82ad88b62e0f9

kde-apps/kget/kget-25.04.3.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+KFMIN=6.13.0
+QTMIN=6.7.2
+inherit ecm gear.kde.org xdg
+
+DESCRIPTION="Advanced download manager by KDE"
+HOMEPAGE="https://apps.kde.org/kget/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="bittorrent gpg mms sqlite"
+
+RDEPEND="
+	>=app-crypt/qca-2.3.7:2[qt6(+)]
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,network,sql,widgets,xml]
+	>=kde-frameworks/kcmutils-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kitemviews-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/knotifyconfig-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	bittorrent? ( net-libs/libktorrent:6 )
+	gpg? ( dev-libs/qgpgme:= )
+	mms? ( media-libs/libmms )
+	sqlite? ( dev-db/sqlite:3 )
+"
+DEPEND="${RDEPEND}"
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package bittorrent KTorrent6)
+		$(cmake_use_find_package gpg Gpgmepp)
+		$(cmake_use_find_package gpg QGpgmeQt6)
+		$(cmake_use_find_package mms LibMms)
+		$(cmake_use_find_package sqlite SQLite3)
+	)
+
+	ecm_src_configure
+}
+
+src_test() {
+	# bug 756817: schedulertest fails, see also upstream commit 45735cfa
+	# filedeletertest hangs.
+	local myctestargs=(
+		-E "(schedulertest|filedeletertest)"
+	)
+
+	ecm_src_test
+}