app-admin/vault: Bump to version 1.1.3

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Zac Medico <zmedico@gentoo.org>

app-admin/vault/Manifest

@@ -5,3 +5,5 @@ DIST vault-1.1.0-webui.tar.xz 1278712 BLAKE2B f0a61d644f613e14e1e8d2adcb894a9cc4
 DIST vault-1.1.0.tar.gz 25943119 BLAKE2B 44a7e339a7ab5e5ecfa33b70f28424b45305714df9eccee1286bdc063e3b1036f7ef830138df54482257a112b03c8e7289f921ad4f353aa37aff8ad06cb405c0 SHA512 b0bc32f438e8432d849aa896f610c9532fa923384d40749efe49985d64a91f4768a3309af449efd8c8ab4604ecdb2474c39999bfe196f0f876894f788618ae61
 DIST vault-1.1.2-webui.tar.xz 1281868 BLAKE2B 9c3662dabfd9403fda4a8acd8f9a86ff867b1cdafb5e7fb01c426e1f83fa33fc7a9bce27f70991fbed4a1e0b5cacd05b20d24644521487bd1746cb83fe1d9eaa SHA512 a33ee124592faa9e7aa02093d4219f1706a34c97159d9e32c71923ddc377f7dd26f3705bc31f968b4036bf354b226f8d2dc2fac7a9fec49a7b73558f1e3e3062
 DIST vault-1.1.2.tar.gz 26026601 BLAKE2B df208b15076007ab87c3c6683698dc4348f56d5a73ff2a52ce17c5a9858acf4d597f7c53f709a1415247cd4cdc65454cc1aa6c18504cbb10368d39df2974175d SHA512 bc645bc5efeaf5a185479ab2ea78589762d09a40e889845d8cceac94568fcfcfeac94ae602c548648aea800b791121fbb2b75c3af9a9651d08dd9e38c1219826
+DIST vault-1.1.3-webui.tar.xz 1284144 BLAKE2B b84260974ce0827ce8ae834827c331a9bf70f589984975152188615aa480172cf41f4a45abc96fa13bfb7837ae1679bcff519f6aa7ab0678048b2cffbbe11afe SHA512 36331457c50e2a5d42269a5f91cd3e982c3f7dbfd0a2cfa4f8f435c253af6f075da6401b59a92e1949c683b4c5e899ef2f28bbd8a5cbeabcca8ef30816d75e73
+DIST vault-1.1.3.tar.gz 26026249 BLAKE2B a8fb531caf43f675d604f58126a7e56f7bf86defa2309d5d81d92911457efe5595b5c3244be4d0f73806ca5b746bddc852f871c10841da0e7ec128e53c6c18a4 SHA512 bf757558b984711967fdc623393e71c74d5e73922de3b0574ecb229a5d52320ebc3f848b48eabf0ed7a8d6e9d9f6c12d69fb23309fb8c19492b135344c8c4be2

app-admin/vault/vault-1.1.3.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps golang-base golang-vcs-snapshot systemd user
+
+EGO_PN="github.com/hashicorp/${PN}"
+VAULT_WEBUI_ARCHIVE="${P}-webui.tar.xz"
+DESCRIPTION="A tool for managing secrets"
+HOMEPAGE="https://vaultproject.io/"
+SRC_URI="https://${EGO_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	webui? (
+		mirror://gentoo/${VAULT_WEBUI_ARCHIVE}
+		https://dev.gentoo.org/~zmedico/dist/${VAULT_WEBUI_ARCHIVE}
+	)"
+SLOT="0"
+LICENSE="MPL-2.0"
+KEYWORDS="~amd64"
+IUSE="+webui"
+
+RESTRICT="test"
+
+DEPEND=">=dev-lang/go-1.11:=
+	dev-go/gox"
+
+FILECAPS=(
+	-m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
+)
+
+src_unpack() {
+	golang-vcs-snapshot_src_unpack
+	if use webui; then
+		# The webui assets build has numerous nodejs dependencies,
+		# see https://github.com/hashicorp/vault/blob/master/ui/README.md
+		pushd "${S}/src/${EGO_PN}" >/dev/null || die
+		unpack "${VAULT_WEBUI_ARCHIVE}"
+		popd >/dev/null
+	fi
+}
+
+src_prepare() {
+	default
+	# Avoid the need to have a git checkout
+	sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
+		-e 's:^\(GIT_DIRTY=\).*:\1:' \
+		-e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
+		-i src/${EGO_PN}/scripts/build.sh || die
+	sed -e "/hooks/d" -i src/${EGO_PN}/Makefile || die
+}
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_compile() {
+	mkdir bin || die
+	export -n GOCACHE XDG_CACHE_HOME #678970
+	export GOBIN=${S}/bin GOPATH=${S}
+	cd src/${EGO_PN} || die
+	# The fmt target may need to be executed if it was previously
+	# executed by an older version of go (bug 665438).
+	emake fmt
+	BUILD_TAGS="$(usex webui ui '')" \
+	XC_ARCH=$(go env GOARCH) \
+	XC_OS=$(go env GOOS) \
+	XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
+	emake
+}
+
+src_install() {
+	dodoc src/${EGO_PN}/{CHANGELOG.md,CONTRIBUTING.md,README.md}
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+
+	keepdir /etc/${PN}.d
+	insinto /etc/${PN}.d
+	doins "${FILESDIR}/"*.json.example
+
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+
+	dobin bin/${PN}
+}