x11-misc/dmenu: add 5.4

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

x11-misc/dmenu/Manifest

@@ -1 +1,2 @@
 DIST dmenu-5.3.tar.gz 16274 BLAKE2B fd76b0b11a153f98dd58ec888820bc8a0ebc67f814cdf2d13a35ea3addcc3ad423bb9b2f4f73897cf6293e61a507900e7b7fec65e4f0acd15cc8e425f5506faa SHA512 60f758134063ad7f304fbb0785c66dddc21461e5e5014f8735cf6d5c95dc22a177f069d48101e633ddffe5bbefc1118a2bf8b31daaf7b6438fdf6fe1bcb5d61c
+DIST dmenu-5.4.tar.gz 17001 BLAKE2B 01498de5af8c357b7ab1a304d8ed201f80fd026b7bb2dd8b84c58a8c2299ac6177d32fe1dcbfce0b1ff3f4ca2631725f884b0c411786827e492b0a287407ae22 SHA512 946c407d8092bdd17b370e6360053d8611c0bbf60772d48aeda7d7365b3437f748a4a3907bdaee0db778a7d731538098dd2fdfce46d7e0e9dbaa52b48ae1fe05

x11-misc/dmenu/dmenu-5.4.ebuild

@@ -0,0 +1,62 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit savedconfig toolchain-funcs
+
+DESCRIPTION="a generic, highly customizable, and efficient menu for the X Window System"
+HOMEPAGE="https://tools.suckless.org/dmenu/"
+SRC_URI="https://dl.suckless.org/tools/${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~x86"
+IUSE="xinerama"
+
+RDEPEND="
+	media-libs/fontconfig
+	x11-libs/libX11
+	>=x11-libs/libXft-2.3.5
+	xinerama? ( x11-libs/libXinerama )
+"
+DEPEND="${RDEPEND}
+	x11-base/xorg-proto
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.2-gentoo.patch
+)
+
+src_prepare() {
+	default
+
+	sed -i \
+		-e 's|^	@|	|g' \
+		-e '/^	echo/d' \
+		Makefile || die
+
+	restore_config config.h
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" \
+		"FREETYPEINC=$( $(tc-getPKG_CONFIG) --cflags x11 fontconfig xft 2>/dev/null )" \
+		"FREETYPELIBS=$( $(tc-getPKG_CONFIG) --libs x11 fontconfig xft 2>/dev/null )" \
+		"X11INC=$( $(tc-getPKG_CONFIG) --cflags x11 2>/dev/null )" \
+		"X11LIB=$( $(tc-getPKG_CONFIG) --libs x11 2>/dev/null )" \
+		"XINERAMAFLAGS=$(
+			usex xinerama "-DXINERAMA $(
+				$(tc-getPKG_CONFIG) --cflags xinerama 2>/dev/null
+			)" ''
+		)" \
+		"XINERAMALIBS=$(
+			usex xinerama "$( $(tc-getPKG_CONFIG) --libs xinerama 2>/dev/null)" ''
+		)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" PREFIX="${EPREFIX}/usr" install
+
+	save_config config.h
+}