kde-frameworks/kfilemetadata: 6.19.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-frameworks/kfilemetadata/Manifest

@@ -1,2 +1,3 @@
 DIST kfilemetadata-6.16.0.tar.xz 696968 BLAKE2B 69b7ffbbfdb55265e537783b3fe72dbe966113ec23ca554a435f5ab9530a6b269f32e113ff27673f96efdbd7f04e7f4468ce1cdef731563bf923180c9a09fcac SHA512 ea0772a06f022ce0d50e1994957025801875b0adef6c84e9cd4faeecabe4fae511e00874f6759ead45d201e874726e135aebbd7cd1476512446b830bd5caf6dc
 DIST kfilemetadata-6.18.0.tar.xz 702700 BLAKE2B 2f34e594c0aca4dccc3e6fde1acec4406af23b183a8d5436dd174b2147c39d24bcd45857deecd693a9bc28ba5ea9153838d9b4010213bf4df62917c32f600632 SHA512 c8648635ac02e5ef72e78d3099537c0c0253fb1068faea797f2031588aa9f056c2b1bcd6326ccd969a2834fb9011ea07dd84831ade1dda5bf6a37177be002a44
+DIST kfilemetadata-6.19.0.tar.xz 702724 BLAKE2B d1c5a2d8f1b8b60a4f03a05163df3d64c38082815fec05620cd84003e095a49e82bb2b5355edb3fadf7071aaa607bd0adda0b76b2f354f7fae156ee2fb1edbe0 SHA512 a160ac11f43e8c7c8c401802d77fb5f8259608ffec616100079cdc646fa9b9abd1e56b00bc26351fdc82dab8364ec71161d9d3a4664cac18f343ac1190237ecf

kde-frameworks/kfilemetadata/kfilemetadata-6.19.0.ebuild

@@ -0,0 +1,64 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+QTMIN=6.7.2
+inherit ecm frameworks.kde.org optfeature python-any-r1
+
+DESCRIPTION="Library for extracting file metadata"
+
+LICENSE="LGPL-2+"
+KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="epub exif ffmpeg mobi pdf taglib"
+
+RESTRICT="test"
+
+RDEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[gui,xml]
+	=kde-frameworks/karchive-${KDE_CATV}*:6
+	=kde-frameworks/kcodecs-${KDE_CATV}*:6
+	=kde-frameworks/kcoreaddons-${KDE_CATV}*:6
+	=kde-frameworks/ki18n-${KDE_CATV}*:6
+	epub? ( app-text/ebook-tools )
+	exif? ( media-gfx/exiv2:= )
+	ffmpeg? ( media-video/ffmpeg:0= )
+	mobi? ( kde-apps/kdegraphics-mobipocket:6 )
+	pdf? ( app-text/poppler[qt6(-)] )
+	taglib? ( media-libs/taglib:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-apps/attr )
+"
+BDEPEND="test? ( ${PYTHON_DEPS} )"
+
+CMAKE_SKIP_TESTS=(
+	# FIXME: bug 644650, fails on tmpfs (but not for everyone)
+	usermetadatawritertest
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package epub EPub)
+		$(cmake_use_find_package exif LibExiv2)
+		$(cmake_use_find_package ffmpeg FFmpeg)
+		$(cmake_use_find_package mobi QMobipocket6)
+		-DENABLE_MOBIPOCKET_TEXT_EXTRACTION=OFF
+		$(cmake_use_find_package pdf Poppler)
+		$(cmake_use_find_package taglib Taglib)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Microsoft Word/Powerpoint file indexing" app-text/catdoc
+		optfeature "Microsoft Excel file indexing" dev-libs/libxls
+	fi
+}