mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
kde-plasma/plasma-workspace: drop 5.25.3.1
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
@@ -1,4 +1,3 @@
|
||||
DIST plasma-workspace-5.24.5.tar.xz 18490588 BLAKE2B 5a9681620f40604f631cd7ef0c9d6256cc490436dc5e29ef9434d0f129324c2d405c5647da12778c208976c0cb0b4da698a90a22b70c1cb2723cbc58f69bda1d SHA512 ae40fe545b03e42e9f8fe2e8885d3853f4b52d4fd2ed3ecf7d24fa59b4924b8f8b389e8713ec6a3a875bc66df3952de9157d4a5631b283105a9329a1a1825996
|
||||
DIST plasma-workspace-5.24.6.tar.xz 18500752 BLAKE2B 1e469e91e8f1828f0b819aaa03f2918fa7df551786d7bbc963c7b4f7078719e9655176c5ddeea262175c36b14ba360e143e182dad78e369f833338ef147af06a SHA512 4e49f59d565e0b84951122155158966a54c05a6999ff99503bfff667c780fac6cfc076326f0cac7d53629bfc1d81599b30e919848168f6beb79a4dc7cf7c5560
|
||||
DIST plasma-workspace-5.25.3.1.tar.xz 18613360 BLAKE2B 44ab976c314004f3af8c27eb6e8b564d06fb1446c673fee81042cfc48a33c05f5033a3525bc0f0cb0f9f80c9ab77484148e3c55a5d85824f0372cc66abf6ded7 SHA512 8bfef223174a21e9b485cebfaf738281ab42955f2bf7bf6b0d53f836d01fc7f31af8522f40fd21f1cb683345d227ee1a8f19531fcc8028a3740212a2dccfc831
|
||||
DIST plasma-workspace-5.25.4.tar.xz 18616536 BLAKE2B 1674728254c7ab5e7572b1feb6c66e04794c06dde4e61ef26a5d2f73fe3d4899c195a572359fdaeff1c7a016fa22ec597072bd07481b87f5055bae4a49c627f6 SHA512 4f06eedcae47d3c03e0d604a95242d13284bf64891d1c982884a482583ff81ba60202b60e63cc46c3f7e35b98e2910bf69e451fe1aedb64af387add8bcaf4e87
|
||||
|
||||
@@ -1,218 +0,0 @@
|
||||
# Copyright 1999-2022 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
ECM_HANDBOOK="optional"
|
||||
ECM_TEST="forceoptional"
|
||||
KFMIN=5.95.0
|
||||
PVCUT=$(ver_cut 1-3)
|
||||
QTMIN=5.15.5
|
||||
VIRTUALX_REQUIRED="test"
|
||||
inherit ecm plasma.kde.org
|
||||
|
||||
DESCRIPTION="KDE Plasma workspace"
|
||||
|
||||
LICENSE="GPL-2" # TODO: CHECK
|
||||
SLOT="5"
|
||||
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
|
||||
IUSE="appstream +calendar +fontconfig geolocation gps +policykit
|
||||
screencast +semantic-desktop telemetry"
|
||||
|
||||
REQUIRED_USE="gps? ( geolocation )"
|
||||
RESTRICT="test"
|
||||
|
||||
# slot op: various private QtWaylandClient headers
|
||||
COMMON_DEPEND="
|
||||
>=dev-libs/wayland-1.15
|
||||
>=dev-qt/qtdbus-${QTMIN}:5
|
||||
>=dev-qt/qtdeclarative-${QTMIN}:5[widgets]
|
||||
>=dev-qt/qtgui-${QTMIN}:5=[jpeg,libinput]
|
||||
>=dev-qt/qtnetwork-${QTMIN}:5
|
||||
>=dev-qt/qtsql-${QTMIN}:5
|
||||
>=dev-qt/qtsvg-${QTMIN}:5
|
||||
>=dev-qt/qtwayland-${QTMIN}:5=
|
||||
>=dev-qt/qtwidgets-${QTMIN}:5
|
||||
>=dev-qt/qtx11extras-${QTMIN}:5
|
||||
>=dev-qt/qtxml-${QTMIN}:5
|
||||
>=kde-frameworks/kactivities-${KFMIN}:5
|
||||
>=kde-frameworks/kactivities-stats-${KFMIN}:5
|
||||
>=kde-frameworks/karchive-${KFMIN}:5
|
||||
>=kde-frameworks/kauth-${KFMIN}:5
|
||||
>=kde-frameworks/kbookmarks-${KFMIN}:5
|
||||
>=kde-frameworks/kcompletion-${KFMIN}:5
|
||||
>=kde-frameworks/kconfig-${KFMIN}:5
|
||||
>=kde-frameworks/kconfigwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/kcoreaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kcrash-${KFMIN}:5
|
||||
>=kde-frameworks/kdbusaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kdeclarative-${KFMIN}:5
|
||||
>=kde-frameworks/kded-${KFMIN}:5
|
||||
>=kde-frameworks/kglobalaccel-${KFMIN}:5
|
||||
>=kde-frameworks/kguiaddons-${KFMIN}:5
|
||||
>=kde-frameworks/ki18n-${KFMIN}:5
|
||||
>=kde-frameworks/kiconthemes-${KFMIN}:5
|
||||
>=kde-frameworks/kidletime-${KFMIN}:5
|
||||
>=kde-frameworks/kinit-${KFMIN}:5
|
||||
>=kde-frameworks/kio-${KFMIN}:5
|
||||
>=kde-frameworks/kitemmodels-${KFMIN}:5
|
||||
>=kde-frameworks/kitemviews-${KFMIN}:5
|
||||
>=kde-frameworks/kjobwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/knewstuff-${KFMIN}:5
|
||||
>=kde-frameworks/knotifications-${KFMIN}:5
|
||||
>=kde-frameworks/knotifyconfig-${KFMIN}:5
|
||||
>=kde-frameworks/kpackage-${KFMIN}:5
|
||||
>=kde-frameworks/kpeople-${KFMIN}:5
|
||||
>=kde-frameworks/krunner-${KFMIN}:5
|
||||
>=kde-frameworks/kservice-${KFMIN}:5
|
||||
>=kde-frameworks/ktexteditor-${KFMIN}:5
|
||||
>=kde-frameworks/ktextwidgets-${KFMIN}:5
|
||||
>=kde-frameworks/kunitconversion-${KFMIN}:5
|
||||
>=kde-frameworks/kwallet-${KFMIN}:5
|
||||
>=kde-frameworks/kwayland-${KFMIN}:5
|
||||
>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
|
||||
>=kde-frameworks/kwindowsystem-${KFMIN}:5
|
||||
>=kde-frameworks/kxmlgui-${KFMIN}:5
|
||||
>=kde-frameworks/plasma-${KFMIN}:5
|
||||
>=kde-frameworks/prison-${KFMIN}:5[qml]
|
||||
>=kde-frameworks/solid-${KFMIN}:5
|
||||
>=kde-plasma/breeze-${PVCUT}:5
|
||||
>=kde-plasma/kscreenlocker-${PVCUT}:5
|
||||
>=kde-plasma/kwin-${PVCUT}:5
|
||||
>=kde-plasma/layer-shell-qt-${PVCUT}:5
|
||||
>=kde-plasma/libkscreen-${PVCUT}:5
|
||||
>=kde-plasma/libksysguard-${PVCUT}:5
|
||||
>=kde-plasma/libkworkspace-${PVCUT}:5
|
||||
>=media-libs/phonon-4.11.0
|
||||
sci-libs/libqalculate:=
|
||||
sys-libs/zlib
|
||||
x11-libs/libICE
|
||||
x11-libs/libSM
|
||||
x11-libs/libX11
|
||||
x11-libs/libXau
|
||||
x11-libs/libxcb
|
||||
x11-libs/libXcursor
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXrender
|
||||
x11-libs/libXtst
|
||||
x11-libs/xcb-util
|
||||
x11-libs/xcb-util-image
|
||||
appstream? ( dev-libs/appstream[qt5] )
|
||||
calendar? ( >=kde-frameworks/kholidays-${KFMIN}:5 )
|
||||
fontconfig? (
|
||||
>=dev-qt/qtprintsupport-${QTMIN}:5
|
||||
media-libs/fontconfig
|
||||
x11-libs/libXft
|
||||
x11-libs/xcb-util-image
|
||||
)
|
||||
geolocation? ( >=kde-frameworks/networkmanager-qt-${KFMIN}:5 )
|
||||
gps? ( sci-geosciences/gpsd )
|
||||
policykit? ( virtual/libcrypt:= )
|
||||
screencast? (
|
||||
>=dev-qt/qtgui-${QTMIN}:5=[egl]
|
||||
media-libs/libglvnd
|
||||
>=media-video/pipewire-0.3:=
|
||||
x11-libs/libdrm
|
||||
)
|
||||
semantic-desktop? ( >=kde-frameworks/baloo-${KFMIN}:5 )
|
||||
telemetry? ( dev-libs/kuserfeedback:5 )
|
||||
"
|
||||
DEPEND="${COMMON_DEPEND}
|
||||
>=dev-libs/plasma-wayland-protocols-1.6.0
|
||||
>=dev-qt/qtconcurrent-${QTMIN}:5
|
||||
>=dev-util/wayland-scanner-1.19.0
|
||||
x11-base/xorg-proto
|
||||
fontconfig? ( x11-libs/libXrender )
|
||||
test? ( >=dev-libs/wayland-protocols-1.24 )
|
||||
"
|
||||
RDEPEND="${COMMON_DEPEND}
|
||||
app-text/iso-codes
|
||||
>=dev-qt/qdbus-${QTMIN}:*
|
||||
>=dev-qt/qtgraphicaleffects-${QTMIN}:5
|
||||
>=dev-qt/qtpaths-${QTMIN}:5
|
||||
>=dev-qt/qtquickcontrols-${QTMIN}:5[widgets]
|
||||
>=dev-qt/qtquickcontrols2-${QTMIN}:5
|
||||
kde-apps/kio-extras:5
|
||||
>=kde-frameworks/kirigami-${KFMIN}:5
|
||||
>=kde-frameworks/kquickcharts-${KFMIN}:5
|
||||
>=kde-plasma/milou-${PVCUT}:5
|
||||
>=kde-plasma/plasma-integration-${PVCUT}:5
|
||||
sys-apps/dbus
|
||||
x11-apps/xmessage
|
||||
x11-apps/xprop
|
||||
x11-apps/xrdb
|
||||
x11-apps/xsetroot
|
||||
!<kde-plasma/breeze-5.22.90:5
|
||||
!<kde-plasma/plasma-desktop-5.23.90:5
|
||||
policykit? ( sys-apps/accountsservice )
|
||||
"
|
||||
BDEPEND="
|
||||
>=dev-qt/qtwaylandscanner-${QTMIN}:5
|
||||
virtual/pkgconfig
|
||||
"
|
||||
PDEPEND=">=kde-plasma/kde-cli-tools-${PVCUT}:5"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}/${PN}-5.24.80-split-libkworkspace.patch" # downstream
|
||||
"${FILESDIR}/${PN}-5.22.5-krunner-cwd-at-home.patch" # TODO upstream: KDE-bug 432975, bug 767478
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
ecm_src_prepare
|
||||
|
||||
cmake_comment_add_subdirectory libkworkspace
|
||||
# delete colliding libkworkspace translations
|
||||
if [[ ${KDE_BUILD_TYPE} = release ]]; then
|
||||
find po -type f -name "*po" -and -name "libkworkspace*" -delete || die
|
||||
fi
|
||||
|
||||
# TODO: try to get a build switch upstreamed
|
||||
if ! use screencast; then
|
||||
sed -e "s/^pkg_check_modules.*PipeWire/#&/" -i CMakeLists.txt || die
|
||||
fi
|
||||
|
||||
# TODO: try to get a build switch upstreamed
|
||||
if use geolocation; then
|
||||
use gps || sed -e "s/^pkg_check_modules.*LIBGPS/#&/" \
|
||||
-i dataengines/geolocation/CMakeLists.txt || die
|
||||
fi
|
||||
|
||||
if ! use policykit; then
|
||||
cmake_run_in kcms cmake_comment_add_subdirectory users
|
||||
fi
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local mycmakeargs=(
|
||||
-DBUILD_xembed-sni-proxy=OFF
|
||||
-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt5=ON
|
||||
$(cmake_use_find_package appstream AppStreamQt)
|
||||
$(cmake_use_find_package calendar KF5Holidays)
|
||||
$(cmake_use_find_package fontconfig Fontconfig)
|
||||
$(cmake_use_find_package geolocation KF5NetworkManagerQt)
|
||||
$(cmake_use_find_package semantic-desktop KF5Baloo)
|
||||
$(cmake_use_find_package telemetry KUserFeedback)
|
||||
)
|
||||
|
||||
ecm_src_configure
|
||||
}
|
||||
|
||||
src_install() {
|
||||
ecm_src_install
|
||||
|
||||
# default startup and shutdown scripts
|
||||
insinto /etc/xdg/plasma-workspace/env
|
||||
doins "${FILESDIR}"/10-agent-startup.sh
|
||||
|
||||
insinto /etc/xdg/plasma-workspace/shutdown
|
||||
doins "${FILESDIR}"/10-agent-shutdown.sh
|
||||
fperms +x /etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh
|
||||
}
|
||||
|
||||
pkg_postinst () {
|
||||
ecm_pkg_postinst
|
||||
|
||||
elog "To enable gpg-agent and/or ssh-agent in Plasma sessions,"
|
||||
elog "edit ${EPREFIX}/etc/xdg/plasma-workspace/env/10-agent-startup.sh"
|
||||
elog "and ${EPREFIX}/etc/xdg/plasma-workspace/shutdown/10-agent-shutdown.sh"
|
||||
}
|
||||
Reference in New Issue
Block a user