mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 10:17:08 -08:00
dev-util/pkgcheck: add 0.10.24
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST pkgcheck-0.10.23.tar.gz 568903 BLAKE2B 8b00dc93d0c3f597f7397d2e7b3686d11b12da715d6e8071f1b02a8085061cbb2d7cb24bde6a73ef6e5d1459637cb78e536ce80a162f188a42739a434c62c397 SHA512 3bcdb91bf73cde60fd9fc2f5e470c5ccdfd7b3564e83192201b0fa1dc38265e1e0c7f7052039accbb62c55d816a6e89317d7d388c0cc3da3b4836475cb82bd03
|
||||
DIST pkgcheck-0.10.24.tar.gz 572336 BLAKE2B 851d6e8d8a5402c539cb690e6e915d3875658f0f4c9e60e8f506d6a663d0732993f2af7a46b3dcf7c2fba11a3d7b521753aa537a893796b8cda216c9e9d370af SHA512 bb0eb962d9d6cafc5b4ca1280307aae8e154d813151841373334971b7613099ebeeb2b9eb3ca9755da43d76a6448b6a8f6570201810b182cf868a172992b40a5
|
||||
|
||||
@@ -0,0 +1,94 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_USE_PEP517=setuptools
|
||||
PYTHON_COMPAT=( python3_{9..11} )
|
||||
inherit elisp-common distutils-r1 optfeature
|
||||
|
||||
if [[ ${PV} == *9999 ]] ; then
|
||||
EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/pkgcore/pkgcheck.git
|
||||
https://github.com/pkgcore/pkgcheck.git"
|
||||
inherit git-r3
|
||||
else
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-macos"
|
||||
inherit pypi
|
||||
fi
|
||||
|
||||
DESCRIPTION="pkgcore-based QA utility for ebuild repos"
|
||||
HOMEPAGE="https://github.com/pkgcore/pkgcheck"
|
||||
|
||||
LICENSE="BSD MIT"
|
||||
SLOT="0"
|
||||
IUSE="emacs"
|
||||
|
||||
if [[ ${PV} == *9999 ]]; then
|
||||
RDEPEND="
|
||||
~dev-python/snakeoil-9999[${PYTHON_USEDEP}]
|
||||
~sys-apps/pkgcore-9999[${PYTHON_USEDEP}]"
|
||||
else
|
||||
RDEPEND="
|
||||
>=dev-python/snakeoil-0.10.4[${PYTHON_USEDEP}]
|
||||
>=sys-apps/pkgcore-0.12.18[${PYTHON_USEDEP}]"
|
||||
fi
|
||||
RDEPEND+="
|
||||
dev-libs/tree-sitter
|
||||
dev-libs/tree-sitter-bash
|
||||
dev-python/chardet[${PYTHON_USEDEP}]
|
||||
dev-python/lazy-object-proxy[${PYTHON_USEDEP}]
|
||||
dev-python/lxml[${PYTHON_USEDEP}]
|
||||
dev-python/pathspec[${PYTHON_USEDEP}]
|
||||
>=dev-python/tree-sitter-0.19.0[${PYTHON_USEDEP}]
|
||||
emacs? (
|
||||
>=app-editors/emacs-24.1:*
|
||||
app-emacs/ebuild-mode
|
||||
app-emacs/flycheck
|
||||
)
|
||||
"
|
||||
BDEPEND="${RDEPEND}
|
||||
dev-python/wheel
|
||||
test? (
|
||||
dev-python/pytest[${PYTHON_USEDEP}]
|
||||
dev-python/requests[${PYTHON_USEDEP}]
|
||||
dev-vcs/git
|
||||
)
|
||||
"
|
||||
|
||||
SITEFILE="50${PN}-gentoo.el"
|
||||
|
||||
distutils_enable_tests pytest
|
||||
|
||||
export USE_SYSTEM_TREE_SITTER_BASH=1
|
||||
|
||||
src_compile() {
|
||||
distutils-r1_src_compile
|
||||
|
||||
if use emacs ; then
|
||||
pushd "${S}"/contrib/emacs >/dev/null || die
|
||||
elisp-compile *.el
|
||||
popd >/dev/null || die
|
||||
fi
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
local DOCS=( NEWS.rst )
|
||||
[[ ${PV} == *9999 ]] || doman man/*
|
||||
distutils-r1_python_install_all
|
||||
|
||||
if use emacs ; then
|
||||
elisp-install ${PN} "${S}"/contrib/emacs/*.el{,c}
|
||||
elisp-site-file-install "${FILESDIR}/${SITEFILE}"
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
use emacs && elisp-site-regen
|
||||
|
||||
optfeature "Network check support" dev-python/requests
|
||||
optfeature "Perl module version check support" dev-perl/Gentoo-PerlMod-Version
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
use emacs && elisp-site-regen
|
||||
}
|
||||
Reference in New Issue
Block a user