app-misc/geneweb: version bump to 7.0.0

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

app-misc/geneweb/Manifest

@@ -1 +1,2 @@
 DIST geneweb-6.08.01.tar.gz 1796215 BLAKE2B 4b7d05126d244984b62ebadda3419ba8cf97326ac3103c73ca5433a8f9edeab8acd968d05942d299e70127bcf75efe5cb9a9af9f7d97ec08fd9a8a6a5aae100d SHA512 54e1ed05e540f1de167c66dee46976a8324a37ca36a9dfd6ab03105fe925053c570842e1a263499fd8bd7aecfebac8f9596b1573fcec1e104e3892337376f84d
+DIST geneweb-7.0.0.tar.gz 14767981 BLAKE2B 3a0a777a934d26fa91bd94d20311c6147e749961035b57aed8322c4e96f5cead2edde3a96e362b5de35073fa594d4cb5f3ef0f4d7eeaebea2095bfeef37740b6 SHA512 359b8e2258d572198a7516dd03830e536038392d552482f25fe4b93ded76dccebfe3c420eb2ba1a566500200755c87cbe19a2060eaeea895bd84c505b7b65345

app-misc/geneweb/geneweb-7.0.0.ebuild

@@ -0,0 +1,83 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit eutils
+
+DESCRIPTION="Genealogy software program with a Web interface"
+HOMEPAGE="https://github.com/geneweb/geneweb"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+ocamlopt"
+RESTRICT="strip"
+
+RDEPEND="dev-lang/ocaml[ocamlopt?]
+	dev-ml/camlp5[ocamlopt?]
+	acct-user/geneweb
+	acct-group/geneweb
+	dev-ml/jingoo
+	dev-ml/uunf
+	>=dev-ml/markup-1.0.0
+	dev-ml/unidecode
+	dev-ml/calendars"
+DEPEND="${RDEPEND}
+	dev-ml/cppo"
+
+QA_FLAGS_IGNORED=(
+	/usr/bin/gwb2ged
+	/usr/bin/update_nldb
+	/usr/bin/consang
+	/usr/bin/gwd
+	/usr/bin/gwsetup
+	/usr/bin/ged2gwb2
+	/usr/bin/gwc
+	/usr/bin/ged2gwb
+	/usr/bin/check_base
+	/usr/bin/gwu
+	/usr/bin/gwc1
+	/usr/bin/gwc2
+	/usr/lib/geneweb/gwtp
+)
+
+src_configure() {
+	ocaml ./configure.ml
+}
+
+src_compile() {
+	if use ocamlopt; then
+		emake
+	else
+		emake OCAMLC=ocamlc OCAMLOPT=ocamlopt out
+		# If using bytecode we dont want to strip the binary as it would remove
+		# the bytecode and only leave ocamlrun...
+	fi
+}
+
+src_install() {
+	default
+	rm -r "${D}"/usr/doc || die
+	dodoc ICHANGES etc/README.txt etc/a.gwf
+
+	# Install manpages
+	doman man/*
+
+	emake distrib
+	cd distribution/gw
+	insinto /usr/share/${PN}
+	doins -r etc images lang setup gwd.arg only.txt
+
+	newinitd "${FILESDIR}/geneweb.initd" geneweb
+	newconfd "${FILESDIR}/geneweb.confd" geneweb
+}
+
+pkg_postinst() {
+	einfo "A CGI program has been installed in /usr/lib/${PN}. Follow the"
+	einfo "instructions on the README in that directory to use it"
+	einfo "If you come from an old version you need to rebuild the database"
+	einfo "\"gwu foo > foo.gw \" will save the database (use the previous"
+	einfo "version to do that). \"gwc2 foo.gw -o bar \" will restore it "
+	einfo "(using the current package)"
+}