gnustep-base/gnustep-gui: add 0.32.0

Signed-off-by: Bernard Cafarelli <voyageur@gentoo.org>

gnustep-base/gnustep-gui/Manifest

@@ -1 +1,2 @@
 DIST gnustep-gui-0.31.1.tar.gz 3103556 BLAKE2B 633e2dc012c40e56cb62f430631c568b88e6ba5f39d4deb4c89ca9767614dab17793e484e7e77f4cf0b4e764059f2697bd1f531bb2a0f85f3eaeac1a75a2d738 SHA512 82c598d6fc962716c930eb27419c9c8296d663053cfef0f489e1f28dd1fac054d18859e9cc60f246c2a53a175404c1c8db0b36a90ad372c80d0158bc24ff4d69
+DIST gnustep-gui-0.32.0.tar.gz 3116133 BLAKE2B d948fedebaba1ce11089ce6f88891b1c58298fff3858a8209b633edc702398fa6c3136ba3358878f8a904f397cb49b206ab629fdeec8486de8f9ada0c57f96ad SHA512 6c85d943f8fac98590064f4bc5635bdb8a0c0aa962a852fbce0ecec95f472f3563273f757dee263d65b0219e4f8d584877776c4c38b7134f993f12887079e5b2

gnustep-base/gnustep-gui/gnustep-gui-0.32.0.ebuild

@@ -0,0 +1,56 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit gnustep-base multilib virtualx
+
+DESCRIPTION="Library of GUI classes written in Obj-C"
+HOMEPAGE="https://gnustep.github.io/"
+SRC_URI="https://ftp.gnustep.org/pub/gnustep/core/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="cups icu jpeg png speech"
+
+DEPEND="${GNUSTEP_CORE_DEPEND}
+	app-text/aspell
+	>=gnustep-base/gnustep-base-1.3.0:=[icu?]
+	media-libs/audiofile
+	>=media-libs/giflib-4.1:=
+	>=media-libs/tiff-3:=
+	x11-libs/libXt
+	cups? ( >=net-print/cups-1.7.4:= )
+	icu? ( dev-libs/icu:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	png? ( >=media-libs/libpng-1.2:= )
+	speech? ( app-accessibility/flite )"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	gnustep-base_src_prepare
+
+	# remove hardcoded -g -Werror, bug #378179
+	sed -i -e 's/-g -Werror//' \
+		Tools/say/GNUmakefile \
+		Tools/speech/GNUmakefile \
+		|| die
+}
+
+src_configure() {
+	egnustep_env
+
+	econf \
+		$(use_enable cups) \
+		$(use_enable icu) \
+		$(use_enable jpeg) \
+		$(use_enable png) \
+		$(use_enable speech) \
+		--disable-ungif --enable-libgif \
+		--with-tiff-include="${EPREFIX}"/usr/include \
+		--with-tiff-library="${EPREFIX}"/usr/$(get_libdir)
+}
+
+src_test() {
+	virtx default
+}