www-apps/radicale: bump to 3.8.3

Signed-off-by: Henning Schild <henning@hennsch.de>
Part-of: https://codeberg.org/gentoo/gentoo/pulls/2032
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
This commit is contained in:
Henning Schild
2026-10-13 08:26:28 +03:00
committed by Viorel Munteanu
parent 3b6b83b581
commit abc955123b
2 changed files with 100 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST Radicale-3.7.7.gh.tar.gz 359951 BLAKE2B 787cdbccfdeee5f931e9ca5a77539258293add2d0acc57ec80776b5db358d1ece5f1978a7fcf826b35d59a3188841713aec920a5e5584d23ad50c46966eb2253 SHA512 68d22ef711cb1dd6ecbac2e8754b3acf2004c304d00356361ad29219b9a6139b29f327621811178046c2b96f64c3792868eeb3a3292a0b64db8c0474e9822d13
DIST Radicale-3.8.1.gh.tar.gz 389961 BLAKE2B 95d73199d0490b2dd587f8e097390241ae4ff77ccc26d005fd156bbe163cf0435d848792417466afab0483f4ecde14e2994e914cc8cdca3d6f4e6fe3c42767e0 SHA512 6284f1d8577fbab2792fcdfc80ea62b68f5639d446e8d3351f4b4f57f066000455708b311b8643d626d0f29445e3c2f36ebbf147f4887cf87461e035c47bbdfa
DIST Radicale-3.8.3.gh.tar.gz 418482 BLAKE2B 05045d94a7846763da72d25f2035bc7e748a00a9ce664ff55bdf209d5a1e5f522cc51434cef1a56eade8acc2a4dfed92874d6494c931e04893d0d258c4b8c93d SHA512 605be4604044c57fa0cb8b50b7d9551222070fe52276913adcb277a80089790176520955cecd3b3bc1c6512af6a063fee410e98047dacc1329b3258c3e82c07a
+99
View File
@@ -0,0 +1,99 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..14} )
inherit distutils-r1 eapi9-ver optfeature systemd
MY_P=${P^}
DESCRIPTION="A simple CalDAV calendar server"
HOMEPAGE="https://radicale.org/"
SRC_URI="
https://github.com/Kozea/Radicale/archive/refs/tags/v${PV}.tar.gz
-> ${MY_P}.gh.tar.gz
"
S=${WORKDIR}/${MY_P}
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~x86"
RDEPEND="
>=acct-user/radicale-0-r2
acct-group/radicale
dev-python/defusedxml[${PYTHON_USEDEP}]
dev-python/libpass[${PYTHON_USEDEP}]
dev-python/vobject[${PYTHON_USEDEP}]
sys-apps/util-linux
"
BDEPEND="
test? (
dev-python/pytest[${PYTHON_USEDEP}]
dev-python/waitress[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
RDIR=/var/lib/"${PN}"
DOCS=( DOCUMENTATION.md CHANGELOG.md )
python_test() {
epytest -o addopts= radicale/tests/
}
python_install_all() {
rm README* || die
# init file
newinitd "${FILESDIR}"/radicale-r4.init.d radicale
systemd_dounit "${FILESDIR}/${PN}.service"
# directories
keepdir "${RDIR}"
fperms 0750 "${RDIR}"
fowners "${PN}:${PN}" "${RDIR}"
# config file
insinto /etc/"${PN}"
doins config
# fcgi and wsgi files
exeinto /usr/share/"${PN}"
doexe radicale.wsgi
distutils-r1_python_install_all
}
pkg_postinst() {
local _erdir="${EROOT}${RDIR}"
if ver_replacing -lt "3.5.0"; then
ewarn ""
ewarn "Since 3.5.0 the default [auth] type is \"denyall\". You need to"
ewarn "change your config if you used the default type so far!"
ewarn ""
fi
einfo "A sample WSGI script has been put into ${EROOT}/usr/share/${PN}."
einfo "You will also find there an example FastCGI script."
if [[ $(stat --format="%U:%G:%a" "${_erdir}") != "${PN}:${PN}:750" ]]
then
ewarn ""
ewarn "Unsafe file permissions detected on ${_erdir}."
ewarn "This probably comes from an earlier version of this ebuild."
ewarn "To fix run:"
ewarn "# \`chown -R ${PN}:${PN} ${_erdir}\`"
ewarn "# \`chmod 0750 ${_erdir}\`"
ewarn "# \`chmod -R o= ${_erdir}\`"
fi
optfeature "Publish changes to rabbitmq" dev-python/pika
optfeature "LDAP/LDAPS authentication" dev-python/ldap3 dev-python/python-ldap
optfeature "bcrypt password hashing" dev-python/bcrypt
optfeature "argon2 password hashing" dev-python/argon2-cffi
optfeature "PAM authentication" dev-python/python-pam
}