gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

kde-apps/kmix: 25.04.1 version bump

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2025-05-08 18:00:59 +02:00
parent 699a22b3ca
commit acb3d48efa
2 changed files with 79 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
kde-apps/kmix/Manifest
View File

@@ -1,2 +1,3 @@
DIST kmix-24.12.3.tar.xz 1167852 BLAKE2B 0e71e92d3b9bdbbf446c84d305788d6accf1d953326e99651088a68aa08f370b5274f29b2369cc88ba68384ddb7319f4e61cc90aa4b67c19b1ec00fd3f0d62c4 SHA512 c966de6ec9a9160538b0291be36bb84aab4888d20955aa2b141ad5c1b7295e90e9026af0033735ba271c2256bc6291f5c90cb5d0471eff5185715a3ba505e446
DIST kmix-25.04.0.tar.xz 1177276 BLAKE2B 33f5acc4eff1b004e6efd1232d390c8ff0f4f4cd57d51077ae23e7c9a7992d6d9ba0c1a73524d41ba4e9650baf1c6fbf66624826651ca86aa1ce852777dda676 SHA512 51dea92790753228ae356a732f6045b6923dae97e2035d8799d7cf432408534d7332608b2e57cada132a07dda6d0c32ad1695d504da11e5ebb4606101ba01814
DIST kmix-25.04.1.tar.xz 1177276 BLAKE2B 5b37156c5a5087c25055f582987f528b822eb8f3ccca2dfd38606ef58c4d205bca31c35e29cf538d93490feb86673fa46b6365dc1482a7bf8574ce09639d32ef SHA512 b93f6a8dc921139894bcebe2f416a922e43ec5b017ecdc3531369db5685271a4bdb10f6e490fdbfc6ced3356845e52eb85b5d043cbadec0c90f68c927981a072

78
kde-apps/kmix/kmix-25.04.1.ebuild Normal file
View File

@@ -0,0 +1,78 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="forceoptional"
ECM_TEST="false"
KFMIN=6.13.0
QTMIN=6.7.2
inherit ecm gear.kde.org xdg
DESCRIPTION="Volume control gui based on KDE Frameworks"
HOMEPAGE="https://apps.kde.org/kmix/"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
IUSE="alsa pulseaudio"
# kde-frameworks/kwindowsystem[X]: Unconditional use of KX11Extras
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets,xml]
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kglobalaccel-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kstatusnotifieritem-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6[X]
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/solid-${KFMIN}:6
alsa? ( >=media-libs/alsa-lib-1.0.14a )
pulseaudio? (
media-libs/libcanberra
media-libs/libpulse
)
"
RDEPEND="${DEPEND}"
PATCHES=(
# TODO: upstream
"${FILESDIR}/${PN}-23.04.2-autostart_disable.patch"
# Pending: https://invent.kde.org/multimedia/kmix/-/merge_requests/29
"${FILESDIR}/${PN}-24.12.2-revert-kcm_pulseaudio-dep.patch"
# Regressed in: https://invent.kde.org/multimedia/kmix/-/merge_requests/32
"${FILESDIR}/${PN}-25.03.90-revert-sndio-automagic.patch"
)
src_configure() {
local mycmakeargs=(
# XXX: sndio is maybe automagic since 5075cc9502b2768471fd917671fd98bfe5b877cc
$(cmake_use_find_package alsa ALSA)
$(cmake_use_find_package pulseaudio Canberra)
$(cmake_use_find_package pulseaudio PulseAudio)
)
ecm_src_configure
}
pkg_postinst() {
if use pulseaudio && has_version kde-plasma/plasma-pa; then
elog "In KDE Plasma, kde-plasma/plasma-pa is the default audio volume handler,"
elog "therefore, autostart by default was disabled for KMix."
elog
elog "Should you prefer to still use kde-apps/kmix instead, do the following:"
elog " - In system tray, right click on [Show hidden items]"
elog " - Select [Configure System Tray]"
elog " - In [Entries], search for [Audio Volume] and set it to [Disabled]"
elog
fi
elog "KMix will be shown as [Volume Control] after manually starting it once"
elog "and will be autostarted after configuring such in KMix startup settings."
xdg_pkg_postinst
}