net-misc/smb4k: add 4.0.7

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-misc/smb4k/Manifest

@@ -1 +1,2 @@
 DIST smb4k-4.0.6.tar.xz 4871876 BLAKE2B a772ff997e7e885ca333b2724e8e7d4e2954db2930e384228669078b34767a2d0f3506bc00f91e26ee8e32707aacccee9e063bcdfc1d34b0dcbaf5d89c38c5ea SHA512 502b71e9617c90c3f6e5d0a7967995f77581cf7663c4debb9810f98ad5cf7ef38f0bc6552c63f52b135aa6f3cf8d083889a9e3107b1943e1b318cd6923789081
+DIST smb4k-4.0.7.tar.xz 4879756 BLAKE2B b34b13f0310b307758d7dcfa102927ecaec1d53a1c1185338de18c1114a53e3d8e6606bc4eaa60e40329cdb171af0b8cea3ce8fd1c8e557a2331a885f5052b7c SHA512 f87f0878f4fe6ed0acf260a0fccc2dde6807b09b90a89386c469c3b2f84476eace2664dbbfeb36cf8e435045ec874a4497e0d093ae02b559e526746c2538b035

net-misc/smb4k/smb4k-4.0.7.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=6.9.0
+QTMIN=6.8.1
+inherit ecm kde.org xdg
+
+DESCRIPTION="Advanced network neighborhood browser"
+HOMEPAGE="https://apps.kde.org/smb4k/
+https://sourceforge.net/p/smb4k/home/Home/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="https://downloads.sourceforge.net/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+discovery plasma"
+
+DEPEND="
+	>=dev-libs/qtkeychain-0.14.2:=[qt6(+)]
+	>=dev-qt/qtbase-${QTMIN}:6[gui,network,widgets]
+	>=dev-qt/qtdeclarative-${QTMIN}:6
+	>=kde-frameworks/kauth-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/kdbusaddons-${KFMIN}:6
+	>=kde-frameworks/kdnssd-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/knotifications-${KFMIN}:6
+	>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
+	>=kde-frameworks/kwallet-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kwindowsystem-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	net-fs/samba[cups]
+	discovery? (
+		>=net-libs/kdsoap-2.2.0:=[qt6(+)]
+		>=net-libs/kdsoap-ws-discovery-client-0.4.0
+	)
+"
+RDEPEND="${DEPEND}
+	!${CATEGORY}/${PN}:5
+	plasma? (
+		>=kde-frameworks/kirigami-${KFMIN}:6
+		kde-plasma/libplasma:6
+	)
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DSMB4K_WITH_WS_DISCOVERY=$(usex discovery)
+		-DSMB4K_INSTALL_PLASMOID=$(usex plasma)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	elog "Users of Samba 4.7 and above please note that for the time being,"
+	elog "the following setting has to be added to or changed in the [global]"
+	elog "section of the smb.conf file:"
+	elog
+	elog "[global]"
+	elog "client max protocol = NT1"
+}