media-gfx/digikam: 6.4.0 version bump

Closes: https://bugs.gentoo.org/699954
Closes: https://bugs.gentoo.org/701886
Package-Manager: Portage-2.3.82, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2019-12-18 13:58:28 +01:00
parent 6f787f902a
commit b2afe8fcd0
3 changed files with 155 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST digikam-6.3.0.tar.xz 335641824 BLAKE2B 1ecddeee653d6b97570aa3616c6dd0a951210983400fe8aca19ee9e01aef29820f0ab32e3cbc2e92e833868f0f652c5bdd0809324437b6fa778dfdaf04ea3c83 SHA512 9463d7a8351acae32e2fa77c96026d1cb60e56fcc20ad2b71ac7461ff1e5e2e02ca0ef8a12e4d5ae2324aa66e185cdf5b237d6330f4741691876977e773511ce
DIST digikam-6.4.0.tar.xz 340146992 BLAKE2B ca1bc8b0d165f9774354d8489a11d46d8d7467edd3c1e90fd3a96024c4b7cd23bfd5c813251183bcca6d4beac9bffeb9d921beaa9a3752f75f1918796aacd719 SHA512 b3b5e9903538d110613aa872c9215f5e7c19f7520a2b9060c24e686f20f72075378b447239dd3e17cb8860cdd35c699399994199b848757f0497ad25a7805e42
+153
View File
@@ -0,0 +1,153 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
CMAKE_MIN_VERSION=3.14.3
KFMIN=5.60.0
QTMIN=5.12.3
inherit ecm kde.org toolchain-funcs
if [[ ${KDE_BUILD_TYPE} != live ]]; then
MY_PV=${PV/_/-}
MY_P=${PN}-${MY_PV}
SRC_BRANCH=stable
[[ ${PV} =~ beta[0-9]$ ]] && SRC_BRANCH=unstable
SRC_URI="mirror://kde/${SRC_BRANCH}/digikam/${PV}/${MY_P}.tar.xz"
KEYWORDS="~amd64 ~x86"
S="${WORKDIR}/${MY_P}"
fi
DESCRIPTION="Digital photo management application"
HOMEPAGE="https://www.digikam.org/"
LICENSE="GPL-2"
SLOT="5"
IUSE="addressbook calendar dnn heif +imagemagick gphoto2 +lensfun libav marble mediaplayer mysql opengl openmp +panorama scanner semantic-desktop vkontakte webkit X"
BDEPEND="
sys-devel/gettext
panorama? (
sys-devel/bison
sys-devel/flex
)
"
COMMON_DEPEND="
dev-libs/expat
>=dev-qt/qtconcurrent-${QTMIN}:5
>=dev-qt/qtdbus-${QTMIN}:5
>=dev-qt/qtgui-${QTMIN}:5[-gles2]
>=dev-qt/qtnetwork-${QTMIN}:5
>=dev-qt/qtprintsupport-${QTMIN}:5
>=dev-qt/qtsql-${QTMIN}:5[mysql?]
>=dev-qt/qtwidgets-${QTMIN}:5
>=dev-qt/qtxml-${QTMIN}:5
>=dev-qt/qtxmlpatterns-${QTMIN}:5
>=kde-frameworks/kconfig-${KFMIN}:5
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
>=kde-frameworks/kcoreaddons-${KFMIN}:5
>=kde-frameworks/ki18n-${KFMIN}:5
>=kde-frameworks/kiconthemes-${KFMIN}:5
>=kde-frameworks/kio-${KFMIN}:5
>=kde-frameworks/knotifications-${KFMIN}:5
>=kde-frameworks/knotifyconfig-${KFMIN}:5
>=kde-frameworks/kservice-${KFMIN}:5
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
>=kde-frameworks/kwindowsystem-${KFMIN}:5
>=kde-frameworks/kxmlgui-${KFMIN}:5
>=kde-frameworks/solid-${KFMIN}:5
>=media-gfx/exiv2-0.27:=
media-libs/lcms:2
media-libs/liblqr
media-libs/libpng:0=
>=media-libs/opencv-3.1.0:=
media-libs/tiff:0
virtual/jpeg:0
addressbook? (
>=kde-apps/akonadi-contacts-19.04.3:5
>=kde-frameworks/kcontacts-${KFMIN}:5
)
calendar? ( >=kde-frameworks/kcalendarcore-${KFMIN}:5 )
dnn? ( >=media-libs/opencv-3.1.0:=[contrib,contribdnn] )
gphoto2? ( media-libs/libgphoto2:= )
heif? ( media-libs/x265:= )
imagemagick? ( media-gfx/imagemagick:= )
lensfun? ( media-libs/lensfun )
marble? (
>=dev-qt/qtconcurrent-${QTMIN}:5
>=kde-apps/marble-19.04.3:5
>=kde-frameworks/kbookmarks-${KFMIN}:5
)
mediaplayer? (
media-libs/qtav[opengl]
!libav? ( media-video/ffmpeg:= )
libav? ( media-video/libav:= )
)
opengl? (
>=dev-qt/qtopengl-${QTMIN}:5
virtual/opengl
)
panorama? ( >=kde-frameworks/threadweaver-${KFMIN}:5 )
scanner? ( >=kde-apps/libksane-19.04.3:5 )
semantic-desktop? ( >=kde-frameworks/kfilemetadata-${KFMIN}:5 )
vkontakte? ( net-libs/libkvkontakte:5 )
!webkit? ( >=dev-qt/qtwebengine-${QTMIN}:5[widgets] )
webkit? ( >=dev-qt/qtwebkit-5.212.0_pre20180120:5 )
X? (
>=dev-qt/qtx11extras-${QTMIN}:5
x11-libs/libX11
)
"
DEPEND="${COMMON_DEPEND}
dev-cpp/eigen:3
dev-libs/boost[threads]
"
RDEPEND="${COMMON_DEPEND}
mysql? ( virtual/mysql[server] )
panorama? ( media-gfx/hugin )
"
RESTRICT+=" test"
# bug 366505
PATCHES=( "${FILESDIR}/${PN}-6.3.0-cmake.patch" )
pkg_pretend() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
ecm_pkg_pretend
}
pkg_setup() {
[[ ${MERGE_TYPE} != binary ]] && use openmp && tc-check-openmp
ecm_pkg_setup
}
# FIXME: Unbundle libraw (libs/rawengine/libraw)
src_configure() {
local mycmakeargs=(
-DBUILD_TESTING=OFF # bug 698192
-DENABLE_APPSTYLES=ON
-DCMAKE_DISABLE_FIND_PACKAGE_Jasper=ON
-DENABLE_AKONADICONTACTSUPPORT=$(usex addressbook)
$(cmake_use_find_package calendar KF5CalendarCore)
-DENABLE_FACESENGINE_DNN=$(usex dnn)
$(cmake_use_find_package gphoto2 Gphoto2)
$(cmake_use_find_package heif X265)
$(cmake_use_find_package imagemagick ImageMagick)
$(cmake_use_find_package lensfun LensFun)
$(cmake_use_find_package marble Marble)
-DENABLE_MEDIAPLAYER=$(usex mediaplayer)
$(cmake_use_find_package mediaplayer QtAV)
-DENABLE_MYSQLSUPPORT=$(usex mysql)
-DENABLE_INTERNALMYSQL=$(usex mysql)
$(cmake_use_find_package opengl OpenGL)
$(cmake_use_find_package panorama KF5ThreadWeaver)
$(cmake_use_find_package scanner KF5Sane)
$(cmake_use_find_package semantic-desktop KF5FileMetaData)
$(cmake_use_find_package vkontakte KF5Vkontakte)
-DENABLE_QWEBENGINE=$(usex !webkit)
$(cmake_use_find_package X X11)
)
ecm_src_configure
}
+1
View File
@@ -11,6 +11,7 @@
<use>
<flag name="addressbook">Enable akonadi contact integration</flag>
<flag name="dnn">Build neural network faces engine module</flag>
<flag name="heif">Enable support for ISO/IEC 23008-12:2017 HEIF files using <pkg>media-libs/x265</pkg></flag>
<flag name="imagemagick">Enable support for additional image formats such as XCF, FITS, HEIC etc.</flag>
<flag name="lensfun">Enable support for <pkg>media-libs/lensfun</pkg></flag>
<flag name="marble">Enable support for geolocation using <pkg>kde-apps/marble</pkg></flag>