app-text/enscript: update EAPI 7 -> 8

Closes: https://bugs.gentoo.org/943994
Signed-off-by: Alexey Sokolov <alexey+gentoo@asokolov.org>
Part-of: https://github.com/gentoo/gentoo/pull/44425
Closes: https://github.com/gentoo/gentoo/pull/44425
Signed-off-by: Sam James <sam@gentoo.org>

app-text/enscript/enscript-1.6.6-r2.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit toolchain-funcs
+
+DESCRIPTION="Powerful text-to-postscript converter"
+HOMEPAGE="https://www.gnu.org/software/enscript/enscript.html"
+SRC_URI="mirror://gnu/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
+IUSE="nls ruby"
+
+RDEPEND="nls? ( virtual/libintl )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-alternatives/lex
+	app-alternatives/yacc
+	nls? ( sys-devel/gettext )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.6.4-ebuild.st.patch
+	"${FILESDIR}"/${PN}-1.6.5.2-php.st.patch
+	"${FILESDIR}"/${PN}-1.6.4-fsf-gcc-darwin.patch
+	"${FILESDIR}"/${PN}-1.6.2-implicit-function-decl.patch
+	"${FILESDIR}"/${PN}-1.6.6-gcc15.patch
+)
+
+src_prepare() {
+	default
+
+	use ruby && eapply "${FILESDIR}"/enscript-1.6.2-ruby.patch
+
+	sed -i src/tests/passthrough.test -e 's|tail +2|tail -n +2|g' || die
+}
+
+src_configure() {
+	econf $(use_enable nls)
+}
+
+src_compile() {
+	emake AR="$(tc-getAR)"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+
+	dodoc AUTHORS ChangeLog NEWS README* THANKS TODO
+
+	insinto /usr/share/enscript/hl
+	doins "${FILESDIR}"/ebuild.st
+
+	if use ruby ; then
+		insinto /usr/share/enscript/hl
+		doins "${FILESDIR}"/ruby.st
+	fi
+}

app-text/enscript/files/enscript-1.6.6-gcc15.patch

@@ -0,0 +1,16 @@
+https://sources.debian.org/src/enscript/1.6.5.90-3.2/debian/patches/1096582-gcc-15
+
+--- a/compat/regex.c
++++ b/compat/regex.c
+@@ -336,7 +336,10 @@ typedef char boolean;
+ #define false 0
+ #define true 1
+ 
+-static int re_match_2_internal ();
++static int re_match_2_internal (struct re_pattern_buffer *bufp,
++	const char *string1, int size1,
++	const char *string2, int size2,
++	int pos, struct re_registers *regs, int stop);
+ 
+ /* These are the command codes that appear in compiled regular
+    expressions.  Some opcodes are followed by argument bytes.  A