media-video/vidcutter: add 6.0.5.1_p20250419

Compatible with python 3.13

Thanks-to: Bill Prendergast
Bug: https://bugs.gentoo.org/929679
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

media-video/vidcutter/Manifest

@@ -1 +1,2 @@
 DIST vidcutter-6.0.5.1_p20230201.tar.gz 9858362 BLAKE2B da10506810f93f5635a364d35f293a2c587455ee5c29cf28c0636b7441e330e6ab70385c22d9da914a22c71fed9f6d13688bcac9106d4430e5820fdd2b377d28 SHA512 1b355db77f4e78ade6c0553441d9b60739209fde74db6d9f0be3613e31f99806c94f33bf40912a43106dfc77bde09a54768d5786e06116af3dae2f9851823041
+DIST vidcutter-6.0.5.1_p20250419.tar.gz 9905936 BLAKE2B c64cb1a85b6d131c05922740de5929f67f64ddcb5533c8d4b3b9cbd19cef3b2fdf5c0cc63999ffb316c9ad4e06155fd179cc7cfeca02dd5ee790fec98a35a511 SHA512 c00034800f533137c4d2299d956b41600590cabce1f9c848b832d74b7e37982586741f8c9856199a5c9a92c2d1faca9e585d0df05dd713923eaf97b0006cd41e

media-video/vidcutter/vidcutter-6.0.5.1_p20250419.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_EXT=1
+
+inherit distutils-r1 xdg
+
+MY_COMMIT="db6818f11bbb4d5598dfc5ceeddf7f81c7078499"
+DESCRIPTION="FFmpeg-based simple video cutter & joiner with a modern PyQt5 GUI"
+HOMEPAGE="http://vidcutter.ozmartians.com https://github.com/ozmartian/vidcutter"
+
+if [[ ${PV} == 9999 ]];then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/ozmartian/vidcutter"
+else
+	SRC_URI="https://github.com/ozmartian/${PN}/archive/${MY_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+S="${WORKDIR}/${PN}-${MY_COMMIT}"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+LICENSE="GPL-3"
+SLOT="0"
+
+DEPEND="
+	>=media-video/mpv-0.25:=[libmpv]
+"
+RDEPEND="${DEPEND}
+	>=dev-python/pyqt5-5.7[dbus,multimedia,widgets,${PYTHON_USEDEP}]
+	dev-python/pyopengl[${PYTHON_USEDEP}]
+	media-video/ffmpeg[X,encode(+)]
+	media-video/mediainfo
+"
+BDEPEND="
+	${PYTHON_DEPS}
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+python_prepare_all() {
+	# https://bugs.gentoo.org/929679
+	rm vidcutter/libs/pympv/mpv.c || die
+	distutils-r1_python_prepare_all
+}
+
+src_install() {
+	distutils-r1_src_install
+	mv "${ED}"/usr/share/doc/{${PN},${PF}} || die
+}