kde-apps/kio-extras-kf5: 24.02.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
2026-11-09 06:37:10 -08:00 · 2024-03-21 16:34:48 +01:00
parent 6caeeb172f
commit ade47ce137
2 changed files with 104 additions and 0 deletions
@@ -1 +1,2 @@
 DIST kio-extras-kf5-24.02.0.tar.xz 1466300 BLAKE2B 7dff74be32df25b09848e77608fd34899022de9243182efdf752d05597040ddd8b94c214d0ca687df143a83eea0acc7aed4d2b829b3da207c3519a6ba6722ed2 SHA512 f24dc142084220f8e87e740891f96952def8fd687975d5c7b7b598d66734de6deb2dd86c78af8b1ac44b1216131db44a2cdb2fcf2f16615072dfd4f3273b09bc
+DIST kio-extras-kf5-24.02.1.tar.xz 1467996 BLAKE2B 3f477146cf37b3250bfcebeeee070eb807498226488ad9cc4ef803fbb8a33bba3e54b9ea221e19a0bb35dfb04f54dc7e39ec6fa9df29e12686aaa0de273fef7e SHA512 9f013c54eec0a540bc4fa45e4e98fc4215d12fcadaa442e92c63aee222cba443e14da8ab1612d63e5ab42ec419bf203f16edf61678ff29f30949bab43d244e6e
@@ -0,0 +1,103 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="optional"
+KDE_ORG_NAME="kio-extras"
+KDE_ORG_TAR_PN="kio-extras-kf5"
+KFMIN=5.115.0
+QTMIN=5.15.12
+inherit ecm gear.kde.org
+
+DESCRIPTION="KIO plugins present a filesystem-like view of arbitrary data"
+HOMEPAGE="https://invent.kde.org/network/kio-extras/-/tree/kf5"
+EGIT_BRANCH="kf5"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="activities ios kf6compat +man mtp nfs openexr phonon samba +sftp taglib X"
+
+# requires running Plasma environment
+RESTRICT="test"
+
+DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	kde-apps/libkexiv2:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdnssd-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/solid-${KFMIN}:5
+	>=kde-frameworks/syntax-highlighting-${KFMIN}:5
+	activities? (
+		>=dev-qt/qtsql-${QTMIN}:5
+		>=kde-plasma/plasma-activities-${KFMIN}:5
+		>=kde-plasma/plasma-activities-stats-${KFMIN}:5
+	)
+	ios? (
+		app-pda/libimobiledevice:=
+		app-pda/libplist:=
+	)
+	mtp? ( >=media-libs/libmtp-1.1.16:= )
+	nfs? ( net-libs/libtirpc:= )
+	openexr? ( media-libs/openexr:= )
+	phonon? ( >=media-libs/phonon-4.11.0[qt5(+)] )
+	samba? (
+		net-fs/samba[client]
+		net-libs/kdsoap:=[qt5(+)]
+	)
+	sftp? ( net-libs/libssh:=[sftp] )
+	taglib? ( >=media-libs/taglib-1.11.1:= )
+	X? (
+		x11-libs/libX11
+		x11-libs/libXcursor
+	)
+"
+RDEPEND="${DEPEND}
+	!<kde-apps/kio-extras-23.08.5-r100:5
+	>=kde-frameworks/kded-${KFMIN}:5
+	kf6compat? ( kde-apps/kio-extras:6 )
+"
+BDEPEND="man? ( dev-util/gperf )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_ACTIVITIES=$(usex activities)
+		$(cmake_use_find_package ios IMobileDevice)
+		$(cmake_use_find_package ios PList)
+		$(cmake_use_find_package man Gperf)
+		$(cmake_use_find_package mtp Libmtp)
+		$(cmake_use_find_package nfs TIRPC)
+		-DKF6_COMPAT_BUILD=$(usex kf6compat)
+		$(cmake_use_find_package openexr OpenEXR)
+		$(cmake_use_find_package phonon Phonon4Qt5)
+		$(cmake_use_find_package samba Samba)
+		$(cmake_use_find_package sftp libssh)
+		$(cmake_use_find_package taglib Taglib)
+		-DWITHOUT_X11=$(usex !X)
+	)
+
+	use samba && mycmakeargs+=(
+		# do not attempt to find now Qt6-based system version
+		-DCMAKE_DISABLE_FIND_PACKAGE_KDSoapWSDiscoveryClient=ON
+	)
+
+	ecm_src_configure
+}