dev-python/setuptools: Bump to 60.1.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/setuptools/Manifest

@@ -11,3 +11,4 @@ DIST setuptools-60.0.2.tar.gz 2284789 BLAKE2B b3763673e65ae7e6e7d8d2e7bb5d4b72e3
 DIST setuptools-60.0.3.tar.gz 2284909 BLAKE2B 39fab878aa5d9ae4712088a96548cf3312070c6bca59d6fb22642bc5fb9919acf1ad151c63f812a5bdddffdb657fff9631330d93685e9a54e569daaa5b3f2760 SHA512 3020182f30f85eef07952085aed90db42e205abe754eb130327651edd3fdb7fcca52b0654d6c7bc69e5b33920549675f2325bebdc4c71425e212275f49572a10
 DIST setuptools-60.0.4.tar.gz 2282600 BLAKE2B bc2e9c38f9646babce1144cfc1751c034fa2783149ad47c8365a4a2e56b4176b6f0e7a44d1cb5567c34b792cb85b52a7553be09eee34d8f079e67f0a09fb54a6 SHA512 f3dae0e4ac9553a35864978db24041f26b7ea05ba07a7f791a30d3910b23d50eb44b75b9f06f1644c0409344aff153b09417b520957d01bccf6413cdaecf9ced
 DIST setuptools-60.0.5.tar.gz 2285236 BLAKE2B 75255465933957e5e8a6cab84d27c0bbab506c70db80c4bfad5d81c61f5ef331fd3d0eec7769cc7da35f670f120d571d455dab40abbaf88e95cec83349a97e6f SHA512 0a92953b9650a06b30b1c3dc8e24ea462ccdd78b177ce0f372dc62cf8395d3df2e25b53d74d174b86e1b44e7ee1dc1852ab6c49d9f78972acd551b692fcc4b49
+DIST setuptools-60.1.0.tar.gz 2281751 BLAKE2B d6302564ccb841232561c479959d2ed412888b49c07f774f194214ded659d7d45c5328570318ded9ff7eb81fc08e20b8be576f7a38099cfb855833955bbdb3a6 SHA512 9dba9022be345f5e0c9a915cfd8a24b441e813e703c817f40cd36236d1de1af8a5227acd886ca5910f1900e0c6ed5836f181117c11486009588a9777d6855032

dev-python/setuptools/setuptools-60.1.0.ebuild

@@ -0,0 +1,89 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+# please keep this ebuild at EAPI 7 -- sys-apps/portage dep
+EAPI=7
+
+# Set to 'manual' to avoid triggering install QA check
+DISTUTILS_USE_SETUPTOOLS=manual
+PYTHON_COMPAT=( python3_{8..10} pypy3 )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 multiprocessing
+
+CPY_PATCHSET="python-gentoo-patches-3.10.0_p1"
+DESCRIPTION="Collection of extensions to Distutils"
+HOMEPAGE="https://github.com/pypa/setuptools https://pypi.org/project/setuptools/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+	https://dev.gentoo.org/~floppym/python/${CPY_PATCHSET}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~x64-cygwin ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/jaraco-envs[${PYTHON_USEDEP}]
+			>=dev-python/jaraco-path-3.2.0[${PYTHON_USEDEP}]
+			dev-python/mock[${PYTHON_USEDEP}]
+			dev-python/pip[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-fixture-config[${PYTHON_USEDEP}]
+			dev-python/pytest-virtualenv[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+			>=dev-python/virtualenv-20[${PYTHON_USEDEP}]
+			dev-python/wheel[${PYTHON_USEDEP}]
+		' python3_{8..10} pypy3)
+	)
+"
+PDEPEND="
+	>=dev-python/certifi-2016.9.26[${PYTHON_USEDEP}]
+	dev-python/setuptools_scm[${PYTHON_USEDEP}]"
+
+# Force in-source build because build system modifies sources.
+DISTUTILS_IN_SOURCE_BUILD=1
+
+DOCS=( {CHANGES,README}.rst )
+
+src_prepare() {
+	# apply distutils patches to the bundled distutils
+	pushd setuptools/_distutils >/dev/null || die
+	# TODO: distutils C++ patch?
+	eapply -p3 "${WORKDIR}/${CPY_PATCHSET}/0006-distutils-make-OO-enable-both-opt-1-and-opt-2-optimi.patch"
+	popd >/dev/null || die
+
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	local -x SETUPTOOLS_USE_DISTUTILS=stdlib
+
+	# keep in sync with python_gen_cond_dep above!
+	has "${EPYTHON}" python3.{8..10} pypy3 || continue
+
+	distutils_install_for_testing
+	local EPYTEST_DESELECT=(
+		# network
+		setuptools/tests/test_distutils_adoption.py
+		'setuptools/tests/test_virtualenv.py::test_pip_upgrade_from_source[None]'
+		# unhappy with pytest-xdist?
+		setuptools/tests/test_easy_install.py::TestUserInstallTest::test_local_index
+		# TODO
+		setuptools/tests/test_easy_install.py::TestSetupRequires::test_setup_requires_with_allow_hosts
+		setuptools/tests/test_test.py::test_tests_are_run_once
+	)
+
+	# test_easy_install raises a SandboxViolation due to ${HOME}/.pydistutils.cfg
+	# It tries to sandbox the test in a tempdir
+	HOME="${PWD}" epytest \
+		-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" setuptools
+}
+
+python_install() {
+	export DISTRIBUTE_DISABLE_VERSIONED_EASY_INSTALL_SCRIPT=1
+	distutils-r1_python_install
+}