media-sound/ncmpcpp: Version bump.

Package-Manager: portage-2.2.20.1

media-sound/ncmpcpp/Manifest

@@ -1,2 +1,3 @@
 DIST ncmpcpp-0.6.4.tar.bz2 429705 SHA256 757e2e06b7e17009c24e2b46a69f008e61aa679476f93e00dc602ca087c805f1 SHA512 c60a6c2c89a9297d73360ec8819e8ae66ca53090c5ea5d3daf235e708467ee20006b1fff344c9312ccb0941c8307f3d84bcdc9cbf500955c74b10bd6a823c19f WHIRLPOOL 56bd22148f38289030a558b43008f83e9e0ccd1ff178be183ad935d08b397de51c49f2c7d84ab9504b62b0105516f460ff131d65a99af9e73519783e15c84797
 DIST ncmpcpp-0.6.5.tar.bz2 429699 SHA256 51128f6835c592c8d4367a66b08e06a9419a86c9d5c6e91d0f1dc73af56cd1fd SHA512 b120bd3c0697d51755e04908d29ddd4180ae662d3f02d60e967ccbefca87471eaf0dcf4ebed5d76203b7a0a6dd17a397f318a65087c1b8ec1e3fb4178964e581 WHIRLPOOL c4fa51645de9f1c7a530ee06113bc0fce5954d155112de4921dec2af5da58465b646c193f8359708b51619ec5f0fc9968680ec22549f97352f9309006499c77b
+DIST ncmpcpp-0.6.6.tar.bz2 429353 SHA256 2b7408b207c3ffd1ddd11bcb9c0a1f2434bb80db990dcf482968cf915ebc0e67 SHA512 5f288c1e5b96b38586e6c3230b09380584e902bc5d44147433093c48e4b61efd32b3b405ee96b4341e56ab2b26590ed2320bf1ca188e46796c13be5da52acb58 WHIRLPOOL f4976fac3eb65f8952104b545d9532c743a07de987ebb0c89fb2ba51f359748ec8a14dc143330fe37e7e0d6115125c834d2a05c6d640214926dae384f4315f05

media-sound/ncmpcpp/ncmpcpp-0.6.6.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+inherit eutils
+
+DESCRIPTION="featureful ncurses based MPD client inspired by ncmpc"
+HOMEPAGE="http://ncmpcpp.rybczak.net/"
+SRC_URI="http://ncmpcpp.rybczak.net/stable/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86"
+IUSE="clock curl outputs taglib unicode visualizer"
+
+RDEPEND="
+	>=media-libs/libmpdclient-2.1
+	curl? ( net-misc/curl )
+	dev-libs/boost:=[nls,threads]
+	sys-libs/ncurses[unicode?]
+	sys-libs/readline:*
+	taglib? ( media-libs/taglib )
+	visualizer? ( sci-libs/fftw:3.0 )
+"
+DEPEND="
+	${RDEPEND}
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	sed -i -e '/^docdir/d' {,doc/}Makefile{.am,.in} || die
+	sed -i -e 's|COPYING||g' Makefile{.am,.in} || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable clock) \
+		$(use_enable outputs) \
+		$(use_enable unicode) \
+		$(use_enable visualizer) \
+		$(use_with curl) \
+		$(use_with taglib) \
+		$(use_with visualizer fftw) \
+		--docdir=/usr/share/doc/${PF}
+}
+
+src_install() {
+	default
+
+	dodoc doc/{bindings,config}
+}
+
+pkg_postinst() {
+	echo
+	elog "Example configuration files have been installed at"
+	elog "${ROOT}usr/share/doc/${PF}"
+	elog "${P} uses ~/.ncmpcpp/config and ~/.ncmpcpp/bindings"
+	elog "as user configuration files."
+	echo
+	if use visualizer; then
+	elog "If you want to use the visualizer, you need mpd with fifo enabled."
+	echo
+	fi
+}