mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-31 21:18:09 -07:00
www-client/opera-developer: bump to 76.0.3981.0
Package-Manager: Portage-3.0.13, Repoman-3.0.2 Signed-off-by: Stephan Hartmann <sultan@gentoo.org>
This commit is contained in:
Stephan Hartmann
@@ -1,3 +1,4 @@
|
||||
DIST opera-developer_75.0.3967.0_amd64.deb 74349124 BLAKE2B c61aa27ae9bf5174e8747c146d85b3ac32887a67106307dc2f195da2e693738359947a2c962ddaba23044ee55fa8c5fbbf8cac33e06b5d25272e87070d3d3202 SHA512 19bab0848e707181cd2d5e853f347f79afad1e10fbef83b09225e37a77069d246a292797f6018a550df7be59c350dacd06709e4807deb43211fb4bcbd50fd4a5
|
||||
DIST opera-developer_76.0.3974.0_amd64.deb 76398292 BLAKE2B cfb3a7d27cc84d43d8b3d7f867a787029dd462283e257201f467c86761e8da93a81ec46a1a98091800269bc1c99c9436e5a910a05a760de26ba08b9dd29dd029 SHA512 3a022e078409c64a4cae7a28b60bfc318c5c0036fae0f5ac712a62e096516fca62ef3c562d63a5d49f367462489b809472c9672be94d7eca9fa29a426c40efc3
|
||||
DIST opera-developer_76.0.3981.0_amd64.deb 76364604 BLAKE2B 00046ef7687c72809f4e7ee6098021a87562a7805a6afabdf571b5d03449a1843a3fa20185488272e78a58b40f65a8e6845506293c5e18cd0dfcf1e90160570b SHA512 9ece065f454d6af496590002853daf360d3b4251a43dcc7e58f96b0b9781579a545b31e6e2f1f5fd4c3978071619c767bca49ffd038959a77c66316b87d47285
|
||||
DIST opera-ffmpeg-codecs-89.0.4381.8.tar.xz 1427048 BLAKE2B 6f92f8582663b46875f4a3d9b0b80b14eb8b361b23699bd5e10319c9b16b26a436cd710cec684a818189eae4892fc41daf2b3387282926e964d4d395a1c7778e SHA512 7947eeaa361e78d1a69d244727ad601719fd4e6d6c284b1655e9fd9c74cf718f42ba3e0d0277f96a7b9cab984d743ea190404e2f74b5e1a6b9bd244e45b71e77
|
||||
|
||||
131
www-client/opera-developer/opera-developer-76.0.3981.0.ebuild
Normal file
131
www-client/opera-developer/opera-developer-76.0.3981.0.ebuild
Normal file
@@ -0,0 +1,131 @@
|
||||
# Copyright 1999-2021 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
CHROMIUM_LANGS="
|
||||
be bg bn ca cs da de el en-GB en-US es-419 es fil fi fr-CA fr hi hr hu id
|
||||
it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
|
||||
zh-CN zh-TW
|
||||
"
|
||||
inherit chromium-2 multilib pax-utils unpacker xdg
|
||||
|
||||
DESCRIPTION="A fast and secure web browser"
|
||||
HOMEPAGE="https://www.opera.com/"
|
||||
LICENSE="OPERA-2018"
|
||||
SLOT="0"
|
||||
|
||||
SRC_URI_BASE=(
|
||||
"https://download1.operacdn.com/pub/${PN}"
|
||||
"https://download2.operacdn.com/pub/${PN}"
|
||||
"https://download3.operacdn.com/pub/${PN}"
|
||||
"https://download4.operacdn.com/pub/${PN}"
|
||||
)
|
||||
|
||||
if [[ ${PN} == opera ]]; then
|
||||
KEYWORDS="-* amd64"
|
||||
MY_PN=${PN}-stable
|
||||
SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
|
||||
else
|
||||
KEYWORDS="-* ~amd64"
|
||||
MY_PN=${PN}
|
||||
fi
|
||||
|
||||
FFMPEG_VERSION="89.0.4381.8"
|
||||
|
||||
SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.deb}
|
||||
proprietary-codecs? (
|
||||
https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
|
||||
)"
|
||||
|
||||
IUSE="+proprietary-codecs suid"
|
||||
RESTRICT="bindist mirror strip"
|
||||
|
||||
RDEPEND="
|
||||
app-accessibility/at-spi2-atk:2
|
||||
app-accessibility/at-spi2-core:2
|
||||
dev-libs/atk
|
||||
dev-libs/expat
|
||||
dev-libs/glib:2
|
||||
dev-libs/nspr
|
||||
dev-libs/nss
|
||||
media-libs/alsa-lib
|
||||
media-libs/mesa[gbm]
|
||||
net-misc/curl
|
||||
net-print/cups
|
||||
sys-apps/dbus
|
||||
x11-libs/cairo
|
||||
x11-libs/gdk-pixbuf
|
||||
x11-libs/gtk+:3
|
||||
x11-libs/libdrm
|
||||
x11-libs/libxcb
|
||||
x11-libs/libxkbcommon
|
||||
x11-libs/libX11
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXext
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXrandr
|
||||
x11-libs/pango
|
||||
"
|
||||
|
||||
QA_PREBUILT="*"
|
||||
S=${WORKDIR}
|
||||
OPERA_HOME="opt/opera${PN#opera}"
|
||||
|
||||
pkg_pretend() {
|
||||
# Protect against people using autounmask overzealously
|
||||
use amd64 || die "opera only works on amd64"
|
||||
}
|
||||
|
||||
pkg_setup() {
|
||||
chromium_suid_sandbox_check_kernel_config
|
||||
}
|
||||
|
||||
src_unpack() {
|
||||
:
|
||||
}
|
||||
|
||||
src_install() {
|
||||
dodir /
|
||||
cd "${ED}" || die
|
||||
unpacker
|
||||
|
||||
# move to /opt, bug #573052
|
||||
mkdir -p "${OPERA_HOME%${PN}}"
|
||||
mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
|
||||
rm -r "usr/lib" || die
|
||||
|
||||
# disable auto update
|
||||
rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
|
||||
|
||||
rm -r "usr/share/lintian" || die
|
||||
|
||||
# fix docs
|
||||
mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
|
||||
gzip -d usr/share/doc/${PF}/changelog.gz || die
|
||||
|
||||
# fix desktop file
|
||||
sed -i \
|
||||
-e 's|^TargetEnvironment|X-&|g' \
|
||||
usr/share/applications/${PN}.desktop || die
|
||||
|
||||
# remove unused language packs
|
||||
pushd "${OPERA_HOME}/localization" > /dev/null || die
|
||||
chromium_remove_language_paks
|
||||
popd > /dev/null || die
|
||||
|
||||
# setup opera symlink
|
||||
rm "usr/bin/${PN}" || die
|
||||
dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
|
||||
|
||||
# install proprietary codecs
|
||||
rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
|
||||
if use proprietary-codecs; then
|
||||
mv lib_extra "${OPERA_HOME}"
|
||||
fi
|
||||
|
||||
# pax mark opera, bug #562038
|
||||
pax-mark m "${OPERA_HOME}/opera"
|
||||
# enable suid sandbox if requested
|
||||
use suid && fperms 4711 "${OPERA_HOME}/opera_sandbox"
|
||||
}
|
||||
Reference in New Issue
Block a user