gnome-extra/nm-applet: bump to 1.4.6

Now has some gtk-docs for libnma, embeds GtkBuilder UI files as GResources
in the binaries, bug fixes. When built against networkmanager-1.6 will have
a new Proxy tab in connection editor (so we should revbump with a NM-1.6 dep
once we have NM-1.6)

Package-Manager: Portage-2.3.4, Repoman-2.3.1

gnome-extra/nm-applet/Manifest

@@ -1,2 +1,3 @@
 DIST network-manager-applet-1.2.4.tar.xz 1321740 SHA256 dff72956c939743e899954c9d32f0ebff4f213f1307a8157adc548584a0da37a SHA512 0cf9dd2db3289b29e550f96212c425c807b4a425d6a98cf00981e44d2bd5d1eb41c482072b5b030f32ae744c27f49a7757d762f7eda17cbba90560f0b3af1a30 WHIRLPOOL e2157108be89cbfab2327ded1bbee101c2332a5b8f85d3ad4bd490b4e4bcfb07f751d87ade9ef9538c2a1004abd6c146c6741eacd5c8825ad8392d40ae9b2277
 DIST network-manager-applet-1.4.2.tar.xz 1312280 SHA256 431b7b4876638c6a537c8bf9c91a9250532b3d960b22b056df554695a81e4499 SHA512 fedd1b41a1b5d63c1647f6801552ecb9676f93e88833dea7bf3e1dc43950c904d5deabdfefa50c46799b3e18297f9349f4462aa9531066482d78b30781e15b60 WHIRLPOOL 3a22d440526d56626eb1fbf24b513aded7c42de4c78a83d5a0a01f66f48807795f80e2f4029ff5887bedb6d966af873011741f24fd3bd8a81ac34cf98a2dcef8
+DIST network-manager-applet-1.4.6.tar.xz 1388916 SHA256 10a6fcfe8c6206cf18ec78a522a716b5ec9d0b7ca1e7d234c638725b316fec76 SHA512 f0eab5c50739c2309fa19336e23ead6603dc953b62fff0600a91988df8d41c2f300c22ebd4d5be8654a3fd7bac38dacc23be149f1a7085f10bb55e1830d9472f WHIRLPOOL f04c5bcf0796539b37fc1b83f81151be2fa68bb078209555196840617332ac8e624cc5911c9932b1768764c2bd696c613c760681d543f8e8e28d0f7f0bc7e221

gnome-extra/nm-applet/nm-applet-1.4.6.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+GNOME_ORG_MODULE="network-manager-applet"
+
+inherit gnome2
+
+DESCRIPTION="GNOME applet for NetworkManager"
+HOMEPAGE="https://wiki.gnome.org/Projects/NetworkManager"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE="+introspection modemmanager teamd"
+KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~x86"
+
+RDEPEND="
+	app-crypt/libsecret
+	>=dev-libs/glib-2.32:2[dbus]
+	>=dev-libs/dbus-glib-0.88
+	>=sys-apps/dbus-1.4.1
+	>=sys-auth/polkit-0.96-r1
+	>=x11-libs/gtk+-3.4:3[introspection?]
+	>=x11-libs/libnotify-0.7.0
+
+	app-text/iso-codes
+	>=net-misc/networkmanager-1.3:=[introspection?,modemmanager?,teamd?]
+	net-misc/mobile-broadband-provider-info
+
+	introspection? ( >=dev-libs/gobject-introspection-0.9.6:= )
+	virtual/freedesktop-icon-theme
+	virtual/libgudev:=
+	modemmanager? ( net-misc/modemmanager )
+	teamd? ( >=dev-libs/jansson-2.3 )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.0
+	>=dev-util/intltool-0.50.1
+	virtual/pkgconfig
+"
+
+PDEPEND="virtual/notification-daemon" #546134
+
+src_configure() {
+	gnome2_src_configure \
+		--without-appindicator \
+		--disable-more-warnings \
+		--disable-static \
+		--localstatedir=/var \
+		$(use_enable introspection) \
+		$(use_with modemmanager wwan) \
+		$(use_with teamd team)
+}