gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-24 18:58:08 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/anyio: Bump to 4.6.2_p1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2024-10-15 07:52:54 +02:00
parent 87f98669a7
commit b148489517
2 changed files with 76 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/anyio/Manifest
View File

@@ -1,2 +1,3 @@
DIST anyio-4.6.0.tar.gz 170983 BLAKE2B 686cb9b622cba29d02fe6e440502de80c159dc40547124aed79eb7558fe147fa62f378745c2aa5487ca1ea7c24e1f3c6167f8343236dbb7e0876d95f741c46ec SHA512 4828198d3e2b2924b3490c305dcaddc14b5746b29a0cb36f75913f897254fed0ac46e075a3c04bf164a7d4d597b0dcdd991fe5cb26ffce477d029db7ff924f38
DIST anyio-4.6.2.post1.tar.gz 173422 BLAKE2B 938b0b12110aea3eb733f251b4cf24a82098314a393e07d5ada45a16fae4d10a89462bd81f67002dcc6ac272df9b600d24bb569cb9a3897213bf9ecf1b00f554 SHA512 86d177d1f3e236fd3a2762ce6a760ad77daf9a9fd0daa6e651e778e8c847f85382d2647bf674970fdf8ab02454a8e0a85cc74585e4912c39f5d230eaf0f363a1
DIST anyio-4.6.2.tar.gz 171302 BLAKE2B 4c44ac9d896fc98fde450c1311ba6a37d28d79848f4d89a1ca571afe53e61e538447bb12b6aa08f3a98b66ff57aee856c2eb1a5472d521f35d07a86a62dd97a1 SHA512 854322ffd16b4002d5ddaa9f417bb2b27e791a417fa41a5e75276c98aed9ad8e1317830c65445f6a9c1f3851589dab0d1950a0b06efade40c743bd976a20ca1c

75
dev-python/anyio/anyio-4.6.2_p1.ebuild Normal file
View File

@@ -0,0 +1,75 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( pypy3 python3_{10..13} )
inherit distutils-r1 pypi
DESCRIPTION="Compatibility layer for multiple asynchronous event loop implementations"
HOMEPAGE="
https://github.com/agronholm/anyio/
https://pypi.org/project/anyio/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~riscv ~sparc ~x86"
RDEPEND="
>=dev-python/idna-2.8[${PYTHON_USEDEP}]
>=dev-python/sniffio-1.1[${PYTHON_USEDEP}]
>=dev-python/truststore-0.9.1[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/exceptiongroup-1.2.0[${PYTHON_USEDEP}]
>=dev-python/typing-extensions-4.1[${PYTHON_USEDEP}]
' 3.10)
"
# On amd64, let's get more test coverage by dragging in uvloop, but let's
# not bother on other arches where uvloop may not be supported.
BDEPEND="
>=dev-python/setuptools-scm-6.4[${PYTHON_USEDEP}]
test? (
>=dev-python/exceptiongroup-1.2.0[${PYTHON_USEDEP}]
>=dev-python/hypothesis-4.0[${PYTHON_USEDEP}]
>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
>=dev-python/pytest-mock-3.6.1[${PYTHON_USEDEP}]
dev-python/trustme[${PYTHON_USEDEP}]
$(python_gen_cond_dep '
>=dev-python/trio-0.26.1[${PYTHON_USEDEP}]
' 3.{10..13})
amd64? (
$(python_gen_cond_dep '
>=dev-python/uvloop-0.21.0_beta1[${PYTHON_USEDEP}]
' python3_{10..13})
)
)
"
distutils_enable_tests pytest
distutils_enable_sphinx docs \
'>=dev-python/sphinx-rtd-theme-1.2.2' \
dev-python/sphinxcontrib-jquery \
dev-python/sphinx-autodoc-typehints
python_test() {
local EPYTEST_DESELECT=(
# requires link-local IPv6 interface
tests/test_sockets.py::TestTCPListener::test_bind_link_local
)
local filter=()
if ! has_version ">=dev-python/trio-0.26.1[${PYTHON_USEDEP}]"; then
filter+=( -k "not trio" )
EPYTEST_DESELECT+=(
tests/test_pytest_plugin.py::test_plugin
tests/test_pytest_plugin.py::test_autouse_async_fixture
tests/test_pytest_plugin.py::test_cancel_scope_in_asyncgen_fixture
)
fi
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
epytest -m 'not network' "${filter[@]}"
}