net-analyzer/monitoring-plugins: bump to 2.3

Closes: https://bugs.gentoo.org/766153
Signed-off-by: Tomáš Mózes <hydrapolic@gmail.com>
Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>
This commit is contained in:
Tomáš Mózes
2021-02-04 23:24:50 +01:00
committed by Thomas Deutschmann
parent eb3bb111e2
commit b21fe4f4e5
3 changed files with 112 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST monitoring-plugins-2.2.tar.gz 2461548 BLAKE2B 0f68b492e089c6dfd09db6aab78ab4490f2e8983677c70dda4c3800a06380c066865587536a44f135d0e314006ed81a757cbfbd918f53e009f9d2c50b8e58db0 SHA512 5f8cfa132891d6d96e69bee3f2c26f7d4546f572be6a18f25ea5d9069f162cb2e424361289a5c26bec60d7b63d28a269437fd6f25645903a1c142fdcbbf77f27
DIST monitoring-plugins-2.3.tar.gz 2528556 BLAKE2B d8c8886aea900a172e5693de766edb6b7ef7aac5ee94fec1f5c14cb0e9873623b14a965cc8852abb4ed44934d5111a86e130e7c37201a03de42bc996797302de SHA512 926065667dff6c608ae5b7da39f6416bfc2443b9e1cdef68cd5d19be99da1b6fc6f23ef87b05731312b5d7ad76d01f0242fc9e544dbb4dd00dbafa0e27434d2e
@@ -0,0 +1,107 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit eutils flag-o-matic multilib
DESCRIPTION="50+ standard plugins for Icinga, Naemon, Nagios, Shinken, Sensu"
HOMEPAGE="https://www.monitoring-plugins.org/"
SRC_URI="https://www.monitoring-plugins.org/download/${P}.tar.gz"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~sparc ~x86"
IUSE="curl gnutls ipv6 ldap libressl mysql dns fping game postgres radius samba snmp ssh +ssl"
# Most of the plugins use automagic dependencies, i.e. the plugin will
# get built if the binary it uses is installed. For example, check_snmp
# will be built only if snmpget from net-analyzer/net-snmp[-minimal] is
# installed. End result: most of our runtime dependencies are required
# at build time as well.
#
# REAL_DEPEND contains the dependencies that are actually needed to
# build. DEPEND contains those plus the automagic dependencies.
#
REAL_DEPEND="dev-lang/perl
curl? (
dev-libs/uriparser
net-misc/curl
)
ldap? ( net-nds/openldap )
mysql? ( || ( dev-db/mysql-connector-c dev-db/mariadb-connector-c ) )
postgres? ( dev-db/postgresql:= )
ssl? (
!gnutls? (
!libressl? ( dev-libs/openssl:0= )
libressl? ( dev-libs/libressl:= )
)
gnutls? ( net-libs/gnutls )
)
radius? ( net-dialup/freeradius-client )"
DEPEND="${REAL_DEPEND}
dns? ( net-dns/bind-tools )
game? ( games-util/qstat )
fping? ( net-analyzer/fping )
samba? ( net-fs/samba )
ssh? ( net-misc/openssh )
snmp? ( dev-perl/Net-SNMP
net-analyzer/net-snmp[-minimal] )"
# Basically everything collides with nagios-plugins.
RDEPEND="${DEPEND}
acct-group/nagios
acct-user/nagios
!net-analyzer/nagios-plugins"
# At least one test is interactive.
RESTRICT="test"
PATCHES=( "${FILESDIR}/define-own-mysql-port-constant.patch" )
src_configure() {
append-flags -fno-strict-aliasing
# Use an array to prevent econf from mangling the ping args.
local myconf=()
if use ssl; then
myconf+=( $(use_with !gnutls openssl /usr)
$(use_with gnutls gnutls /usr) )
else
myconf+=( --without-openssl )
myconf+=( --without-gnutls )
fi
# The autodetection for these two commands can hang if localhost is
# down or ICMP traffic is filtered. Bug #468296.
myconf+=( --with-ping-command="/bin/ping -4 -n -U -w %d -c %d %s" )
if use ipv6; then
myconf+=( --with-ping6-command="/bin/ping -6 -n -U -w %d -c %d %s" )
fi
econf \
$(use_with curl libcurl) \
$(use_with curl uriparser) \
$(use_with mysql) \
$(use_with ipv6) \
$(use_with ldap) \
$(use_with postgres pgsql /usr) \
$(use_with radius) \
"${myconf[@]}" \
--libexecdir="/usr/$(get_libdir)/nagios/plugins" \
--sysconfdir="/etc/nagios"
}
DOCS=( ACKNOWLEDGEMENTS AUTHORS CODING ChangeLog FAQ \
NEWS README REQUIREMENTS SUPPORT THANKS )
pkg_postinst() {
elog "This ebuild has a number of USE flags that determine what you"
elog "are able to monitor. Depending on what you want to monitor, some"
elog "or all of these USE flags need to be set."
elog
elog "The plugins are installed in ${EROOT}/usr/$(get_libdir)/nagios/plugins"
}
+4
View File
@@ -1,6 +1,10 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
# Tomáš Mózes <hydrapolic@gmail.com> (2021-02-04)
# Dependency not keyworded on this arch.
net-analyzer/monitoring-plugins curl
# Joonas Niilola <juippis@gentoo.org> (2021-01-15)
# Dependency not keyworded on this arch.
app-text/enchant voikko