dev-python/translate-toolkit: Bump to 3.3.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/translate-toolkit/Manifest

@@ -1,2 +1,3 @@
 DIST translate-toolkit-3.2.0.tar.gz 6029254 BLAKE2B fe4c30e09fcba6755a928775f931f1027bb5678606e74aa435fd5803642ab39b8b55d763bb96dba6b1a957d6656cfca4ec6400b735afd8df7f2c1273ac173c89 SHA512 1045762a5c63cc2bc8459b61a85ef56e4f1d1f705d74646b8235169f22d8d5aa4ab5e3599af52a860d9e434df0fad3e98836b0c021bb0a9697b36a59edbfb6ec
 DIST translate-toolkit-3.3.0.tar.gz 6122607 BLAKE2B 77e4d4e37fa5fdd0a735b04ccef40769863134411476abe2852855970594f7a11cf06114831c196a744a5e76d50b1707b630a738213d0ded5f588ad98dcfd613 SHA512 3529e5301e8e1f0d89bbadff92cebd5d55ada29fe5eb8d611f604139239645dd6d110bf93180b18faf2ececafb675f2fc6dfbe30d7631ba606a7dfcd5d8f27ca
+DIST translate-toolkit-3.3.1.tar.gz 5969914 BLAKE2B 2ede440a341be0bd0206400d01bab881e6070820f362c53f47b5f88e192bcb7a18d2bf667a678378110046f70a035d42b67a77e2dc70829da323d69f675d21cc SHA512 1578fb8f96fa83ad97051a20f02d6570f96f2346d99fc86172718c995468c318f318f27f2ef259bd5dc10521bda4ac7da17385f72b726d7ea3c0fe65af8f313e

dev-python/translate-toolkit/translate-toolkit-3.3.1.ebuild

@@ -0,0 +1,99 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{7..9} )
+PYTHON_REQ_USE="sqlite"
+DISTUTILS_USE_SETUPTOOLS=rdepend
+inherit distutils-r1
+
+DESCRIPTION="Toolkit to convert between many translation formats"
+HOMEPAGE="https://github.com/translate/translate"
+SRC_URI="https://github.com/translate/translate/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+html +ical +ini +subtitles +yaml"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+DEPEND=">=dev-python/six-1.11.0[${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}
+	!dev-python/pydiff
+	app-text/iso-codes
+	>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
+	dev-python/cheroot[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.3.1[${PYTHON_USEDEP}]
+	>=dev-python/pycountry-19.8.18[${PYTHON_USEDEP}]
+	>=dev-python/python-levenshtein-0.12.0[${PYTHON_USEDEP}]
+	dev-python/ruamel-yaml[${PYTHON_USEDEP}]
+	sys-devel/gettext
+	html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
+	ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
+	ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
+	subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
+	yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
+"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx-bootstrap-theme
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/translate-toolkit-3.3.0-no-install-docs.patch
+)
+
+python_test() {
+	local deselect=(
+		# Not packaging optional phply for now.
+		# Seems inactive upstream.
+		--ignore translate/convert/test_php2po.py
+		--ignore translate/convert/test_po2php.py
+		--ignore translate/storage/test_php.py
+		--deselect 'translate/storage/test_cpo.py::TestCPOUnit::test_buildfromunit'
+		--deselect 'translate/storage/test_po.py::TestPOUnit::test_buildfromunit'
+		--deselect 'translate/storage/test_pypo.py::TestPYPOUnit::test_buildfromunit'
+
+		# Fails with network-sandbox (and even with it off but w/ softer fail)
+		--deselect 'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
+		--deselect 'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
+	)
+
+	if ! use ini; then
+		deselect+=(
+			--ignore translate/convert/test_ini2po.py
+			--ignore translate/convert/test_po2ini.py
+		)
+	fi
+
+	if ! use subtitles; then
+		deselect+=(
+			--ignore translate/storage/test_subtitles.py
+		)
+	fi
+
+	# translate/storage/test_mo.py needs 'pocompile'
+	distutils_install_for_testing --via-root
+
+	pytest -vv "${deselect[@]}" || die "Tests failed with ${EPYTHON}"
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+
+	if ! use html; then
+		rm "${ED}"/usr/bin/{html2po,po2html} || die
+	fi
+	if ! use ical; then
+		rm "${ED}"/usr/bin/{ical2po,po2ical} || die
+	fi
+	if ! use ini; then
+		rm "${ED}"/usr/bin/{ini2po,po2ini} || die
+	fi
+	if ! use subtitles; then
+		rm "${ED}"/usr/bin/{sub2po,po2sub} || die
+	fi
+
+	python_optimize
+}