x11-misc/mozo: add 1.26.1, EAPI=7, enable py3.11

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

x11-misc/mozo/Manifest

@@ -1,2 +1,3 @@
 DIST mozo-1.24.0.tar.xz 228180 BLAKE2B 6eb880b82dcb608f84efd8df74e77812f9da68dfa877ec896c6f04fa18088e8e4a82641c715e3620201dbb8a1bea8bb4ded09dd72f50770edae09c1326cbf453 SHA512 e0d217d2e7bb7d2c8df777e51bfb20e8bf4fa1bee0f9f3a9348ec1c8501b386a4afbd8848735ecfa61a0f9576382d784d3ef5b884a2a34af6ba33d3a126fe193
 DIST mozo-1.24.1.tar.xz 231032 BLAKE2B 27938aca9810943d19074cc5761ac58bb1dc2c1918b2fefea983f7a1b8788cb555311555515bb4387944c7b48a309de4a80da9003d212ca68ea257fa9ab06c8d SHA512 04b7e93e7302b46a3959f78655de4a6f8b17896be2c506c0e8a9041a9a2d5247e8c2ac00b5c8f86616f6c39a533584923feacfe4b81ae58d41080632af2a24bd
+DIST mozo-1.26.1.tar.xz 242836 BLAKE2B 59047b087e531792c0e831779d06a2dc7d9d2709bef7a7c8ba4a21d6f9fe1a79f917e2ba4e4912d655ad94391c0f7789e6ad6394be1a7bcb482881781f81c9ff SHA512 8570db4719d88bb34269a23acaa63638c5b7e50bf840bca73db718040c9d585670f1fd3be128c51ff22b4314f59dad6050907db8ce60bb506e4d46c3f807707e

x11-misc/mozo/mozo-1.26.1.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{8..11} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit mate python-r1
+
+DESCRIPTION="Mozo menu editor for MATE"
+LICENSE="GPL-2+ GPL-3+ LGPL-2+ LGPL-2.1+"
+
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=dev-python/pygobject-3:3[${PYTHON_USEDEP}]
+	>=mate-base/mate-menus-1.21.0[introspection]
+	x11-libs/gdk-pixbuf:2[introspection]
+	>=x11-libs/gtk+-3.22:3[introspection]
+	!!x11-misc/mate-menu-editor
+"
+
+RDEPEND="${COMMON_DEPEND}
+	virtual/libintl
+"
+DEPEND="${COMMON_DEPEND}
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	mate_src_prepare
+	python_copy_sources
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir mate_src_configure \
+		--disable-icon-update
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir default
+}
+
+src_test() {
+	python_foreach_impl run_in_build_dir emake check
+}
+
+src_install() {
+	installing() {
+		mate_src_install
+
+		# Massage shebang to make python_doscript happy
+		sed -e 's:#! '"${PYTHON}:#!/usr/bin/python:" \
+			-i mozo || die
+
+		python_doscript mozo
+		python_optimize
+	}
+
+	python_foreach_impl run_in_build_dir installing
+}