dev-ada/gnatcoll-bindings: add 23.0.0

Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

dev-ada/gnatcoll-bindings/Manifest

@@ -1,2 +1,3 @@
 DIST gnatcoll-bindings-2021-20210518-19B15-src.tar.gz 1425986 BLAKE2B c10fc6ff8bc74de37178a5e74d7ca81fd476c84765612b59c4a7711bfd6fb2428157bc12715e3813170c1403419ca89bdea55569f111c7a66130f689575fe368 SHA512 c2cae5bef27c19c46a69c188d111676cb6d68762e8666740dac69bddbeb350d56497ceceda5b6959e7810d51d98ead7827d95735bfc932c343cec5acee81b041
 DIST gnatcoll-bindings-22.0.0.tar.gz 243040 BLAKE2B f6577e6d31362b59ac2bdb8c70772e6783d88f192f63e335082140d143d17be15bb62143174217b2e823e6183e5148725c1d12e4b00c3cc0abfacf3a279d30df SHA512 b8f4184f0992057ea33350e30e007859c5ef3e028d7604c47ae160f3c2ffcc828187ed9c9c3de7c6d2b7b16274714822460dc09d687386035d2773df45e90bf2
+DIST gnatcoll-bindings-23.0.0.tar.gz 251006 BLAKE2B 8cc5ada5c76d146d80c1b83bfbcfea28b9951339eb5dcdca40a4b40fdeb2ed2ad1971deea60b6fdc7cc2565745958d13fcc1acbd012465dea4cb2535e947af34 SHA512 3f92d3c95ffbcf96df53a1db39c9b829ae3d0a9ee3695d3d7726168bd6744ca4d4dfe4b224b50b50603c6295e1c0c6dd3d9940cf9e20c147a3bed8e6cc39c1ce

dev-ada/gnatcoll-bindings/gnatcoll-bindings-23.0.0.ebuild

@@ -0,0 +1,96 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8,9,10} )
+ADA_COMPAT=( gnat_2021 gcc_12_2_0 )
+inherit ada multiprocessing python-single-r1
+
+DESCRIPTION="GNAT Component Collection"
+HOMEPAGE="http://libre.adacore.com"
+SRC_URI="https://github.com/AdaCore/${PN}/archive/refs/tags/v${PV}.tar.gz
+	-> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86"
+IUSE="gmp iconv lzma openmp python readline +shared static-libs static-pic syslog"
+REQUIRED_USE="|| ( shared static-libs static-pic )
+	|| ( gmp iconv lzma openmp python readline syslog )
+	${PYTHON_REQUIRED_USE}
+	${ADA_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	${ADA_DEPS}
+	dev-ada/gnatcoll-core:=[${ADA_USEDEP},shared?,static-libs?,static-pic?]
+	gmp? ( dev-libs/gmp:* )
+	lzma? ( app-arch/xz-utils )
+	openmp? ( dev-lang/gnat-gpl:=[openmp] )
+	"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+
+QA_EXECSTACK=usr/lib/gnatcoll_readline.*/libgnatcoll_readline.*
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ada_pkg_setup
+}
+
+src_prepare() {
+	rm -r python || die
+	mv python3 python || die
+	default
+}
+
+src_compile() {
+	build () {
+		gprbuild -j$(makeopts_jobs) -m -p -v \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XLIBRARY_TYPE=$2 -P $1/gnatcoll_$1.gpr -XBUILD="PROD" \
+			-XGNATCOLL_VERSION=${PV} \
+			-XGNATCOLL_ICONV_OPT= -XGNATCOLL_PYTHON_CFLAGS="-I$(python_get_includedir)" \
+			-XGNATCOLL_PYTHON_LIBS=$(python_get_library_path) \
+			-cargs:Ada ${ADAFLAGS} -cargs:C ${CFLAGS} || die "gprbuild failed"
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			for dir in gmp iconv lzma python readline syslog ; do
+				if use $dir; then
+					build $dir $lib
+				fi
+			done
+			if use openmp; then
+				build omp $lib
+			fi
+		fi
+	done
+}
+
+src_install() {
+	build () {
+		gprinstall -p -f -XBUILD=PROD --prefix="${D}"/usr -XLIBRARY_TYPE=$2 \
+			-XGPR_BUILD=$2 -XGNATCOLL_CORE_BUILD=$2 \
+			-XGNATCOLL_VERSION=${PV} --build-var=LIBRARY_TYPE \
+			-XGNATCOLL_ICONV_OPT= -P $1/gnatcoll_$1.gpr --build-name=$2
+	}
+	for kind in shared static-libs static-pic ; do
+		if use $kind; then
+			lib=${kind%-libs}
+			lib=${lib/shared/relocatable}
+			for dir in gmp iconv lzma python readline syslog ; do
+				if use $dir; then
+					build $dir $lib
+				fi
+			done
+			if use openmp; then
+				build omp $lib
+			fi
+		fi
+	done
+	rm -rf "${D}"/usr/share/gpr/manifests
+	einstalldocs
+}