app-emacs/org-mode: bump to 9.7.20

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-emacs/org-mode/Manifest

@@ -2,3 +2,4 @@ DIST org-mode-release_9.7.16.tar.gz 2364239 BLAKE2B eb379531f5dbc6407e32bcd4fd9e
 DIST org-mode-release_9.7.17.tar.gz 2364232 BLAKE2B b0f3c94e92f6721b0ffb4b9196391a0520c2cad8124eb9afda58f3e1705d7031e616cd0549eed2ed16b1d6e8d10113f7f384f4c1ca969a83d9b5975a9cd95d76 SHA512 4bb12ed1aa3be2ab32037450960535f1552395409b49721cae5babf0f2eb3d96497c635d08141efdc7b7fc738b8df8422cf0ee65cb3c329ad4db578c4478dc19
 DIST org-mode-release_9.7.18.tar.gz 2364125 BLAKE2B 6def92460c96c02e4fa0304bf02437819b3a3541db4f30ee6cf354faaa55860886b785940af6cb32d9b6881d6484c3eaf50942b9a788712f84e2a1676f06940f SHA512 c019d82c2bc2bde3ee555f7a99e0b935e3dc9b64bdecdb2f83b2ed8460c822cd1d7a3f318dff637c57ed905070df98aff32cdc82b3c96a10f26038859c540e0a
 DIST org-mode-release_9.7.19.tar.gz 2364122 BLAKE2B d7e65b8af54968a812e012aa11f380f64d65bd5e0829ecdc96d64a539c54f384157a336c192806d9fb32be50a0c6c62e60bc8d067ab581049b0edc8a57ad1327 SHA512 bef652cc8e31f86ccaf6ce0288389f1cb10aa43fd9d8f4191ab30e7d4563b977f4da309c322367a6f2beb27e88c3d771b5c4d4e259ca4c8c6a0b145c1e8d43ca
+DIST org-mode-release_9.7.20.tar.gz 2364571 BLAKE2B 694e709b161a3669191fefa517b93d3629580cd986c48af0e0cf1198a1a7bcbee835c452ec87d4445f5ac91bf10f1127c8ad22283eede9b3eca5f67bed567f15 SHA512 ee81f6be7f544205c256811e90bd9dda9d830b1ad19dde079be7affbe304ee6ce6d059814f6658514af3273630ea3ce99797c6af419f0c9ab3f1f1b64e8bf35c

app-emacs/org-mode/org-mode-9.7.20.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit elisp readme.gentoo-r1
+
+DESCRIPTION="An Emacs mode for notes and project planning"
+HOMEPAGE="https://orgmode.org/"
+
+if [[ "${PV}" == 9999 ]]; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://git.savannah.gnu.org/git/emacs/${PN}.git"
+	EGIT_CHECKOUT_DIR="${WORKDIR}/org"
+	S="${WORKDIR}/org"
+else
+	MY_P="${PN}-release_${PV}"
+	SRC_URI="https://git.savannah.gnu.org/cgit/emacs/${PN}.git/snapshot/${MY_P}.tar.gz"
+	S="${WORKDIR}/${MY_P}"
+
+	KEYWORDS="~amd64 ~ppc ~x86"
+fi
+
+LICENSE="GPL-3+ FDL-1.3+ CC-BY-SA-3.0 odt-schema? ( OASIS-Open )"
+SLOT="0"
+IUSE="doc odt-schema"
+RESTRICT="test"
+
+BDEPEND="
+	doc? ( virtual/texi2dvi )
+"
+
+SITEFILE="50${PN}-gentoo.el"
+
+src_prepare() {
+	elisp_src_prepare
+
+	# Remove failing tests.
+	rm ./testing/lisp/test-{ob,ob-exp,ob-tangle,ob-shell}.el || die
+}
+
+src_compile() {
+	emake -j1 \
+		ORGVERSION="${PV}" \
+		datadir="${EPREFIX}${SITEETC}/${PN}"
+
+	use doc && emake -j1 pdf card
+}
+
+src_install() {
+	emake -j1 \
+		ORGVERSION="${PV}" \
+		DESTDIR="${D}" \
+		ETCDIRS="styles csl $(use odt-schema && echo schema)" \
+		lispdir="${EPREFIX}${SITELISP}/${PN}" \
+		datadir="${EPREFIX}${SITEETC}/${PN}" \
+		infodir="${EPREFIX}/usr/share/info" \
+		install
+
+	elisp-site-file-install "${FILESDIR}/${SITEFILE}"
+	dodoc README.org CONTRIBUTE.org etc/ORG-NEWS
+	use doc && dodoc doc/org.pdf doc/orgcard.pdf doc/orgguide.pdf
+
+	local DOC_CONTENTS="Org mode has a large variety of run-time dependencies,
+		so you may have to install one or more additional packages.
+		A non-exhaustive list of these dependencies may be found at
+		<http://orgmode.org/worg/org-dependencies.html>."
+	readme.gentoo_create_doc
+}