sci-electronics/nvc: bump to 1.23.1

Signed-off-by: Maciej Barć <xgqt@gentoo.org>
This commit is contained in:
Maciej Barć
2026-11-06 19:26:53 +01:00
parent 5e53c31815
commit af1beb4cc5
2 changed files with 117 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST nvc-1.23.0.tar.gz 2523973 BLAKE2B 48f1c30dea403bb821bd433b6a84bb12a56c74cbea0d1df218d3d64b4ee0d268939bc339d50a74117c238bdf0a460d6718569766f81ed182cabd1d4ace39894f SHA512 9a14c002b474729bd942fd944493886c00bc78acc24db09741d70b079089a3cbe5758cefe3e183e07e8bfa3585e51a205d9254b0835c6c822e988ba930b1ed42
DIST nvc-1.23.1.tar.gz 2528512 BLAKE2B 6d8025bf472113cfbdd49182f9844c4eb01eae2d753bddcbc042721de13f8c04b7fb122fe158af1ab7fdda2a439f69f60c266244a74d875326d6d2e7545f5875 SHA512 802fab09643ea2a26ca722a07e4ad522f786dc513ae9fb29efd21d5f374f38dfead64cc0a00270cbc1b3da3b76b3f77e549e12a7f5b7ab9cb8b9c1684e4fe6a9
+116
View File
@@ -0,0 +1,116 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
LLVM_COMPAT=( {20..22} )
inherit autotools llvm-r2 shell-completion
DESCRIPTION="NVC is a VHDL compiler and simulator"
HOMEPAGE="https://www.nickg.me.uk/nvc/
https://github.com/nickg/nvc/"
if [[ "${PV}" == *9999* ]] ; then
inherit git-r3
EGIT_REPO_URI="https://github.com/nickg/nvc"
NVC_SOURCEDIR="${WORKDIR}/${PN}-${PV}"
else
SRC_URI="https://github.com/nickg/nvc/archive/r${PV}.tar.gz
-> ${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
NVC_SOURCEDIR="${WORKDIR}/${PN}-r${PV}"
fi
NVC_BUILDDIR="${NVC_SOURCEDIR}_BuildDir"
S="${NVC_BUILDDIR}"
LICENSE="GPL-3+"
SLOT="0"
IUSE="llvm test"
RESTRICT="test" # Some tests fail.
RDEPEND="
app-arch/bzip2:=
app-arch/zstd:=
dev-libs/capstone:=
dev-libs/elfutils
dev-libs/icu:=
dev-libs/libffi:=
dev-libs/libxml2:=
sys-libs/ncurses:=
virtual/zlib:=
llvm? (
$(llvm_gen_dep '
llvm-core/llvm:${LLVM_SLOT}=
')
)
"
DEPEND="
${RDEPEND}
"
BDEPEND="
dev-libs/check
sys-apps/which
sys-devel/bison
sys-devel/flex
test? (
dev-libs/check
)
"
PATCHES=(
"${FILESDIR}/nvc-1.9.2-jit-code-capstone.patch"
"${FILESDIR}/nvc-1.21.1-fpurge.patch"
)
# Special libraries for NVC.
QA_FLAGS_IGNORED="usr/lib[0-9]*/nvc/preload[0-9]*.so usr/lib[0-9]*/nvc/plugins/siginit.so"
pkg_setup() {
if use llvm ; then
llvm-r2_pkg_setup
fi
}
src_unpack() {
default
mkdir -p "${S}" || die
}
src_prepare() {
pushd "${NVC_SOURCEDIR}" >/dev/null || die
default
eautoreconf
popd >/dev/null || die
}
src_configure() {
# Needs "bison" and "flex" exactly.
unset LEX
unset YACC
export V="1" # Verbose compilation and install.
local ECONF_SOURCE="${NVC_SOURCEDIR}"
local -a myconf=(
--enable-vital
--with-bash-completion="$(get_bashcompdir)"
$(use_enable llvm)
)
econf "${myconf[@]}"
}
src_compile() {
emake -j1
}
src_test() {
local -x ASAN_OPTIONS="detect_leaks=0"
local -x PATH="${S}/bin:${PATH}"
nonfatal emake -j1 check-TESTS
}
src_install() {
default
mv "${D}/$(get_bashcompdir)"/nvc{.bash,} || die
dostrip -x "/usr/$(get_libdir)/nvc"
}