net-libs/libssh: Drop 0.8.5

Package-Manager: Portage-2.3.66, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-libs/libssh/Manifest

@@ -1,3 +1,2 @@
-DIST libssh-0.8.5.tar.xz 427372 BLAKE2B d1cd94a50f09b1562f7267ff435b2d180b84d4132a589e053f43f5de64bb764d9263910837a53be594e64595483ed9516dcbf20abc5071e9a8154b8bb75f6f4c SHA512 f1e90a5046e006d44a48ab36675167761d8e308ada7a1d7a1f7ba2825d222a2fab7e19dbc78b1371fee9ba74d9c55d9856a623f97842c9b9ad4c79215e344124
 DIST libssh-0.8.6.tar.xz 433680 BLAKE2B f222e67676a90a2d2431463dc71859ad336a23a519b54e08fe368efe6322d0b9c8e393ec92d5246cb4721cd57bb955856fa6a2d92ffe71b6c35e2c94cde28762 SHA512 e91d1f4c1343aa232ade0fe4b5e9a92ca65e3716f4ebe2ec25b04def4fae5a3774349f05a6919836551f66fb0288ed6a3e19e0ab786c081616218be973356522
 DIST libssh-0.8.7.tar.xz 430104 BLAKE2B 8ad9455d81120726434a418abb74bfee53279040541cda50117909d43088ea992b9dbc7164b079dbe970b4348b967ed0d3f6352df98f60d1e6d9f14a086b5a40 SHA512 13c3dccad81d521edf29c8a5e2c5f7fdd90507a0eda652b2b040a0a17bab88860873e089a46e181907ea3f449ca1847b1c84453b1960f456e391eefe5be983c5

net-libs/libssh/libssh-0.8.5.ebuild

@@ -1,111 +0,0 @@
-# Copyright 1999-2019 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-MY_P="${PN}-${PV/_rc/rc}"
-inherit cmake-multilib
-
-DESCRIPTION="Access a working SSH implementation by means of a library"
-HOMEPAGE="https://www.libssh.org/"
-
-if [[ "${PV}" == *9999 ]] ; then
-	inherit git-r3
-	EGIT_REPO_URI="https://git.libssh.org/projects/libssh.git"
-else
-	inherit eapi7-ver
-	SRC_URI="https://www.libssh.org/files/$(ver_cut 1-2)/${MY_P}.tar.xz"
-	KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ~ppc ~ppc64 ~s390 sparc x86 ~amd64-fbsd ~amd64-linux ~x86-linux"
-fi
-
-LICENSE="LGPL-2.1"
-SLOT="0/4" # subslot = soname major version
-IUSE="debug doc examples gcrypt gssapi libressl mbedtls pcap server +sftp static-libs test zlib"
-# Maintainer: check IUSE-defaults at DefineOptions.cmake
-
-REQUIRED_USE="?? ( gcrypt mbedtls ) test? ( static-libs )"
-
-RDEPEND="
-	!gcrypt? (
-		!mbedtls? (
-			!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
-			libressl? ( dev-libs/libressl:=[${MULTILIB_USEDEP}] )
-		)
-	)
-	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:0[${MULTILIB_USEDEP}] )
-	gssapi? ( >=virtual/krb5-0-r1[${MULTILIB_USEDEP}] )
-	mbedtls? ( net-libs/mbedtls[${MULTILIB_USEDEP}] )
-	zlib? ( >=sys-libs/zlib-1.2.8-r1[${MULTILIB_USEDEP}] )
-"
-DEPEND="${RDEPEND}
-	doc? ( app-doc/doxygen[dot] )
-	test? ( >=dev-util/cmocka-0.3.1[${MULTILIB_USEDEP}] )
-"
-
-DOCS=( AUTHORS README ChangeLog )
-
-S="${WORKDIR}/${MY_P}"
-
-PATCHES=(
-	"${FILESDIR}/${PN}-0.8.0-tests.patch"
-	"${FILESDIR}/${PN}-0.8.3-strict-overflow.patch"
-)
-
-src_prepare() {
-	cmake-utils_src_prepare
-
-	# just install the examples, do not compile them
-	cmake_comment_add_subdirectory examples
-
-	# keyfile torture test is currently broken
-	sed -i \
-		-e '/torture_keyfiles/d' \
-		tests/unittests/CMakeLists.txt || die
-}
-
-multilib_src_configure() {
-	local mycmakeargs=(
-		-DUNIT_TESTING="$(usex test)"
-		-DWITH_DEBUG_CALLTRACE="$(usex debug)"
-		-DWITH_DEBUG_CRYPTO="$(usex debug)"
-		-DWITH_GCRYPT="$(usex gcrypt)"
-		-DWITH_GSSAPI="$(usex gssapi)"
-		-DWITH_MBEDTLS="$(usex mbedtls)"
-		-DWITH_NACL=no
-		-DWITH_PCAP="$(usex pcap)"
-		-DWITH_SERVER="$(usex server)"
-		-DWITH_SFTP="$(usex sftp)"
-		-DWITH_STACK_PROTECTOR=OFF
-		-DWITH_STACK_PROTECTOR_STRONG=OFF
-		-DWITH_STATIC_LIB="$(usex static-libs)"
-		-DWITH_ZLIB="$(usex zlib)"
-	)
-
-	multilib_is_native_abi || mycmakeargs+=( -DCMAKE_DISABLE_FIND_PACKAGE_Doxygen=ON )
-
-	cmake-utils_src_configure
-}
-
-multilib_src_compile() {
-	cmake-utils_src_compile
-	multilib_is_native_abi && use doc && cmake-utils_src_compile docs
-}
-
-multilib_src_install() {
-	cmake-utils_src_install
-	use doc && HTML_DOCS=( "${BUILD_DIR}"/doc/html/. )
-
-	# compatibility symlink until all consumers have been updated
-	# to no longer use libssh_threads.so
-	dosym libssh.so /usr/$(get_libdir)/libssh_threads.so
-}
-
-multilib_src_install_all() {
-	use mbedtls && DOCS+=( README.mbedtls )
-	einstalldocs
-
-	if use examples; then
-		docinto examples
-		dodoc examples/*.{c,h,cpp}
-	fi
-}