mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
sys-block/fio: bump to 3.36
Also make pandas dependency optional due to size (used for only one processing script). Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
This commit is contained in:
Robin H. Johnson
@@ -1,3 +1,4 @@
|
||||
DIST fio-3.27.tar.bz2 960330 BLAKE2B 7e7e01a5c1d6af13a6f87139e7738646cbc8f45ebc370d0c45b9efe1f93778613d374daafc6df459f988f27f2be54ff636235e1e5a92a4a6ecf9a60ed573d170 SHA512 9c5f2ab0c9ac24ab78dbc74fb6c5acd60f8189fdc618f4280992141b6c0abe1c235c373fee18ad0c803e7fb25d480f45aec56dc3be2e0d26d181b3418b179f99
|
||||
DIST fio-3.30.tar.bz2 6001772 BLAKE2B a4941cd415e6444bb9871274580efdf82281a1e52dc3caaa235f63176e3564fb1dc08e1e4586c555f9c25975d7e6220fe53209ed7218da713b9cb9135de0fc05 SHA512 1fb2ae9c28028147edabceff734fc41bf07ce504af98afdb0951920b724b15d647f2b0852262c177279ad6b4dbbf24be458db7f939d1c80069e0f8e7bc8aa10d
|
||||
DIST fio-3.34.tar.bz2 7049859 BLAKE2B 297fef62098bc3bc5476ebc7794566172c182059ce35d57a84bf87f6cedf08f234371d363fd08570e675eef9fbc7eae8d79755826d4312d543a16a144b4afc3f SHA512 912da2d7c7c4e0ad6c64a2e8c5254d23e5b6286c54d3ebf23d6bd2e0b5a9e4d2a53a75da3c807467b0fbe637b4ff23d64f1166fc45d6cce1d13d239f233548d0
|
||||
DIST fio-3.36.tar.bz2 7229204 BLAKE2B a9265ae8817486ddda1b63c35c79814b7854ec29106a188110b22ba82fc41a015b076626daa577a43189804a768f5465395b8daa74ceb31c949e03eca091a23b SHA512 925cab44619991052085216253c9c5637f7319f52d92f4cc946df60ab1a964dbfa0bbb0ecd171d6dc21ae1402375a6cf1e7b8ac94df0c03889f849aeb2da8890
|
||||
|
||||
169
sys-block/fio/fio-3.36.ebuild
Normal file
169
sys-block/fio/fio-3.36.ebuild
Normal file
@@ -0,0 +1,169 @@
|
||||
# Copyright 1999-2024 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python3_{10..12} )
|
||||
|
||||
inherit python-r1 toolchain-funcs
|
||||
|
||||
MY_PV="${PV/_rc/-rc}"
|
||||
MY_P="${PN}-${MY_PV}"
|
||||
|
||||
DESCRIPTION="Jens Axboe's Flexible IO tester"
|
||||
HOMEPAGE="https://brick.kernel.dk/snaps/"
|
||||
SRC_URI="https://brick.kernel.dk/snaps/${MY_P}.tar.bz2"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~loong ~ppc ~ppc64 ~riscv ~x86"
|
||||
IUSE="aio curl glusterfs gnuplot gtk io-uring nfs numa pandas python rbd rdma static tcmalloc test valgrind zbc zlib"
|
||||
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )
|
||||
gnuplot? ( python )
|
||||
io-uring? ( aio )"
|
||||
RESTRICT="!test? ( test )"
|
||||
|
||||
BDEPEND="virtual/pkgconfig"
|
||||
|
||||
# GTK+:2 does not offer static libaries.
|
||||
# xnvme
|
||||
# libblkio
|
||||
# pmem2
|
||||
LIB_DEPEND="aio? ( dev-libs/libaio[static-libs(+)] )
|
||||
curl? (
|
||||
net-misc/curl:=[static-libs(+)]
|
||||
dev-libs/openssl:0=[static-libs(+)]
|
||||
)
|
||||
nfs? ( net-fs/libnfs:=[static-libs(+)] )
|
||||
glusterfs? ( sys-cluster/glusterfs[static-libs(+)] )
|
||||
gtk? ( dev-libs/glib:2[static-libs(+)] )
|
||||
io-uring? ( sys-libs/liburing:=[static-libs(+)] )
|
||||
numa? ( sys-process/numactl[static-libs(+)] )
|
||||
rbd? ( sys-cluster/ceph[static-libs(+)] )
|
||||
rdma? ( sys-cluster/rdma-core[static-libs(+)] )
|
||||
tcmalloc? ( dev-util/google-perftools:=[static-libs(+)] )
|
||||
zbc? ( >=sys-block/libzbc-5 )
|
||||
zlib? ( sys-libs/zlib[static-libs(+)] )"
|
||||
RDEPEND="!static? ( ${LIB_DEPEND//\[static-libs(+)]} )
|
||||
gtk? ( x11-libs/gtk+:2 )"
|
||||
DEPEND="${RDEPEND}
|
||||
static? ( ${LIB_DEPEND} )
|
||||
test? ( dev-util/cunit )
|
||||
valgrind? ( dev-debug/valgrind )"
|
||||
RDEPEND+="
|
||||
python? (
|
||||
${PYTHON_DEPS}
|
||||
pandas? ( dev-python/pandas[${PYTHON_USEDEP}] )
|
||||
)
|
||||
gnuplot? ( sci-visualization/gnuplot )"
|
||||
|
||||
S="${WORKDIR}/${MY_P}"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/fio-2.2.13-libmtd.patch
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
sed -i '/^DEBUGFLAGS/s: -D_FORTIFY_SOURCE=2::g' Makefile || die
|
||||
|
||||
# Many checks don't have configure flags.
|
||||
sed -i \
|
||||
-e "s:\<pkg-config\>:$(tc-getPKG_CONFIG):" \
|
||||
-e '/if compile_prog "" "-lzbc" "libzbc" *; *then/ '"s::if $(usex zbc true false) ; then:" \
|
||||
-e '/if compile_prog "" "-lz" "zlib" *; *then/ '"s::if $(usex zlib true false) ; then:" \
|
||||
-e '/if compile_prog "" "-laio" "libaio" *; *then/'"s::if $(usex aio true false) ; then:" \
|
||||
-e '/if compile_prog "" "-lcunit" "CUnit" *; *then/'"s::if $(usex test true false) ; then:" \
|
||||
-e '/if compile_prog "" "" "valgrind_dev" *; *then/'"s::if $(usex valgrind true false) ; then:" \
|
||||
configure || die
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
chmod g-w "${T}"
|
||||
# not a real configure script
|
||||
# TODO: cuda
|
||||
# TODO: libnbd - not packaged in Gentoo
|
||||
# TODO: pmem - not packaged in Gentoo
|
||||
# TODO: libblkiio - not packaged in Gentoo
|
||||
# TODO: xnvme - not packaged in Gentoo
|
||||
# TODO: libhdfs
|
||||
# libnfs option does not work as expected:
|
||||
# $(usex nfs '' '--disable-libnfs') \
|
||||
OPTS=(
|
||||
--disable-optimizations
|
||||
--extra-cflags="${CFLAGS} ${CPPFLAGS}"
|
||||
--cc="$(tc-getCC)"
|
||||
--disable-pmem
|
||||
--disable-xnvme
|
||||
--disable-libblkio
|
||||
# Not booleans, enable-only up to this version
|
||||
#--disable-cuda
|
||||
#--disable-libcufile
|
||||
#--disable-libhdfs
|
||||
--disable-dfs
|
||||
$(usex nfs '' '--disable-libnfs')
|
||||
$(usex curl '' '--disable-http')
|
||||
$(usex glusterfs '' '--disable-gfapi')
|
||||
$(usex gtk '--enable-gfio' '')
|
||||
$(usex numa '' '--disable-numa')
|
||||
$(usex rbd '' '--disable-rbd')
|
||||
$(usex rdma '' '--disable-rdma')
|
||||
$(usex static '--build-static' '')
|
||||
$(usex tcmalloc '' '--disable-tcmalloc')
|
||||
)
|
||||
set -- \
|
||||
# not autoconf
|
||||
./configure "${OPTS[@]}"
|
||||
echo "$@" |tr ' ' '\n'
|
||||
"$@" || die 'configure failed'
|
||||
}
|
||||
|
||||
src_compile() {
|
||||
emake V=1 OPTFLAGS=
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake install DESTDIR="${D}" prefix="${EPREFIX}/usr" mandir="${EPREFIX}/usr/share/man"
|
||||
|
||||
local python2_7_files=(
|
||||
"${ED}"/usr/bin/fiologparser_hist.py
|
||||
"${ED}"/usr/bin/fiologparser.py
|
||||
)
|
||||
local python_files=(
|
||||
"${python2_7_files[@]}"
|
||||
"${ED}"/usr/bin/fio_jsonplus_clat2csv
|
||||
)
|
||||
if use python ; then
|
||||
sed -i 's:python2.7:python:g' "${python2_7_files[@]}" || die
|
||||
python_replicate_script "${python2_7_files[@]}"
|
||||
use pandas || rm -f "${ED}"/usr/bin/fiologparser_hist.py
|
||||
else
|
||||
rm "${python_files[@]}" || die
|
||||
fi
|
||||
|
||||
local gnuplot_python2_7_files=(
|
||||
"${ED}"/usr/bin/fio2gnuplot
|
||||
)
|
||||
local gnuplot_files=(
|
||||
"${gnuplot_python2_7_files[@]}"
|
||||
"${ED}"/usr/bin/fio_generate_plots
|
||||
"${ED}"/usr/share/man/man1/fio_generate_plots.1
|
||||
"${ED}"/usr/share/man/man1/fio2gnuplot.1
|
||||
"${ED}"/usr/share/fio/*.gpm
|
||||
)
|
||||
if use gnuplot ; then
|
||||
sed -i 's:python2.7:python:g' "${gnuplot_python2_7_files[@]}" || die
|
||||
python_replicate_script "${gnuplot_python2_7_files[@]}"
|
||||
else
|
||||
rm "${gnuplot_files[@]}" || die
|
||||
rmdir "${ED}"/usr/share/fio/ || die
|
||||
fi
|
||||
|
||||
# This tool has security/parallel issues -- it hardcodes /tmp/template.fio.
|
||||
rm "${ED}"/usr/bin/genfio || die
|
||||
|
||||
dodoc README.rst REPORTING-BUGS HOWTO.rst
|
||||
docinto examples
|
||||
dodoc examples/*
|
||||
}
|
||||
@@ -12,6 +12,7 @@
|
||||
<flag name="curl">Enable HTTP engine for S3 and WebDav support support via <pkg>net-misc/curl</pkg></flag>
|
||||
<flag name="glusterfs">Enable GlusterFS gfapi support via <pkg>sys-cluster/glusterfs</pkg></flag>
|
||||
<flag name="gnuplot">Install tools for generating gnuplots</flag>
|
||||
<flag name="pandas">Install dependencies for complex python scripts</flag>
|
||||
<flag name="io-uring">Enable efficient I/O via <pkg>sys-libs/liburing</pkg>.</flag>
|
||||
<flag name="nfs">Enable NFS support</flag>
|
||||
<flag name="numa">Enable numa support</flag>
|
||||
|
||||
Reference in New Issue
Block a user